sqrt17()

real function sqrt17	(	character	trans,
		integer	iresid,
		integer	m,
		integer	n,
		integer	nrhs,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( ldb, * )	c,
		real, dimension( lwork )	work,
		integer	lwork
	)

SQRT17

Purpose:

 SQRT17 computes the ratio

    norm(R**T * op(A)) / ( norm(A) * alpha * max(M,N,NRHS) * EPS ),

 where R = B - op(A)*X, op(A) is A or A**T, depending on TRANS, EPS
 is the machine epsilon, and

    alpha = norm(B) if IRESID = 1 (zero-residual problem)
    alpha = norm(R) if IRESID = 2 (otherwise).

 The norm used is the 1-norm.

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies whether or not the transpose of A is used. = 'N': No transpose, op(A) = A. = 'T': Transpose, op(A) = A**T.
[in]	IRESID	IRESID is INTEGER IRESID = 1 indicates zero-residual problem. IRESID = 2 indicates non-zero residual.
[in]	M	M is INTEGER The number of rows of the matrix A. If TRANS = 'N', the number of rows of the matrix B. If TRANS = 'T', the number of rows of the matrix X.
[in]	N	N is INTEGER The number of columns of the matrix A. If TRANS = 'N', the number of rows of the matrix X. If TRANS = 'T', the number of rows of the matrix B.
[in]	NRHS	NRHS is INTEGER The number of columns of the matrices X and B.
[in]	A	A is REAL array, dimension (LDA,N) The m-by-n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= M.
[in]	X	X is REAL array, dimension (LDX,NRHS) If TRANS = 'N', the n-by-nrhs matrix X. If TRANS = 'T', the m-by-nrhs matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. If TRANS = 'N', LDX >= N. If TRANS = 'T', LDX >= M.
[in]	B	B is REAL array, dimension (LDB,NRHS) If TRANS = 'N', the m-by-nrhs matrix B. If TRANS = 'T', the n-by-nrhs matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. If TRANS = 'N', LDB >= M. If TRANS = 'T', LDB >= N.
[out]	C	C is REAL array, dimension (LDB,NRHS)
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= NRHS*(M+N).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 151 of file sqrt17.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IRESID, LDA, LDB, LDX, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), C( LDB, * ),
     $                   WORK( LWORK ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, ISCL, NCOLS, NROWS
      REAL               ERR, NORMA, NORMB, NORMRS, SMLNUM
*     ..
*     .. Local Arrays ..
      REAL               RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE
      EXTERNAL           lsame, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slascl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Executable Statements ..
*
      sqrt17 = zero
*
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
      ELSE IF( lsame( trans, 'T' ) ) THEN
         nrows = n
         ncols = m
      ELSE
         CALL xerbla( 'SQRT17', 1 )
         RETURN
      END IF
*
      IF( lwork.LT.ncols*nrhs ) THEN
         CALL xerbla( 'SQRT17', 13 )
         RETURN
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 ) THEN
         RETURN
      END IF
*
      norma = slange( 'One-norm', m, n, a, lda, rwork )
      smlnum = slamch( 'Safe minimum' ) / slamch( 'Precision' )
      iscl = 0
*
*     compute residual and scale it
*
      CALL slacpy( 'All', nrows, nrhs, b, ldb, c, ldb )
      CALL sgemm( trans, 'No transpose', nrows, nrhs, ncols, -one, a,
     $            lda, x, ldx, one, c, ldb )
      normrs = slange( 'Max', nrows, nrhs, c, ldb, rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL slascl( 'General', 0, 0, normrs, one, nrows, nrhs, c, ldb,
     $                info )
      END IF
*
*     compute R**T * op(A)
*
      CALL sgemm( 'Transpose', trans, nrhs, ncols, nrows, one, c, ldb,
     $            a, lda, zero, work, nrhs )
*
*     compute and properly scale error
*
      err = slange( 'One-norm', nrhs, ncols, work, nrhs, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = slange( 'One-norm', nrows, nrhs, b, ldb, rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         IF( normrs.NE.zero )
     $      err = err / normrs
      END IF
*
      sqrt17 = err / ( slamch( 'Epsilon' )*real( max( m, n, nrhs ) ) )
      RETURN
*
*     End of SQRT17
*

Here is the call graph for this function:

Here is the caller graph for this function: