zhpgst.f

Go to the documentation of this file.

*> \brief \b ZHPGST
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download ZHPGST + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhpgst.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhpgst.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhpgst.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZHPGST( ITYPE, UPLO, N, AP, BP, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, ITYPE, N
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         AP( * ), BP( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZHPGST reduces a complex Hermitian-definite generalized
*> eigenproblem to standard form, using packed storage.
*>
*> If ITYPE = 1, the problem is A*x = lambda*B*x,
*> and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)
*>
*> If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
*> B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H*A*L.
*>
*> B must have been previously factorized as U**H*U or L*L**H by ZPPTRF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ITYPE
*> \verbatim
*>          ITYPE is INTEGER
*>          = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
*>          = 2 or 3: compute U*A*U**H or L**H*A*L.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          = 'U':  Upper triangle of A is stored and B is factored as
*>                  U**H*U;
*>          = 'L':  Lower triangle of A is stored and B is factored as
*>                  L*L**H.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          On entry, the upper or lower triangle of the Hermitian matrix
*>          A, packed columnwise in a linear array.  The j-th column of A
*>          is stored in the array AP as follows:
*>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
*>          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
*>
*>          On exit, if INFO = 0, the transformed matrix, stored in the
*>          same format as A.
*> \endverbatim
*>
*> \param[in] BP
*> \verbatim
*>          BP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The triangular factor from the Cholesky factorization of B,
*>          stored in the same format as A, as returned by ZPPTRF.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hpgst
*
*  =====================================================================
      SUBROUTINE zhpgst( ITYPE, UPLO, N, AP, BP, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         AP( * ), BP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, HALF
      parameter( one = 1.0d+0, half = 0.5d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, J1, J1J1, JJ, K, K1, K1K1, KK
      DOUBLE PRECISION   AJJ, AKK, BJJ, BKK
      COMPLEX*16         CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zdscal, zhpmv, zhpr2,
     $                   ztpmv,
     $                   ztpsv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, zdotc
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZHPGST', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**H)*A*inv(U)
*
*           J1 and JJ are the indices of A(1,j) and A(j,j)
*
            jj = 0
            DO 10 j = 1, n
               j1 = jj + 1
               jj = jj + j
*
*              Compute the j-th column of the upper triangle of A
*
               ap( jj ) = dble( ap( jj ) )
               bjj = dble( bp( jj ) )
               CALL ztpsv( uplo, 'Conjugate transpose', 'Non-unit',
     $                     j,
     $                     bp, ap( j1 ), 1 )
               CALL zhpmv( uplo, j-1, -cone, ap, bp( j1 ), 1, cone,
     $                     ap( j1 ), 1 )
               CALL zdscal( j-1, one / bjj, ap( j1 ), 1 )
               ap( jj ) = ( ap( jj )-zdotc( j-1, ap( j1 ), 1,
     $             bp( j1 ),
     $                    1 ) ) / bjj
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L**H)
*
*           KK and K1K1 are the indices of A(k,k) and A(k+1,k+1)
*
            kk = 1
            DO 20 k = 1, n
               k1k1 = kk + n - k + 1
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = dble( ap( kk ) )
               bkk = dble( bp( kk ) )
               akk = akk / bkk**2
               ap( kk ) = akk
               IF( k.LT.n ) THEN
                  CALL zdscal( n-k, one / bkk, ap( kk+1 ), 1 )
                  ct = -half*akk
                  CALL zaxpy( n-k, ct, bp( kk+1 ), 1, ap( kk+1 ), 1 )
                  CALL zhpr2( uplo, n-k, -cone, ap( kk+1 ), 1,
     $                        bp( kk+1 ), 1, ap( k1k1 ) )
                  CALL zaxpy( n-k, ct, bp( kk+1 ), 1, ap( kk+1 ), 1 )
                  CALL ztpsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        bp( k1k1 ), ap( kk+1 ), 1 )
               END IF
               kk = k1k1
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**H
*
*           K1 and KK are the indices of A(1,k) and A(k,k)
*
            kk = 0
            DO 30 k = 1, n
               k1 = kk + 1
               kk = kk + k
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = dble( ap( kk ) )
               bkk = dble( bp( kk ) )
               CALL ztpmv( uplo, 'No transpose', 'Non-unit', k-1, bp,
     $                     ap( k1 ), 1 )
               ct = half*akk
               CALL zaxpy( k-1, ct, bp( k1 ), 1, ap( k1 ), 1 )
               CALL zhpr2( uplo, k-1, cone, ap( k1 ), 1, bp( k1 ), 1,
     $                     ap )
               CALL zaxpy( k-1, ct, bp( k1 ), 1, ap( k1 ), 1 )
               CALL zdscal( k-1, bkk, ap( k1 ), 1 )
               ap( kk ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L**H *A*L
*
*           JJ and J1J1 are the indices of A(j,j) and A(j+1,j+1)
*
            jj = 1
            DO 40 j = 1, n
               j1j1 = jj + n - j + 1
*
*              Compute the j-th column of the lower triangle of A
*
               ajj = dble( ap( jj ) )
               bjj = dble( bp( jj ) )
               ap( jj ) = ajj*bjj + zdotc( n-j, ap( jj+1 ), 1,
     $                    bp( jj+1 ), 1 )
               CALL zdscal( n-j, bjj, ap( jj+1 ), 1 )
               CALL zhpmv( uplo, n-j, cone, ap( j1j1 ), bp( jj+1 ),
     $                     1,
     $                     cone, ap( jj+1 ), 1 )
               CALL ztpmv( uplo, 'Conjugate transpose', 'Non-unit',
     $                     n-j+1, bp( jj ), ap( jj ), 1 )
               jj = j1j1
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of ZHPGST
*
      END