LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ chbev()

subroutine chbev ( character jobz,
character uplo,
integer n,
integer kd,
complex, dimension( ldab, * ) ab,
integer ldab,
real, dimension( * ) w,
complex, dimension( ldz, * ) z,
integer ldz,
complex, dimension( * ) work,
real, dimension( * ) rwork,
integer info )

CHBEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices

Download CHBEV + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CHBEV computes all the eigenvalues and, optionally, eigenvectors of
!> a complex Hermitian band matrix A.
!>
Parameters
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in]KD
!>          KD is INTEGER
!>          The number of superdiagonals of the matrix A if UPLO = 'U',
!>          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
!>
[in,out]AB
!>          AB is COMPLEX array, dimension (LDAB, N)
!>          On entry, the upper or lower triangle of the Hermitian band
!>          matrix A, stored in the first KD+1 rows of the array.  The
!>          j-th column of A is stored in the j-th column of the array AB
!>          as follows:
!>          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
!>          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).
!>
!>          On exit, AB is overwritten by values generated during the
!>          reduction to tridiagonal form.  If UPLO = 'U', the first
!>          superdiagonal and the diagonal of the tridiagonal matrix T
!>          are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
!>          the diagonal and first subdiagonal of T are returned in the
!>          first two rows of AB.
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KD + 1.
!>
[out]W
!>          W is REAL array, dimension (N)
!>          If INFO = 0, the eigenvalues in ascending order.
!>
[out]Z
!>          Z is COMPLEX array, dimension (LDZ, N)
!>          If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
!>          eigenvectors of the matrix A, with the i-th column of Z
!>          holding the eigenvector associated with W(i).
!>          If JOBZ = 'N', then Z is not referenced.
!>
[in]LDZ
!>          LDZ is INTEGER
!>          The leading dimension of the array Z.  LDZ >= 1, and if
!>          JOBZ = 'V', LDZ >= max(1,N).
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (N)
!>
[out]RWORK
!>          RWORK is REAL array, dimension (max(1,3*N-2))
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit.
!>          < 0:  if INFO = -i, the i-th argument had an illegal value.
!>          > 0:  if INFO = i, the algorithm failed to converge; i
!>                off-diagonal elements of an intermediate tridiagonal
!>                form did not converge to zero.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 148 of file chbev.f.

150*
151* -- LAPACK driver routine --
152* -- LAPACK is a software package provided by Univ. of Tennessee, --
153* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
154*
155* .. Scalar Arguments ..
156 CHARACTER JOBZ, UPLO
157 INTEGER INFO, KD, LDAB, LDZ, N
158* ..
159* .. Array Arguments ..
160 REAL RWORK( * ), W( * )
161 COMPLEX AB( LDAB, * ), WORK( * ), Z( LDZ, * )
162* ..
163*
164* =====================================================================
165*
166* .. Parameters ..
167 REAL ZERO, ONE
168 parameter( zero = 0.0e0, one = 1.0e0 )
169* ..
170* .. Local Scalars ..
171 LOGICAL LOWER, WANTZ
172 INTEGER IINFO, IMAX, INDE, INDRWK, ISCALE
173 REAL ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
174 $ SMLNUM
175* ..
176* .. External Functions ..
177 LOGICAL LSAME
178 REAL CLANHB, SLAMCH
179 EXTERNAL lsame, clanhb, slamch
180* ..
181* .. External Subroutines ..
182 EXTERNAL chbtrd, clascl, csteqr, sscal, ssterf,
183 $ xerbla
184* ..
185* .. Intrinsic Functions ..
186 INTRINSIC sqrt
187* ..
188* .. Executable Statements ..
189*
190* Test the input parameters.
191*
192 wantz = lsame( jobz, 'V' )
193 lower = lsame( uplo, 'L' )
194*
195 info = 0
196 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
197 info = -1
198 ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
199 info = -2
200 ELSE IF( n.LT.0 ) THEN
201 info = -3
202 ELSE IF( kd.LT.0 ) THEN
203 info = -4
204 ELSE IF( ldab.LT.kd+1 ) THEN
205 info = -6
206 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
207 info = -9
208 END IF
209*
210 IF( info.NE.0 ) THEN
211 CALL xerbla( 'CHBEV ', -info )
212 RETURN
213 END IF
214*
215* Quick return if possible
216*
217 IF( n.EQ.0 )
218 $ RETURN
219*
220 IF( n.EQ.1 ) THEN
221 IF( lower ) THEN
222 w( 1 ) = real( ab( 1, 1 ) )
223 ELSE
224 w( 1 ) = real( ab( kd+1, 1 ) )
225 END IF
226 IF( wantz )
227 $ z( 1, 1 ) = one
228 RETURN
229 END IF
230*
231* Get machine constants.
232*
233 safmin = slamch( 'Safe minimum' )
234 eps = slamch( 'Precision' )
235 smlnum = safmin / eps
236 bignum = one / smlnum
237 rmin = sqrt( smlnum )
238 rmax = sqrt( bignum )
239*
240* Scale matrix to allowable range, if necessary.
241*
242 anrm = clanhb( 'M', uplo, n, kd, ab, ldab, rwork )
243 iscale = 0
244 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
245 iscale = 1
246 sigma = rmin / anrm
247 ELSE IF( anrm.GT.rmax ) THEN
248 iscale = 1
249 sigma = rmax / anrm
250 END IF
251 IF( iscale.EQ.1 ) THEN
252 IF( lower ) THEN
253 CALL clascl( 'B', kd, kd, one, sigma, n, n, ab, ldab,
254 $ info )
255 ELSE
256 CALL clascl( 'Q', kd, kd, one, sigma, n, n, ab, ldab,
257 $ info )
258 END IF
259 END IF
260*
261* Call CHBTRD to reduce Hermitian band matrix to tridiagonal form.
262*
263 inde = 1
264 CALL chbtrd( jobz, uplo, n, kd, ab, ldab, w, rwork( inde ), z,
265 $ ldz, work, iinfo )
266*
267* For eigenvalues only, call SSTERF. For eigenvectors, call CSTEQR.
268*
269 IF( .NOT.wantz ) THEN
270 CALL ssterf( n, w, rwork( inde ), info )
271 ELSE
272 indrwk = inde + n
273 CALL csteqr( jobz, n, w, rwork( inde ), z, ldz,
274 $ rwork( indrwk ), info )
275 END IF
276*
277* If matrix was scaled, then rescale eigenvalues appropriately.
278*
279 IF( iscale.EQ.1 ) THEN
280 IF( info.EQ.0 ) THEN
281 imax = n
282 ELSE
283 imax = info - 1
284 END IF
285 CALL sscal( imax, one / sigma, w, 1 )
286 END IF
287*
288 RETURN
289*
290* End of CHBEV
291*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
chbtrd
subroutine chbtrd(vect, uplo, n, kd, ab, ldab, d, e, q, ldq, work, info)
CHBTRD
Definition chbtrd.f:161
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
clanhb
real function clanhb(norm, uplo, n, k, ab, ldab, work)
CLANHB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition clanhb.f:130
clascl
subroutine clascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
CLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition clascl.f:142
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sscal
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
csteqr
subroutine csteqr(compz, n, d, e, z, ldz, work, info)
CSTEQR
Definition csteqr.f:130
ssterf
subroutine ssterf(n, d, e, info)
SSTERF
Definition ssterf.f:84
Here is the call graph for this function:
Here is the caller graph for this function: