LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dlatsqr()

subroutine dlatsqr ( integer  M,
integer  N,
integer  MB,
integer  NB,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension(ldt, *)  T,
integer  LDT,
double precision, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

DLATSQR

Purpose:
 DLATSQR computes a blocked Tall-Skinny QR factorization of
 a real M-by-N matrix A for M >= N:

    A = Q * ( R ),
            ( 0 )

 where:

    Q is a M-by-M orthogonal matrix, stored on exit in an implicit
    form in the elements below the diagonal of the array A and in
    the elements of the array T;

    R is an upper-triangular N-by-N matrix, stored on exit in
    the elements on and above the diagonal of the array A.

    0 is a (M-N)-by-N zero matrix, and is not stored.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A. M >= N >= 0.
[in]MB
          MB is INTEGER
          The row block size to be used in the blocked QR.
          MB > 0.
[in]NB
          NB is INTEGER
          The column block size to be used in the blocked QR.
          N >= NB >= 1.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          On entry, the M-by-N matrix A.
          On exit, the elements on and above the diagonal
          of the array contain the N-by-N upper triangular matrix R;
          the elements below the diagonal represent Q by the columns
          of blocked V (see Further Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]T
          T is DOUBLE PRECISION array,
          dimension (LDT, N * Number_of_row_blocks)
          where Number_of_row_blocks = CEIL((M-N)/(MB-N))
          The blocked upper triangular block reflectors stored in compact form
          as a sequence of upper triangular blocks.
          See Further Details below.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= NB.
[out]WORK
         (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
[in]LWORK
          The dimension of the array WORK.  LWORK >= NB*N.
          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
 Tall-Skinny QR (TSQR) performs QR by a sequence of orthogonal transformations,
 representing Q as a product of other orthogonal matrices
   Q = Q(1) * Q(2) * . . . * Q(k)
 where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
   Q(1) zeros out the subdiagonal entries of rows 1:MB of A
   Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
   Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
   . . .

 Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
 stored under the diagonal of rows 1:MB of A, and by upper triangular
 block reflectors, stored in array T(1:LDT,1:N).
 For more information see Further Details in GEQRT.

 Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
 stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
 block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
 The last Q(k) may use fewer rows.
 For more information see Further Details in TPQRT.

 For more details of the overall algorithm, see the description of
 Sequential TSQR in Section 2.2 of [1].

 [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
     J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
     SIAM J. Sci. Comput, vol. 34, no. 1, 2012

Definition at line 164 of file dlatsqr.f.

166*
167* -- LAPACK computational routine --
168* -- LAPACK is a software package provided by Univ. of Tennessee, --
169* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
170*
171* .. Scalar Arguments ..
172 INTEGER INFO, LDA, M, N, MB, NB, LDT, LWORK
173* ..
174* .. Array Arguments ..
175 DOUBLE PRECISION A( LDA, * ), WORK( * ), T(LDT, *)
176* ..
177*
178* =====================================================================
179*
180* ..
181* .. Local Scalars ..
182 LOGICAL LQUERY
183 INTEGER I, II, KK, CTR
184* ..
185* .. EXTERNAL FUNCTIONS ..
186 LOGICAL LSAME
187 EXTERNAL lsame
188* .. EXTERNAL SUBROUTINES ..
189 EXTERNAL dgeqrt, dtpqrt, xerbla
190* .. INTRINSIC FUNCTIONS ..
191 INTRINSIC max, min, mod
192* ..
193* .. EXECUTABLE STATEMENTS ..
194*
195* TEST THE INPUT ARGUMENTS
196*
197 info = 0
198*
199 lquery = ( lwork.EQ.-1 )
200*
201 IF( m.LT.0 ) THEN
202 info = -1
203 ELSE IF( n.LT.0 .OR. m.LT.n ) THEN
204 info = -2
205 ELSE IF( mb.LT.1 ) THEN
206 info = -3
207 ELSE IF( nb.LT.1 .OR. ( nb.GT.n .AND. n.GT.0 )) THEN
208 info = -4
209 ELSE IF( lda.LT.max( 1, m ) ) THEN
210 info = -6
211 ELSE IF( ldt.LT.nb ) THEN
212 info = -8
213 ELSE IF( lwork.LT.(n*nb) .AND. (.NOT.lquery) ) THEN
214 info = -10
215 END IF
216 IF( info.EQ.0) THEN
217 work(1) = nb*n
218 END IF
219 IF( info.NE.0 ) THEN
220 CALL xerbla( 'DLATSQR', -info )
221 RETURN
222 ELSE IF (lquery) THEN
223 RETURN
224 END IF
225*
226* Quick return if possible
227*
228 IF( min(m,n).EQ.0 ) THEN
229 RETURN
230 END IF
231*
232* The QR Decomposition
233*
234 IF ((mb.LE.n).OR.(mb.GE.m)) THEN
235 CALL dgeqrt( m, n, nb, a, lda, t, ldt, work, info)
236 RETURN
237 END IF
238*
239 kk = mod((m-n),(mb-n))
240 ii=m-kk+1
241*
242* Compute the QR factorization of the first block A(1:MB,1:N)
243*
244 CALL dgeqrt( mb, n, nb, a(1,1), lda, t, ldt, work, info )
245*
246 ctr = 1
247 DO i = mb+1, ii-mb+n , (mb-n)
248*
249* Compute the QR factorization of the current block A(I:I+MB-N,1:N)
250*
251 CALL dtpqrt( mb-n, n, 0, nb, a(1,1), lda, a( i, 1 ), lda,
252 $ t(1, ctr * n + 1),
253 $ ldt, work, info )
254 ctr = ctr + 1
255 END DO
256*
257* Compute the QR factorization of the last block A(II:M,1:N)
258*
259 IF (ii.LE.m) THEN
260 CALL dtpqrt( kk, n, 0, nb, a(1,1), lda, a( ii, 1 ), lda,
261 $ t(1, ctr * n + 1), ldt,
262 $ work, info )
263 END IF
264*
265 work( 1 ) = n*nb
266 RETURN
267*
268* End of DLATSQR
269*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dgeqrt(M, N, NB, A, LDA, T, LDT, WORK, INFO)
DGEQRT
Definition: dgeqrt.f:141
subroutine dtpqrt(M, N, L, NB, A, LDA, B, LDB, T, LDT, WORK, INFO)
DTPQRT
Definition: dtpqrt.f:189
Here is the call graph for this function:
Here is the caller graph for this function: