LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ clabrd()

subroutine clabrd ( integer m,
integer n,
integer nb,
complex, dimension( lda, * ) a,
integer lda,
real, dimension( * ) d,
real, dimension( * ) e,
complex, dimension( * ) tauq,
complex, dimension( * ) taup,
complex, dimension( ldx, * ) x,
integer ldx,
complex, dimension( ldy, * ) y,
integer ldy )

CLABRD reduces the first nb rows and columns of a general matrix to a bidiagonal form.

Download CLABRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CLABRD reduces the first NB rows and columns of a complex general
!> m by n matrix A to upper or lower real bidiagonal form by a unitary
!> transformation Q**H * A * P, and returns the matrices X and Y which
!> are needed to apply the transformation to the unreduced part of A.
!>
!> If m >= n, A is reduced to upper bidiagonal form; if m < n, to lower
!> bidiagonal form.
!>
!> This is an auxiliary routine called by CGEBRD
!>
Parameters
[in]M
!>          M is INTEGER
!>          The number of rows in the matrix A.
!>
[in]N
!>          N is INTEGER
!>          The number of columns in the matrix A.
!>
[in]NB
!>          NB is INTEGER
!>          The number of leading rows and columns of A to be reduced.
!>
[in,out]A
!>          A is COMPLEX array, dimension (LDA,N)
!>          On entry, the m by n general matrix to be reduced.
!>          On exit, the first NB rows and columns of the matrix are
!>          overwritten; the rest of the array is unchanged.
!>          If m >= n, elements on and below the diagonal in the first NB
!>            columns, with the array TAUQ, represent the unitary
!>            matrix Q as a product of elementary reflectors; and
!>            elements above the diagonal in the first NB rows, with the
!>            array TAUP, represent the unitary matrix P as a product
!>            of elementary reflectors.
!>          If m < n, elements below the diagonal in the first NB
!>            columns, with the array TAUQ, represent the unitary
!>            matrix Q as a product of elementary reflectors, and
!>            elements on and above the diagonal in the first NB rows,
!>            with the array TAUP, represent the unitary matrix P as
!>            a product of elementary reflectors.
!>          See Further Details.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,M).
!>
[out]D
!>          D is REAL array, dimension (NB)
!>          The diagonal elements of the first NB rows and columns of
!>          the reduced matrix.  D(i) = A(i,i).
!>
[out]E
!>          E is REAL array, dimension (NB)
!>          The off-diagonal elements of the first NB rows and columns of
!>          the reduced matrix.
!>
[out]TAUQ
!>          TAUQ is COMPLEX array, dimension (NB)
!>          The scalar factors of the elementary reflectors which
!>          represent the unitary matrix Q. See Further Details.
!>
[out]TAUP
!>          TAUP is COMPLEX array, dimension (NB)
!>          The scalar factors of the elementary reflectors which
!>          represent the unitary matrix P. See Further Details.
!>
[out]X
!>          X is COMPLEX array, dimension (LDX,NB)
!>          The m-by-nb matrix X required to update the unreduced part
!>          of A.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X. LDX >= max(1,M).
!>
[out]Y
!>          Y is COMPLEX array, dimension (LDY,NB)
!>          The n-by-nb matrix Y required to update the unreduced part
!>          of A.
!>
[in]LDY
!>          LDY is INTEGER
!>          The leading dimension of the array Y. LDY >= max(1,N).
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The matrices Q and P are represented as products of elementary
!>  reflectors:
!>
!>     Q = H(1) H(2) . . . H(nb)  and  P = G(1) G(2) . . . G(nb)
!>
!>  Each H(i) and G(i) has the form:
!>
!>     H(i) = I - tauq * v * v**H  and G(i) = I - taup * u * u**H
!>
!>  where tauq and taup are complex scalars, and v and u are complex
!>  vectors.
!>
!>  If m >= n, v(1:i-1) = 0, v(i) = 1, and v(i:m) is stored on exit in
!>  A(i:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+1:n) is stored on exit in
!>  A(i,i+1:n); tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  If m < n, v(1:i) = 0, v(i+1) = 1, and v(i+1:m) is stored on exit in
!>  A(i+2:m,i); u(1:i-1) = 0, u(i) = 1, and u(i:n) is stored on exit in
!>  A(i,i+1:n); tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  The elements of the vectors v and u together form the m-by-nb matrix
!>  V and the nb-by-n matrix U**H which are needed, with X and Y, to apply
!>  the transformation to the unreduced part of the matrix, using a block
!>  update of the form:  A := A - V*Y**H - X*U**H.
!>
!>  The contents of A on exit are illustrated by the following examples
!>  with nb = 2:
!>
!>  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):
!>
!>    (  1   1   u1  u1  u1 )           (  1   u1  u1  u1  u1  u1 )
!>    (  v1  1   1   u2  u2 )           (  1   1   u2  u2  u2  u2 )
!>    (  v1  v2  a   a   a  )           (  v1  1   a   a   a   a  )
!>    (  v1  v2  a   a   a  )           (  v1  v2  a   a   a   a  )
!>    (  v1  v2  a   a   a  )           (  v1  v2  a   a   a   a  )
!>    (  v1  v2  a   a   a  )
!>
!>  where a denotes an element of the original matrix which is unchanged,
!>  vi denotes an element of the vector defining H(i), and ui an element
!>  of the vector defining G(i).
!>

Definition at line 208 of file clabrd.f.

211*
212* -- LAPACK auxiliary routine --
213* -- LAPACK is a software package provided by Univ. of Tennessee, --
214* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
215*
216* .. Scalar Arguments ..
217 INTEGER LDA, LDX, LDY, M, N, NB
218* ..
219* .. Array Arguments ..
220 REAL D( * ), E( * )
221 COMPLEX A( LDA, * ), TAUP( * ), TAUQ( * ), X( LDX, * ),
222 $ Y( LDY, * )
223* ..
224*
225* =====================================================================
226*
227* .. Parameters ..
228 COMPLEX ZERO, ONE
229 parameter( zero = ( 0.0e+0, 0.0e+0 ),
230 $ one = ( 1.0e+0, 0.0e+0 ) )
231* ..
232* .. Local Scalars ..
233 INTEGER I
234 COMPLEX ALPHA
235* ..
236* .. External Subroutines ..
237 EXTERNAL cgemv, clacgv, clarfg, cscal
238* ..
239* .. Intrinsic Functions ..
240 INTRINSIC min
241* ..
242* .. Executable Statements ..
243*
244* Quick return if possible
245*
246 IF( m.LE.0 .OR. n.LE.0 )
247 $ RETURN
248*
249 IF( m.GE.n ) THEN
250*
251* Reduce to upper bidiagonal form
252*
253 DO 10 i = 1, nb
254*
255* Update A(i:m,i)
256*
257 CALL clacgv( i-1, y( i, 1 ), ldy )
258 CALL cgemv( 'No transpose', m-i+1, i-1, -one, a( i, 1 ),
259 $ lda, y( i, 1 ), ldy, one, a( i, i ), 1 )
260 CALL clacgv( i-1, y( i, 1 ), ldy )
261 CALL cgemv( 'No transpose', m-i+1, i-1, -one, x( i, 1 ),
262 $ ldx, a( 1, i ), 1, one, a( i, i ), 1 )
263*
264* Generate reflection Q(i) to annihilate A(i+1:m,i)
265*
266 alpha = a( i, i )
267 CALL clarfg( m-i+1, alpha, a( min( i+1, m ), i ), 1,
268 $ tauq( i ) )
269 d( i ) = real( alpha )
270 IF( i.LT.n ) THEN
271 a( i, i ) = one
272*
273* Compute Y(i+1:n,i)
274*
275 CALL cgemv( 'Conjugate transpose', m-i+1, n-i, one,
276 $ a( i, i+1 ), lda, a( i, i ), 1, zero,
277 $ y( i+1, i ), 1 )
278 CALL cgemv( 'Conjugate transpose', m-i+1, i-1, one,
279 $ a( i, 1 ), lda, a( i, i ), 1, zero,
280 $ y( 1, i ), 1 )
281 CALL cgemv( 'No transpose', n-i, i-1, -one, y( i+1,
282 $ 1 ),
283 $ ldy, y( 1, i ), 1, one, y( i+1, i ), 1 )
284 CALL cgemv( 'Conjugate transpose', m-i+1, i-1, one,
285 $ x( i, 1 ), ldx, a( i, i ), 1, zero,
286 $ y( 1, i ), 1 )
287 CALL cgemv( 'Conjugate transpose', i-1, n-i, -one,
288 $ a( 1, i+1 ), lda, y( 1, i ), 1, one,
289 $ y( i+1, i ), 1 )
290 CALL cscal( n-i, tauq( i ), y( i+1, i ), 1 )
291*
292* Update A(i,i+1:n)
293*
294 CALL clacgv( n-i, a( i, i+1 ), lda )
295 CALL clacgv( i, a( i, 1 ), lda )
296 CALL cgemv( 'No transpose', n-i, i, -one, y( i+1, 1 ),
297 $ ldy, a( i, 1 ), lda, one, a( i, i+1 ), lda )
298 CALL clacgv( i, a( i, 1 ), lda )
299 CALL clacgv( i-1, x( i, 1 ), ldx )
300 CALL cgemv( 'Conjugate transpose', i-1, n-i, -one,
301 $ a( 1, i+1 ), lda, x( i, 1 ), ldx, one,
302 $ a( i, i+1 ), lda )
303 CALL clacgv( i-1, x( i, 1 ), ldx )
304*
305* Generate reflection P(i) to annihilate A(i,i+2:n)
306*
307 alpha = a( i, i+1 )
308 CALL clarfg( n-i, alpha, a( i, min( i+2, n ) ),
309 $ lda, taup( i ) )
310 e( i ) = real( alpha )
311 a( i, i+1 ) = one
312*
313* Compute X(i+1:m,i)
314*
315 CALL cgemv( 'No transpose', m-i, n-i, one, a( i+1,
316 $ i+1 ),
317 $ lda, a( i, i+1 ), lda, zero, x( i+1, i ), 1 )
318 CALL cgemv( 'Conjugate transpose', n-i, i, one,
319 $ y( i+1, 1 ), ldy, a( i, i+1 ), lda, zero,
320 $ x( 1, i ), 1 )
321 CALL cgemv( 'No transpose', m-i, i, -one, a( i+1, 1 ),
322 $ lda, x( 1, i ), 1, one, x( i+1, i ), 1 )
323 CALL cgemv( 'No transpose', i-1, n-i, one, a( 1,
324 $ i+1 ),
325 $ lda, a( i, i+1 ), lda, zero, x( 1, i ), 1 )
326 CALL cgemv( 'No transpose', m-i, i-1, -one, x( i+1,
327 $ 1 ),
328 $ ldx, x( 1, i ), 1, one, x( i+1, i ), 1 )
329 CALL cscal( m-i, taup( i ), x( i+1, i ), 1 )
330 CALL clacgv( n-i, a( i, i+1 ), lda )
331 END IF
332 10 CONTINUE
333 ELSE
334*
335* Reduce to lower bidiagonal form
336*
337 DO 20 i = 1, nb
338*
339* Update A(i,i:n)
340*
341 CALL clacgv( n-i+1, a( i, i ), lda )
342 CALL clacgv( i-1, a( i, 1 ), lda )
343 CALL cgemv( 'No transpose', n-i+1, i-1, -one, y( i, 1 ),
344 $ ldy, a( i, 1 ), lda, one, a( i, i ), lda )
345 CALL clacgv( i-1, a( i, 1 ), lda )
346 CALL clacgv( i-1, x( i, 1 ), ldx )
347 CALL cgemv( 'Conjugate transpose', i-1, n-i+1, -one,
348 $ a( 1, i ), lda, x( i, 1 ), ldx, one, a( i, i ),
349 $ lda )
350 CALL clacgv( i-1, x( i, 1 ), ldx )
351*
352* Generate reflection P(i) to annihilate A(i,i+1:n)
353*
354 alpha = a( i, i )
355 CALL clarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
356 $ taup( i ) )
357 d( i ) = real( alpha )
358 IF( i.LT.m ) THEN
359 a( i, i ) = one
360*
361* Compute X(i+1:m,i)
362*
363 CALL cgemv( 'No transpose', m-i, n-i+1, one, a( i+1,
364 $ i ),
365 $ lda, a( i, i ), lda, zero, x( i+1, i ), 1 )
366 CALL cgemv( 'Conjugate transpose', n-i+1, i-1, one,
367 $ y( i, 1 ), ldy, a( i, i ), lda, zero,
368 $ x( 1, i ), 1 )
369 CALL cgemv( 'No transpose', m-i, i-1, -one, a( i+1,
370 $ 1 ),
371 $ lda, x( 1, i ), 1, one, x( i+1, i ), 1 )
372 CALL cgemv( 'No transpose', i-1, n-i+1, one, a( 1,
373 $ i ),
374 $ lda, a( i, i ), lda, zero, x( 1, i ), 1 )
375 CALL cgemv( 'No transpose', m-i, i-1, -one, x( i+1,
376 $ 1 ),
377 $ ldx, x( 1, i ), 1, one, x( i+1, i ), 1 )
378 CALL cscal( m-i, taup( i ), x( i+1, i ), 1 )
379 CALL clacgv( n-i+1, a( i, i ), lda )
380*
381* Update A(i+1:m,i)
382*
383 CALL clacgv( i-1, y( i, 1 ), ldy )
384 CALL cgemv( 'No transpose', m-i, i-1, -one, a( i+1,
385 $ 1 ),
386 $ lda, y( i, 1 ), ldy, one, a( i+1, i ), 1 )
387 CALL clacgv( i-1, y( i, 1 ), ldy )
388 CALL cgemv( 'No transpose', m-i, i, -one, x( i+1, 1 ),
389 $ ldx, a( 1, i ), 1, one, a( i+1, i ), 1 )
390*
391* Generate reflection Q(i) to annihilate A(i+2:m,i)
392*
393 alpha = a( i+1, i )
394 CALL clarfg( m-i, alpha, a( min( i+2, m ), i ), 1,
395 $ tauq( i ) )
396 e( i ) = real( alpha )
397 a( i+1, i ) = one
398*
399* Compute Y(i+1:n,i)
400*
401 CALL cgemv( 'Conjugate transpose', m-i, n-i, one,
402 $ a( i+1, i+1 ), lda, a( i+1, i ), 1, zero,
403 $ y( i+1, i ), 1 )
404 CALL cgemv( 'Conjugate transpose', m-i, i-1, one,
405 $ a( i+1, 1 ), lda, a( i+1, i ), 1, zero,
406 $ y( 1, i ), 1 )
407 CALL cgemv( 'No transpose', n-i, i-1, -one, y( i+1,
408 $ 1 ),
409 $ ldy, y( 1, i ), 1, one, y( i+1, i ), 1 )
410 CALL cgemv( 'Conjugate transpose', m-i, i, one,
411 $ x( i+1, 1 ), ldx, a( i+1, i ), 1, zero,
412 $ y( 1, i ), 1 )
413 CALL cgemv( 'Conjugate transpose', i, n-i, -one,
414 $ a( 1, i+1 ), lda, y( 1, i ), 1, one,
415 $ y( i+1, i ), 1 )
416 CALL cscal( n-i, tauq( i ), y( i+1, i ), 1 )
417 ELSE
418 CALL clacgv( n-i+1, a( i, i ), lda )
419 END IF
420 20 CONTINUE
421 END IF
422 RETURN
423*
424* End of CLABRD
425*
cgemv
subroutine cgemv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
CGEMV
Definition cgemv.f:160
clacgv
subroutine clacgv(n, x, incx)
CLACGV conjugates a complex vector.
Definition clacgv.f:72
clarfg
subroutine clarfg(n, alpha, x, incx, tau)
CLARFG generates an elementary reflector (Householder matrix).
Definition clarfg.f:104
cscal
subroutine cscal(n, ca, cx, incx)
CSCAL
Definition cscal.f:78
Here is the call graph for this function:
Here is the caller graph for this function: