dtbcon()

subroutine dtbcon	(	character	norm,
		character	uplo,
		character	diag,
		integer	n,
		integer	kd,
		double precision, dimension( ldab, * )	ab,
		integer	ldab,
		double precision	rcond,
		double precision, dimension( * )	work,
		integer, dimension( * )	iwork,
		integer	info
	)

DTBCON

Download DTBCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DTBCON estimates the reciprocal of the condition number of a
 triangular band matrix A, in either the 1-norm or the infinity-norm.

 The norm of A is computed and an estimate is obtained for
 norm(inv(A)), then the reciprocal of the condition number is
 computed as
    RCOND = 1 / ( norm(A) * norm(inv(A)) ).

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies whether the 1-norm condition number or the infinity-norm condition number is required: = '1' or 'O': 1-norm; = 'I': Infinity-norm.
[in]	UPLO	UPLO is CHARACTER*1 = 'U': A is upper triangular; = 'L': A is lower triangular.
[in]	DIAG	DIAG is CHARACTER*1 = 'N': A is non-unit triangular; = 'U': A is unit triangular.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of superdiagonals or subdiagonals of the triangular band matrix A. KD >= 0.
[in]	AB	AB is DOUBLE PRECISION array, dimension (LDAB,N) The upper or lower triangular band matrix A, stored in the first kd+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). If DIAG = 'U', the diagonal elements of A are not referenced and are assumed to be 1.
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	RCOND	RCOND is DOUBLE PRECISION The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(norm(A) * norm(inv(A))).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (3*N)
[out]	IWORK	IWORK is INTEGER array, dimension (N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 141 of file dtbcon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, NORM, UPLO
      INTEGER            INFO, KD, LDAB, N
      DOUBLE PRECISION   RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, ONENRM, UPPER
      CHARACTER          NORMIN
      INTEGER            IX, KASE, KASE1
      DOUBLE PRECISION   AINVNM, ANORM, SCALE, SMLNUM, XNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH, DLANTB
      EXTERNAL           lsame, idamax, dlamch, dlantb
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlacn2, dlatbs, drscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( kd.LT.0 ) THEN
         info = -5
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DTBCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      END IF
*
      rcond = zero
      smlnum = dlamch( 'Safe minimum' )*dble( max( 1, n ) )
*
*     Compute the norm of the triangular matrix A.
*
      anorm = dlantb( norm, uplo, diag, n, kd, ab, ldab, work )
*
*     Continue only if ANORM > 0.
*
      IF( anorm.GT.zero ) THEN
*
*        Estimate the norm of the inverse of A.
*
         ainvnm = zero
         normin = 'N'
         IF( onenrm ) THEN
            kase1 = 1
         ELSE
            kase1 = 2
         END IF
         kase = 0
   10    CONTINUE
         CALL dlacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.kase1 ) THEN
*
*              Multiply by inv(A).
*
               CALL dlatbs( uplo, 'No transpose', diag, normin, n, kd,
     $                      ab, ldab, work, scale, work( 2*n+1 ), info )
            ELSE
*
*              Multiply by inv(A**T).
*
               CALL dlatbs( uplo, 'Transpose', diag, normin, n, kd, ab,
     $                      ldab, work, scale, work( 2*n+1 ), info )
            END IF
            normin = 'Y'
*
*           Multiply by 1/SCALE if doing so will not cause overflow.
*
            IF( scale.NE.one ) THEN
               ix = idamax( n, work, 1 )
               xnorm = abs( work( ix ) )
               IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
     $            GO TO 20
               CALL drscl( n, scale, work, 1 )
            END IF
            GO TO 10
         END IF
*
*        Compute the estimate of the reciprocal condition number.
*
         IF( ainvnm.NE.zero )
     $      rcond = ( one / anorm ) / ainvnm
      END IF
*
   20 CONTINUE
      RETURN
*
*     End of DTBCON
*

Here is the call graph for this function:

Here is the caller graph for this function: