dlaic1.f

Go to the documentation of this file.

*> \brief \b DLAIC1 applies one step of incremental condition estimation.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download DLAIC1 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlaic1.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlaic1.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlaic1.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLAIC1( JOB, J, X, SEST, W, GAMMA, SESTPR, S, C )
*
*       .. Scalar Arguments ..
*       INTEGER            J, JOB
*       DOUBLE PRECISION   C, GAMMA, S, SEST, SESTPR
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   W( J ), X( J )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLAIC1 applies one step of incremental condition estimation in
*> its simplest version:
*>
*> Let x, twonorm(x) = 1, be an approximate singular vector of an j-by-j
*> lower triangular matrix L, such that
*>          twonorm(L*x) = sest
*> Then DLAIC1 computes sestpr, s, c such that
*> the vector
*>                 [ s*x ]
*>          xhat = [  c  ]
*> is an approximate singular vector of
*>                 [ L       0  ]
*>          Lhat = [ w**T gamma ]
*> in the sense that
*>          twonorm(Lhat*xhat) = sestpr.
*>
*> Depending on JOB, an estimate for the largest or smallest singular
*> value is computed.
*>
*> Note that [s c]**T and sestpr**2 is an eigenpair of the system
*>
*>     diag(sest*sest, 0) + [alpha  gamma] * [ alpha ]
*>                                           [ gamma ]
*>
*> where  alpha =  x**T*w.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] JOB
*> \verbatim
*>          JOB is INTEGER
*>          = 1: an estimate for the largest singular value is computed.
*>          = 2: an estimate for the smallest singular value is computed.
*> \endverbatim
*>
*> \param[in] J
*> \verbatim
*>          J is INTEGER
*>          Length of X and W
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension (J)
*>          The j-vector x.
*> \endverbatim
*>
*> \param[in] SEST
*> \verbatim
*>          SEST is DOUBLE PRECISION
*>          Estimated singular value of j by j matrix L
*> \endverbatim
*>
*> \param[in] W
*> \verbatim
*>          W is DOUBLE PRECISION array, dimension (J)
*>          The j-vector w.
*> \endverbatim
*>
*> \param[in] GAMMA
*> \verbatim
*>          GAMMA is DOUBLE PRECISION
*>          The diagonal element gamma.
*> \endverbatim
*>
*> \param[out] SESTPR
*> \verbatim
*>          SESTPR is DOUBLE PRECISION
*>          Estimated singular value of (j+1) by (j+1) matrix Lhat.
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION
*>          Sine needed in forming xhat.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is DOUBLE PRECISION
*>          Cosine needed in forming xhat.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup laic1
*
*  =====================================================================
      SUBROUTINE dlaic1( JOB, J, X, SEST, W, GAMMA, SESTPR, S, C )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            J, JOB
      DOUBLE PRECISION   C, GAMMA, S, SEST, SESTPR
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   W( J ), X( J )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO
      parameter( zero = 0.0d0, one = 1.0d0, two = 2.0d0 )
      DOUBLE PRECISION   HALF, FOUR
      parameter( half = 0.5d0, four = 4.0d0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ABSALP, ABSEST, ABSGAM, ALPHA, B, COSINE, EPS,
     $                   NORMA, S1, S2, SINE, T, TEST, TMP, ZETA1, ZETA2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sign, sqrt
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DDOT, DLAMCH
      EXTERNAL           ddot, dlamch
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      alpha = ddot( j, x, 1, w, 1 )
*
      absalp = abs( alpha )
      absgam = abs( gamma )
      absest = abs( sest )
*
      IF( job.EQ.1 ) THEN
*
*        Estimating largest singular value
*
*        special cases
*
         IF( sest.EQ.zero ) THEN
            s1 = max( absgam, absalp )
            IF( s1.EQ.zero ) THEN
               s = zero
               c = one
               sestpr = zero
            ELSE
               s = alpha / s1
               c = gamma / s1
               tmp = sqrt( s*s+c*c )
               s = s / tmp
               c = c / tmp
               sestpr = s1*tmp
            END IF
            RETURN
         ELSE IF( absgam.LE.eps*absest ) THEN
            s = one
            c = zero
            tmp = max( absest, absalp )
            s1 = absest / tmp
            s2 = absalp / tmp
            sestpr = tmp*sqrt( s1*s1+s2*s2 )
            RETURN
         ELSE IF( absalp.LE.eps*absest ) THEN
            s1 = absgam
            s2 = absest
            IF( s1.LE.s2 ) THEN
               s = one
               c = zero
               sestpr = s2
            ELSE
               s = zero
               c = one
               sestpr = s1
            END IF
            RETURN
         ELSE IF( absest.LE.eps*absalp .OR. absest.LE.eps*absgam ) THEN
            s1 = absgam
            s2 = absalp
            IF( s1.LE.s2 ) THEN
               tmp = s1 / s2
               s = sqrt( one+tmp*tmp )
               sestpr = s2*s
               c = ( gamma / s2 ) / s
               s = sign( one, alpha ) / s
            ELSE
               tmp = s2 / s1
               c = sqrt( one+tmp*tmp )
               sestpr = s1*c
               s = ( alpha / s1 ) / c
               c = sign( one, gamma ) / c
            END IF
            RETURN
         ELSE
*
*           normal case
*
            zeta1 = alpha / absest
            zeta2 = gamma / absest
*
            b = ( one-zeta1*zeta1-zeta2*zeta2 )*half
            c = zeta1*zeta1
            IF( b.GT.zero ) THEN
               t = c / ( b+sqrt( b*b+c ) )
            ELSE
               t = sqrt( b*b+c ) - b
            END IF
*
            sine = -zeta1 / t
            cosine = -zeta2 / ( one+t )
            tmp = sqrt( sine*sine+cosine*cosine )
            s = sine / tmp
            c = cosine / tmp
            sestpr = sqrt( t+one )*absest
            RETURN
         END IF
*
      ELSE IF( job.EQ.2 ) THEN
*
*        Estimating smallest singular value
*
*        special cases
*
         IF( sest.EQ.zero ) THEN
            sestpr = zero
            IF( max( absgam, absalp ).EQ.zero ) THEN
               sine = one
               cosine = zero
            ELSE
               sine = -gamma
               cosine = alpha
            END IF
            s1 = max( abs( sine ), abs( cosine ) )
            s = sine / s1
            c = cosine / s1
            tmp = sqrt( s*s+c*c )
            s = s / tmp
            c = c / tmp
            RETURN
         ELSE IF( absgam.LE.eps*absest ) THEN
            s = zero
            c = one
            sestpr = absgam
            RETURN
         ELSE IF( absalp.LE.eps*absest ) THEN
            s1 = absgam
            s2 = absest
            IF( s1.LE.s2 ) THEN
               s = zero
               c = one
               sestpr = s1
            ELSE
               s = one
               c = zero
               sestpr = s2
            END IF
            RETURN
         ELSE IF( absest.LE.eps*absalp .OR. absest.LE.eps*absgam ) THEN
            s1 = absgam
            s2 = absalp
            IF( s1.LE.s2 ) THEN
               tmp = s1 / s2
               c = sqrt( one+tmp*tmp )
               sestpr = absest*( tmp / c )
               s = -( gamma / s2 ) / c
               c = sign( one, alpha ) / c
            ELSE
               tmp = s2 / s1
               s = sqrt( one+tmp*tmp )
               sestpr = absest / s
               c = ( alpha / s1 ) / s
               s = -sign( one, gamma ) / s
            END IF
            RETURN
         ELSE
*
*           normal case
*
            zeta1 = alpha / absest
            zeta2 = gamma / absest
*
            norma = max( one+zeta1*zeta1+abs( zeta1*zeta2 ),
     $              abs( zeta1*zeta2 )+zeta2*zeta2 )
*
*           See if root is closer to zero or to ONE
*
            test = one + two*( zeta1-zeta2 )*( zeta1+zeta2 )
            IF( test.GE.zero ) THEN
*
*              root is close to zero, compute directly
*
               b = ( zeta1*zeta1+zeta2*zeta2+one )*half
               c = zeta2*zeta2
               t = c / ( b+sqrt( abs( b*b-c ) ) )
               sine = zeta1 / ( one-t )
               cosine = -zeta2 / t
               sestpr = sqrt( t+four*eps*eps*norma )*absest
            ELSE
*
*              root is closer to ONE, shift by that amount
*
               b = ( zeta2*zeta2+zeta1*zeta1-one )*half
               c = zeta1*zeta1
               IF( b.GE.zero ) THEN
                  t = -c / ( b+sqrt( b*b+c ) )
               ELSE
                  t = b - sqrt( b*b+c )
               END IF
               sine = -zeta1 / t
               cosine = -zeta2 / ( one+t )
               sestpr = sqrt( one+t+four*eps*eps*norma )*absest
            END IF
            tmp = sqrt( sine*sine+cosine*cosine )
            s = sine / tmp
            c = cosine / tmp
            RETURN
*
         END IF
      END IF
      RETURN
*
*     End of DLAIC1
*
      END