sqpt01()

real function sqpt01	(	integer	M,
		integer	N,
		integer	K,
		real, dimension( lda, * )	A,
		real, dimension( lda, * )	AF,
		integer	LDA,
		real, dimension( * )	TAU,
		integer, dimension( * )	JPVT,
		real, dimension( lwork )	WORK,
		integer	LWORK
	)

SQPT01

Purpose:

 SQPT01 tests the QR-factorization with pivoting of a matrix A.  The
 array AF contains the (possibly partial) QR-factorization of A, where
 the upper triangle of AF(1:k,1:k) is a partial triangular factor,
 the entries below the diagonal in the first k columns are the
 Householder vectors, and the rest of AF contains a partially updated
 matrix.

 This function returns ||A*P - Q*R||/(||norm(A)||*eps*M)

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	K	K is INTEGER The number of columns of AF that have been reduced to upper triangular form.
[in]	A	A is REAL array, dimension (LDA, N) The original matrix A.
[in]	AF	AF is REAL array, dimension (LDA,N) The (possibly partial) output of SGEQPF. The upper triangle of AF(1:k,1:k) is a partial triangular factor, the entries below the diagonal in the first k columns are the Householder vectors, and the rest of AF contains a partially updated matrix.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is REAL array, dimension (K) Details of the Householder transformations as returned by SGEQPF.
[in]	JPVT	JPVT is INTEGER array, dimension (N) Pivot information as returned by SGEQPF.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*N+N.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 118 of file sqpt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            JPVT( * )
      REAL               A( LDA, * ), AF( LDA, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      REAL               NORMA
*     ..
*     .. Local Arrays ..
      REAL               RWORK( 1 )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, sormqr, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      sqpt01 = zero
*
*     Test if there is enough workspace
*
      IF( lwork.LT.m*n+n ) THEN
         CALL xerbla( 'SQPT01', 10 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = slange( 'One-norm', m, n, a, lda, rwork )
*
      DO 30 j = 1, k
         DO 10 i = 1, min( j, m )
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
         DO 20 i = j + 1, m
            work( ( j-1 )*m+i ) = zero
   20    CONTINUE
   30 CONTINUE
      DO 40 j = k + 1, n
         CALL scopy( m, af( 1, j ), 1, work( ( j-1 )*m+1 ), 1 )
   40 CONTINUE
*
      CALL sormqr( 'Left', 'No transpose', m, n, k, af, lda, tau, work,
     $             m, work( m*n+1 ), lwork-m*n, info )
*
      DO 50 j = 1, n
*
*        Compare i-th column of QR and jpvt(i)-th column of A
*
         CALL saxpy( m, -one, a( 1, jpvt( j ) ), 1, work( ( j-1 )*m+1 ),
     $               1 )
   50 CONTINUE
*
      sqpt01 = slange( 'One-norm', m, n, work, m, rwork ) /
     $         ( real( max( m, n ) )*slamch( 'Epsilon' ) )
      IF( norma.NE.zero )
     $   sqpt01 = sqpt01 / norma
*
      RETURN
*
*     End of SQPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: