stpt01()

subroutine stpt01	(	character	uplo,
		character	diag,
		integer	n,
		real, dimension( * )	ap,
		real, dimension( * )	ainvp,
		real	rcond,
		real, dimension( * )	work,
		real	resid )

STPT01

Purpose:

!>
!> STPT01 computes the residual for a triangular matrix A times its
!> inverse when A is stored in packed format:
!>    RESID = norm(A*AINV - I) / ( N * norm(A) * norm(AINV) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	AP	!> AP is REAL array, dimension (N*(N+1)/2) !> The original upper or lower triangular matrix A, packed !> columnwise in a linear array. The j-th column of A is stored !> in the array AP as follows: !> if UPLO = 'U', AP((j-1)*j/2 + i) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', !> AP((j-1)*(n-j) + j*(j+1)/2 + i-j) = A(i,j) for j<=i<=n. !>
[in,out]	AINVP	!> AINVP is REAL array, dimension (N*(N+1)/2) !> On entry, the (triangular) inverse of the matrix A, packed !> columnwise in a linear array as in AP. !> On exit, the contents of AINVP are destroyed. !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal condition number of A, computed as !> 1/(norm(A) * norm(AINV)). !>
[out]	WORK	!> WORK is REAL array, dimension (N) !>
[out]	RESID	!> RESID is REAL !> norm(A*AINV - I) / ( N * norm(A) * norm(AINV) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 107 of file stpt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            N
      REAL               RCOND, RESID
*     ..
*     .. Array Arguments ..
      REAL               AINVP( * ), AP( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UNITD
      INTEGER            J, JC
      REAL               AINVNM, ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANTP
      EXTERNAL           lsame, slamch, slantp
*     ..
*     .. External Subroutines ..
      EXTERNAL           stpmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slantp( '1', uplo, diag, n, ap, work )
      ainvnm = slantp( '1', uplo, diag, n, ainvp, work )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Compute A * AINV, overwriting AINV.
*
      unitd = lsame( diag, 'U' )
      IF( lsame( uplo, 'U' ) ) THEN
         jc = 1
         DO 10 j = 1, n
            IF( unitd )
     $         ainvp( jc+j-1 ) = one
*
*           Form the j-th column of A*AINV
*
            CALL stpmv( 'Upper', 'No transpose', diag, j, ap,
     $                  ainvp( jc ), 1 )
*
*           Subtract 1 from the diagonal
*
            ainvp( jc+j-1 ) = ainvp( jc+j-1 ) - one
            jc = jc + j
   10    CONTINUE
      ELSE
         jc = 1
         DO 20 j = 1, n
            IF( unitd )
     $         ainvp( jc ) = one
*
*           Form the j-th column of A*AINV
*
            CALL stpmv( 'Lower', 'No transpose', diag, n-j+1, ap( jc ),
     $                  ainvp( jc ), 1 )
*
*           Subtract 1 from the diagonal
*
            ainvp( jc ) = ainvp( jc ) - one
            jc = jc + n - j + 1
   20    CONTINUE
      END IF
*
*     Compute norm(A*AINV - I) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = slantp( '1', uplo, 'Non-unit', n, ainvp, work )
*
      resid = ( ( resid*rcond ) / real( n ) ) / eps
*
      RETURN
*
*     End of STPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: