ctbrfs()

subroutine ctbrfs	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	kd,
		integer	nrhs,
		complex, dimension( ldab, * )	ab,
		integer	ldab,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	info )

CTBRFS

Download CTBRFS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CTBRFS provides error bounds and backward error estimates for the
!> solution to a system of linear equations with a triangular band
!> coefficient matrix.
!>
!> The solution matrix X must be computed by CTBTRS or some other
!> means before entering this routine.  CTBRFS does not do iterative
!> refinement because doing so cannot improve the backward error.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': A is upper triangular; !> = 'L': A is lower triangular. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations: !> = 'N': A * X = B (No transpose) !> = 'T': A**T * X = B (Transpose) !> = 'C': A**H * X = B (Conjugate transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> = 'N': A is non-unit triangular; !> = 'U': A is unit triangular. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of superdiagonals or subdiagonals of the !> triangular band matrix A. KD >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in]	AB	!> AB is COMPLEX array, dimension (LDAB,N) !> The upper or lower triangular band matrix A, stored in the !> first kd+1 rows of the array. The j-th column of A is stored !> in the j-th column of the array AB as follows: !> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; !> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). !> If DIAG = 'U', the diagonal elements of A are not referenced !> and are assumed to be 1. !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KD+1. !>
[in]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> The right hand side matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	X	!> X is COMPLEX array, dimension (LDX,NRHS) !> The solution matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[out]	FERR	!> FERR is REAL array, dimension (NRHS) !> The estimated forward error bound for each solution vector !> X(j) (the j-th column of the solution matrix X). !> If XTRUE is the true solution corresponding to X(j), FERR(j) !> is an estimated upper bound for the magnitude of the largest !> element in (X(j) - XTRUE) divided by the magnitude of the !> largest element in X(j). The estimate is as reliable as !> the estimate for RCOND, and is almost always a slight !> overestimate of the true error. !>
[out]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector X(j) (i.e., the smallest relative change in !> any element of A or B that makes X(j) an exact solution). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*N) !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 184 of file ctbrfs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            INFO, KD, LDAB, LDB, LDX, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               BERR( * ), FERR( * ), RWORK( * )
      COMPLEX            AB( LDAB, * ), B( LDB, * ), WORK( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN, NOUNIT, UPPER
      CHARACTER          TRANSN, TRANST
      INTEGER            I, J, K, KASE, NZ
      REAL               EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
      COMPLEX            ZDUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, ccopy, clacn2, ctbmv, ctbsv,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, min, real
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH
      EXTERNAL           lsame, slamch
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
     $         lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( kd.LT.0 ) THEN
         info = -5
      ELSE IF( nrhs.LT.0 ) THEN
         info = -6
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -8
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -10
      ELSE IF( ldx.LT.max( 1, n ) ) THEN
         info = -12
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTBRFS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
         DO 10 j = 1, nrhs
            ferr( j ) = zero
            berr( j ) = zero
   10    CONTINUE
         RETURN
      END IF
*
      IF( notran ) THEN
         transn = 'N'
         transt = 'C'
      ELSE
         transn = 'C'
         transt = 'N'
      END IF
*
*     NZ = maximum number of nonzero elements in each row of A, plus 1
*
      nz = kd + 2
      eps = slamch( 'Epsilon' )
      safmin = slamch( 'Safe minimum' )
      safe1 = real( nz )*safmin
      safe2 = safe1 / eps
*
*     Do for each right hand side
*
      DO 250 j = 1, nrhs
*
*        Compute residual R = B - op(A) * X,
*        where op(A) = A, A**T, or A**H, depending on TRANS.
*
         CALL ccopy( n, x( 1, j ), 1, work, 1 )
         CALL ctbmv( uplo, trans, diag, n, kd, ab, ldab, work, 1 )
         CALL caxpy( n, -one, b( 1, j ), 1, work, 1 )
*
*        Compute componentwise relative backward error from formula
*
*        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
*
*        where abs(Z) is the componentwise absolute value of the matrix
*        or vector Z.  If the i-th component of the denominator is less
*        than SAFE2, then SAFE1 is added to the i-th components of the
*        numerator and denominator before dividing.
*
         DO 20 i = 1, n
            rwork( i ) = cabs1( b( i, j ) )
   20    CONTINUE
*
         IF( notran ) THEN
*
*           Compute abs(A)*abs(X) + abs(B).
*
            IF( upper ) THEN
               IF( nounit ) THEN
                  DO 40 k = 1, n
                     xk = cabs1( x( k, j ) )
                     DO 30 i = max( 1, k-kd ), k
                        rwork( i ) = rwork( i ) +
     $                               cabs1( ab( kd+1+i-k, k ) )*xk
   30                CONTINUE
   40             CONTINUE
               ELSE
                  DO 60 k = 1, n
                     xk = cabs1( x( k, j ) )
                     DO 50 i = max( 1, k-kd ), k - 1
                        rwork( i ) = rwork( i ) +
     $                               cabs1( ab( kd+1+i-k, k ) )*xk
   50                CONTINUE
                     rwork( k ) = rwork( k ) + xk
   60             CONTINUE
               END IF
            ELSE
               IF( nounit ) THEN
                  DO 80 k = 1, n
                     xk = cabs1( x( k, j ) )
                     DO 70 i = k, min( n, k+kd )
                        rwork( i ) = rwork( i ) +
     $                               cabs1( ab( 1+i-k, k ) )*xk
   70                CONTINUE
   80             CONTINUE
               ELSE
                  DO 100 k = 1, n
                     xk = cabs1( x( k, j ) )
                     DO 90 i = k + 1, min( n, k+kd )
                        rwork( i ) = rwork( i ) +
     $                               cabs1( ab( 1+i-k, k ) )*xk
   90                CONTINUE
                     rwork( k ) = rwork( k ) + xk
  100             CONTINUE
               END IF
            END IF
         ELSE
*
*           Compute abs(A**H)*abs(X) + abs(B).
*
            IF( upper ) THEN
               IF( nounit ) THEN
                  DO 120 k = 1, n
                     s = zero
                     DO 110 i = max( 1, k-kd ), k
                        s = s + cabs1( ab( kd+1+i-k, k ) )*
     $                      cabs1( x( i, j ) )
  110                CONTINUE
                     rwork( k ) = rwork( k ) + s
  120             CONTINUE
               ELSE
                  DO 140 k = 1, n
                     s = cabs1( x( k, j ) )
                     DO 130 i = max( 1, k-kd ), k - 1
                        s = s + cabs1( ab( kd+1+i-k, k ) )*
     $                      cabs1( x( i, j ) )
  130                CONTINUE
                     rwork( k ) = rwork( k ) + s
  140             CONTINUE
               END IF
            ELSE
               IF( nounit ) THEN
                  DO 160 k = 1, n
                     s = zero
                     DO 150 i = k, min( n, k+kd )
                        s = s + cabs1( ab( 1+i-k, k ) )*
     $                      cabs1( x( i, j ) )
  150                CONTINUE
                     rwork( k ) = rwork( k ) + s
  160             CONTINUE
               ELSE
                  DO 180 k = 1, n
                     s = cabs1( x( k, j ) )
                     DO 170 i = k + 1, min( n, k+kd )
                        s = s + cabs1( ab( 1+i-k, k ) )*
     $                      cabs1( x( i, j ) )
  170                CONTINUE
                     rwork( k ) = rwork( k ) + s
  180             CONTINUE
               END IF
            END IF
         END IF
         s = zero
         DO 190 i = 1, n
            IF( rwork( i ).GT.safe2 ) THEN
               s = max( s, cabs1( work( i ) ) / rwork( i ) )
            ELSE
               s = max( s, ( cabs1( work( i ) )+safe1 ) /
     $             ( rwork( i )+safe1 ) )
            END IF
  190    CONTINUE
         berr( j ) = s
*
*        Bound error from formula
*
*        norm(X - XTRUE) / norm(X) .le. FERR =
*        norm( abs(inv(op(A)))*
*           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
*
*        where
*          norm(Z) is the magnitude of the largest component of Z
*          inv(op(A)) is the inverse of op(A)
*          abs(Z) is the componentwise absolute value of the matrix or
*             vector Z
*          NZ is the maximum number of nonzeros in any row of A, plus 1
*          EPS is machine epsilon
*
*        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
*        is incremented by SAFE1 if the i-th component of
*        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
*
*        Use CLACN2 to estimate the infinity-norm of the matrix
*           inv(op(A)) * diag(W),
*        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
*
         DO 200 i = 1, n
            IF( rwork( i ).GT.safe2 ) THEN
               rwork( i ) = cabs1( work( i ) ) + real( nz )*
     $                      eps*rwork( i )
            ELSE
               rwork( i ) = cabs1( work( i ) ) + real( nz )*
     $                      eps*rwork( i ) + safe1
            END IF
  200    CONTINUE
*
         kase = 0
  210    CONTINUE
         CALL clacn2( n, work( n+1 ), work, ferr( j ), kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.1 ) THEN
*
*              Multiply by diag(W)*inv(op(A)**H).
*
               CALL ctbsv( uplo, transt, diag, n, kd, ab, ldab, work,
     $                     1 )
               DO 220 i = 1, n
                  work( i ) = rwork( i )*work( i )
  220          CONTINUE
            ELSE
*
*              Multiply by inv(op(A))*diag(W).
*
               DO 230 i = 1, n
                  work( i ) = rwork( i )*work( i )
  230          CONTINUE
               CALL ctbsv( uplo, transn, diag, n, kd, ab, ldab, work,
     $                     1 )
            END IF
            GO TO 210
         END IF
*
*        Normalize error.
*
         lstres = zero
         DO 240 i = 1, n
            lstres = max( lstres, cabs1( x( i, j ) ) )
  240    CONTINUE
         IF( lstres.NE.zero )
     $      ferr( j ) = ferr( j ) / lstres
*
  250 CONTINUE
*
      RETURN
*
*     End of CTBRFS
*

Here is the call graph for this function:

Here is the caller graph for this function: