zgbmv()

subroutine zgbmv	(	character	trans,
		integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		complex*16	alpha,
		complex*16, dimension(lda,*)	a,
		integer	lda,
		complex*16, dimension(*)	x,
		integer	incx,
		complex*16	beta,
		complex*16, dimension(*)	y,
		integer	incy )

ZGBMV

Purpose:

!>
!> ZGBMV  performs one of the matrix-vector operations
!>
!>    y := alpha*A*x + beta*y,   or   y := alpha*A**T*x + beta*y,   or
!>
!>    y := alpha*A**H*x + beta*y,
!>
!> where alpha and beta are scalars, x and y are vectors and A is an
!> m by n band matrix, with kl sub-diagonals and ku super-diagonals.
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> On entry, TRANS specifies the operation to be performed as !> follows: !> !> TRANS = 'N' or 'n' y := alpha*A*x + beta*y. !> !> TRANS = 'T' or 't' y := alpha*A**T*x + beta*y. !> !> TRANS = 'C' or 'c' y := alpha*A**H*x + beta*y. !>
[in]	M	!> M is INTEGER !> On entry, M specifies the number of rows of the matrix A. !> M must be at least zero. !>
[in]	N	!> N is INTEGER !> On entry, N specifies the number of columns of the matrix A. !> N must be at least zero. !>
[in]	KL	!> KL is INTEGER !> On entry, KL specifies the number of sub-diagonals of the !> matrix A. KL must satisfy 0 .le. KL. !>
[in]	KU	!> KU is INTEGER !> On entry, KU specifies the number of super-diagonals of the !> matrix A. KU must satisfy 0 .le. KU. !>
[in]	ALPHA	!> ALPHA is COMPLEX*16 !> On entry, ALPHA specifies the scalar alpha. !>
[in]	A	!> A is COMPLEX*16 array, dimension ( LDA, N ) !> Before entry, the leading ( kl + ku + 1 ) by n part of the !> array A must contain the matrix of coefficients, supplied !> column by column, with the leading diagonal of the matrix in !> row ( ku + 1 ) of the array, the first super-diagonal !> starting at position 2 in row ku, the first sub-diagonal !> starting at position 1 in row ( ku + 2 ), and so on. !> Elements in the array A that do not correspond to elements !> in the band matrix (such as the top left ku by ku triangle) !> are not referenced. !> The following program segment will transfer a band matrix !> from conventional full matrix storage to band storage: !> !> DO 20, J = 1, N !> K = KU + 1 - J !> DO 10, I = MAX( 1, J - KU ), MIN( M, J + KL ) !> A( K + I, J ) = matrix( I, J ) !> 10 CONTINUE !> 20 CONTINUE !>
[in]	LDA	!> LDA is INTEGER !> On entry, LDA specifies the first dimension of A as declared !> in the calling (sub) program. LDA must be at least !> ( kl + ku + 1 ). !>
[in]	X	!> X is COMPLEX*16 array, dimension at least !> ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n' !> and at least !> ( 1 + ( m - 1 )*abs( INCX ) ) otherwise. !> Before entry, the incremented array X must contain the !> vector x. !>
[in]	INCX	!> INCX is INTEGER !> On entry, INCX specifies the increment for the elements of !> X. INCX must not be zero. !>
[in]	BETA	!> BETA is COMPLEX*16 !> On entry, BETA specifies the scalar beta. When BETA is !> supplied as zero then Y need not be set on input. !>
[in,out]	Y	!> Y is COMPLEX*16 array, dimension at least !> ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n' !> and at least !> ( 1 + ( n - 1 )*abs( INCY ) ) otherwise. !> Before entry, the incremented array Y must contain the !> vector y. On exit, Y is overwritten by the updated vector y. !> If either m or n is zero, then Y not referenced and the function !> performs a quick return. !>
[in]	INCY	!> INCY is INTEGER !> On entry, INCY specifies the increment for the elements of !> Y. INCY must not be zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  Level 2 Blas routine.
!>  The vector and matrix arguments are not referenced when N = 0, or M = 0
!>
!>  -- Written on 22-October-1986.
!>     Jack Dongarra, Argonne National Lab.
!>     Jeremy Du Croz, Nag Central Office.
!>     Sven Hammarling, Nag Central Office.
!>     Richard Hanson, Sandia National Labs.
!> 

Definition at line 188 of file zgbmv.f.

*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      COMPLEX*16 ALPHA,BETA
      INTEGER INCX,INCY,KL,KU,LDA,M,N
      CHARACTER TRANS
*     ..
*     .. Array Arguments ..
      COMPLEX*16 A(LDA,*),X(*),Y(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16 ONE
      parameter(one= (1.0d+0,0.0d+0))
      COMPLEX*16 ZERO
      parameter(zero= (0.0d+0,0.0d+0))
*     ..
*     .. Local Scalars ..
      COMPLEX*16 TEMP
      INTEGER I,INFO,IX,IY,J,JX,JY,K,KUP1,KX,KY,LENX,LENY
      LOGICAL NOCONJ
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC dconjg,max,min
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
     +    .NOT.lsame(trans,'C')) THEN
          info = 1
      ELSE IF (m.LT.0) THEN
          info = 2
      ELSE IF (n.LT.0) THEN
          info = 3
      ELSE IF (kl.LT.0) THEN
          info = 4
      ELSE IF (ku.LT.0) THEN
          info = 5
      ELSE IF (lda.LT. (kl+ku+1)) THEN
          info = 8
      ELSE IF (incx.EQ.0) THEN
          info = 10
      ELSE IF (incy.EQ.0) THEN
          info = 13
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('ZGBMV ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF ((m.EQ.0) .OR. (n.EQ.0) .OR.
     +    ((alpha.EQ.zero).AND. (beta.EQ.one))) RETURN
*
      noconj = lsame(trans,'T')
*
*     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
*     up the start points in  X  and  Y.
*
      IF (lsame(trans,'N')) THEN
          lenx = n
          leny = m
      ELSE
          lenx = m
          leny = n
      END IF
      IF (incx.GT.0) THEN
          kx = 1
      ELSE
          kx = 1 - (lenx-1)*incx
      END IF
      IF (incy.GT.0) THEN
          ky = 1
      ELSE
          ky = 1 - (leny-1)*incy
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through the band part of A.
*
*     First form  y := beta*y.
*
      IF (beta.NE.one) THEN
          IF (incy.EQ.1) THEN
              IF (beta.EQ.zero) THEN
                  DO 10 i = 1,leny
                      y(i) = zero
   10             CONTINUE
              ELSE
                  DO 20 i = 1,leny
                      y(i) = beta*y(i)
   20             CONTINUE
              END IF
          ELSE
              iy = ky
              IF (beta.EQ.zero) THEN
                  DO 30 i = 1,leny
                      y(iy) = zero
                      iy = iy + incy
   30             CONTINUE
              ELSE
                  DO 40 i = 1,leny
                      y(iy) = beta*y(iy)
                      iy = iy + incy
   40             CONTINUE
              END IF
          END IF
      END IF
      IF (alpha.EQ.zero) RETURN
      kup1 = ku + 1
      IF (lsame(trans,'N')) THEN
*
*        Form  y := alpha*A*x + y.
*
          jx = kx
          IF (incy.EQ.1) THEN
              DO 60 j = 1,n
                  temp = alpha*x(jx)
                  k = kup1 - j
                  DO 50 i = max(1,j-ku),min(m,j+kl)
                      y(i) = y(i) + temp*a(k+i,j)
   50             CONTINUE
                  jx = jx + incx
   60         CONTINUE
          ELSE
              DO 80 j = 1,n
                  temp = alpha*x(jx)
                  iy = ky
                  k = kup1 - j
                  DO 70 i = max(1,j-ku),min(m,j+kl)
                      y(iy) = y(iy) + temp*a(k+i,j)
                      iy = iy + incy
   70             CONTINUE
                  jx = jx + incx
                  IF (j.GT.ku) ky = ky + incy
   80         CONTINUE
          END IF
      ELSE
*
*        Form  y := alpha*A**T*x + y  or  y := alpha*A**H*x + y.
*
          jy = ky
          IF (incx.EQ.1) THEN
              DO 110 j = 1,n
                  temp = zero
                  k = kup1 - j
                  IF (noconj) THEN
                      DO 90 i = max(1,j-ku),min(m,j+kl)
                          temp = temp + a(k+i,j)*x(i)
   90                 CONTINUE
                  ELSE
                      DO 100 i = max(1,j-ku),min(m,j+kl)
                          temp = temp + dconjg(a(k+i,j))*x(i)
  100                 CONTINUE
                  END IF
                  y(jy) = y(jy) + alpha*temp
                  jy = jy + incy
  110         CONTINUE
          ELSE
              DO 140 j = 1,n
                  temp = zero
                  ix = kx
                  k = kup1 - j
                  IF (noconj) THEN
                      DO 120 i = max(1,j-ku),min(m,j+kl)
                          temp = temp + a(k+i,j)*x(ix)
                          ix = ix + incx
  120                 CONTINUE
                  ELSE
                      DO 130 i = max(1,j-ku),min(m,j+kl)
                          temp = temp + dconjg(a(k+i,j))*x(ix)
                          ix = ix + incx
  130                 CONTINUE
                  END IF
                  y(jy) = y(jy) + alpha*temp
                  jy = jy + incy
                  IF (j.GT.ku) kx = kx + incx
  140         CONTINUE
          END IF
      END IF
*
      RETURN
*
*     End of ZGBMV
*

Here is the call graph for this function:

Here is the caller graph for this function: