ctpcon()

subroutine ctpcon	(	character	norm,
		character	uplo,
		character	diag,
		integer	n,
		complex, dimension( * )	ap,
		real	rcond,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	info )

CTPCON

Download CTPCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CTPCON estimates the reciprocal of the condition number of a packed
!> triangular matrix A, in either the 1-norm or the infinity-norm.
!>
!> The norm of A is computed and an estimate is obtained for
!> norm(inv(A)), then the reciprocal of the condition number is
!> computed as
!>    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
!> 

Parameters

[in]	NORM	!> NORM is CHARACTER*1 !> Specifies whether the 1-norm condition number or the !> infinity-norm condition number is required: !> = '1' or 'O': 1-norm; !> = 'I': Infinity-norm. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': A is upper triangular; !> = 'L': A is lower triangular. !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> = 'N': A is non-unit triangular; !> = 'U': A is unit triangular. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	AP	!> AP is COMPLEX array, dimension (N*(N+1)/2) !> The upper or lower triangular matrix A, packed columnwise in !> a linear array. The j-th column of A is stored in the array !> AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. !> If DIAG = 'U', the diagonal elements of A are not referenced !> and are assumed to be 1. !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal of the condition number of the matrix A, !> computed as RCOND = 1/(norm(A) * norm(inv(A))). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*N) !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 126 of file ctpcon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, NORM, UPLO
      INTEGER            INFO, N
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            AP( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, ONENRM, UPPER
      CHARACTER          NORMIN
      INTEGER            IX, KASE, KASE1
      REAL               AINVNM, ANORM, SCALE, SMLNUM, XNORM
      COMPLEX            ZDUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               CLANTP, SLAMCH
      EXTERNAL           lsame, icamax, clantp, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacn2, clatps, csrscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTPCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      END IF
*
      rcond = zero
      smlnum = slamch( 'Safe minimum' )*real( max( 1, n ) )
*
*     Compute the norm of the triangular matrix A.
*
      anorm = clantp( norm, uplo, diag, n, ap, rwork )
*
*     Continue only if ANORM > 0.
*
      IF( anorm.GT.zero ) THEN
*
*        Estimate the norm of the inverse of A.
*
         ainvnm = zero
         normin = 'N'
         IF( onenrm ) THEN
            kase1 = 1
         ELSE
            kase1 = 2
         END IF
         kase = 0
   10    CONTINUE
         CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.kase1 ) THEN
*
*              Multiply by inv(A).
*
               CALL clatps( uplo, 'No transpose', diag, normin, n,
     $                      ap,
     $                      work, scale, rwork, info )
            ELSE
*
*              Multiply by inv(A**H).
*
               CALL clatps( uplo, 'Conjugate transpose', diag,
     $                      normin,
     $                      n, ap, work, scale, rwork, info )
            END IF
            normin = 'Y'
*
*           Multiply by 1/SCALE if doing so will not cause overflow.
*
            IF( scale.NE.one ) THEN
               ix = icamax( n, work, 1 )
               xnorm = cabs1( work( ix ) )
               IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
     $            GO TO 20
               CALL csrscl( n, scale, work, 1 )
            END IF
            GO TO 10
         END IF
*
*        Compute the estimate of the reciprocal condition number.
*
         IF( ainvnm.NE.zero )
     $      rcond = ( one / anorm ) / ainvnm
      END IF
*
   20 CONTINUE
      RETURN
*
*     End of CTPCON
*

Here is the call graph for this function:

Here is the caller graph for this function: