cheswapr()

subroutine cheswapr	(	character	uplo,
		integer	n,
		complex, dimension( lda, n )	a,
		integer	lda,
		integer	i1,
		integer	i2 )

CHESWAPR applies an elementary permutation on the rows and columns of a Hermitian matrix.

Download CHESWAPR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHESWAPR applies an elementary permutation on the rows and the columns of
!> a hermitian matrix.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the details of the factorization are stored !> as an upper or lower triangular matrix. !> = 'U': Upper triangular, form is A = U*D*U**T; !> = 'L': Lower triangular, form is A = L*D*L**T. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the NB diagonal matrix D and the multipliers !> used to obtain the factor U or L as computed by CSYTRF. !> !> On exit, if INFO = 0, the (symmetric) inverse of the original !> matrix. If UPLO = 'U', the upper triangular part of the !> inverse is formed and the part of A below the diagonal is not !> referenced; if UPLO = 'L' the lower triangular part of the !> inverse is formed and the part of A above the diagonal is !> not referenced. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	I1	!> I1 is INTEGER !> Index of the first row to swap !>
[in]	I2	!> I2 is INTEGER !> Index of the second row to swap !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 99 of file cheswapr.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER        UPLO
      INTEGER          I1, I2, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX          A( LDA, N )
*
*  =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I
      COMPLEX            TMP
*
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cswap
*     ..
*     .. Executable Statements ..
*
      upper = lsame( uplo, 'U' )
      IF (upper) THEN
*
*         UPPER
*         first swap
*          - swap column I1 and I2 from I1 to I1-1
         CALL cswap( i1-1, a(1,i1), 1, a(1,i2), 1 )
*
*          second swap :
*          - swap A(I1,I1) and A(I2,I2)
*          - swap row I1 from I1+1 to I2-1 with col I2 from I1+1 to I2-1
*          - swap A(I2,I1) and A(I1,I2)
 
         tmp=a(i1,i1)
         a(i1,i1)=a(i2,i2)
         a(i2,i2)=tmp
*
         DO i=1,i2-i1-1
            tmp=a(i1,i1+i)
            a(i1,i1+i)=conjg(a(i1+i,i2))
            a(i1+i,i2)=conjg(tmp)
         END DO
*
          a(i1,i2)=conjg(a(i1,i2))
 
*
*          third swap
*          - swap row I1 and I2 from I2+1 to N
         DO i=i2+1,n
            tmp=a(i1,i)
            a(i1,i)=a(i2,i)
            a(i2,i)=tmp
         END DO
*
        ELSE
*
*         LOWER
*         first swap
*          - swap row I1 and I2 from 1 to I1-1
         CALL cswap ( i1-1, a(i1,1), lda, a(i2,1), lda )
*
*         second swap :
*          - swap A(I1,I1) and A(I2,I2)
*          - swap col I1 from I1+1 to I2-1 with row I2 from I1+1 to I2-1
*          - swap A(I2,I1) and A(I1,I2)
 
          tmp=a(i1,i1)
          a(i1,i1)=a(i2,i2)
          a(i2,i2)=tmp
*
          DO i=1,i2-i1-1
             tmp=a(i1+i,i1)
             a(i1+i,i1)=conjg(a(i2,i1+i))
             a(i2,i1+i)=conjg(tmp)
          END DO
*
          a(i2,i1)=conjg(a(i2,i1))
*
*         third swap
*          - swap col I1 and I2 from I2+1 to N
          DO i=i2+1,n
             tmp=a(i,i1)
             a(i,i1)=a(i,i2)
             a(i,i2)=tmp
          END DO
*
      ENDIF
 

Here is the call graph for this function:

Here is the caller graph for this function: