cheev_2stage()

subroutine cheev_2stage	(	character	jobz,
		character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	w,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	info )

CHEEV_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for HE matrices

Download CHEEV_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHEEV_2STAGE computes all eigenvalues and, optionally, eigenvectors of a
!> complex Hermitian matrix A using the 2stage technique for
!> the reduction to tridiagonal.
!> 

Parameters

[in]	JOBZ	!> JOBZ is CHARACTER*1 !> = 'N': Compute eigenvalues only; !> = 'V': Compute eigenvalues and eigenvectors. !> Not available in this release. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA, N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the !> leading N-by-N upper triangular part of A contains the !> upper triangular part of the matrix A. If UPLO = 'L', !> the leading N-by-N lower triangular part of A contains !> the lower triangular part of the matrix A. !> On exit, if JOBZ = 'V', then if INFO = 0, A contains the !> orthonormal eigenvectors of the matrix A. !> If JOBZ = 'N', then on exit the lower triangle (if UPLO='L') !> or the upper triangle (if UPLO='U') of A, including the !> diagonal, is destroyed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	W	!> W is REAL array, dimension (N) !> If INFO = 0, the eigenvalues in ascending order. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK >= 1, when N <= 1; !> otherwise !> If JOBZ = 'N' and N > 1, LWORK must be queried. !> LWORK = MAX(1, dimension) where !> dimension = max(stage1,stage2) + (KD+1)*N + N !> = N*KD + N*max(KD+1,FACTOPTNB) !> + max(2*KD*KD, KD*NTHREADS) !> + (KD+1)*N + N !> where KD is the blocking size of the reduction, !> FACTOPTNB is the blocking used by the QR or LQ !> algorithm, usually FACTOPTNB=128 is a good choice !> NTHREADS is the number of threads used when !> openMP compilation is enabled, otherwise =1. !> If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(1, 3*N-2)) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, the algorithm failed to converge; i !> off-diagonal elements of an intermediate tridiagonal !> form did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  All details about the 2stage techniques are available in:
!>
!>  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
!>  Parallel reduction to condensed forms for symmetric eigenvalue problems
!>  using aggregated fine-grained and memory-aware kernels. In Proceedings
!>  of 2011 International Conference for High Performance Computing,
!>  Networking, Storage and Analysis (SC '11), New York, NY, USA,
!>  Article 8 , 11 pages.
!>  http://doi.acm.org/10.1145/2063384.2063394
!>
!>  A. Haidar, J. Kurzak, P. Luszczek, 2013.
!>  An improved parallel singular value algorithm and its implementation
!>  for multicore hardware, In Proceedings of 2013 International Conference
!>  for High Performance Computing, Networking, Storage and Analysis (SC '13).
!>  Denver, Colorado, USA, 2013.
!>  Article 90, 12 pages.
!>  http://doi.acm.org/10.1145/2503210.2503292
!>
!>  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
!>  A novel hybrid CPU-GPU generalized eigensolver for electronic structure
!>  calculations based on fine-grained memory aware tasks.
!>  International Journal of High Performance Computing Applications.
!>  Volume 28 Issue 2, Pages 196-209, May 2014.
!>  http://hpc.sagepub.com/content/28/2/196
!>
!> 

Definition at line 185 of file cheev_2stage.f.

*
      IMPLICIT NONE
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            INFO, LDA, LWORK, N
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * ), W( * )
      COMPLEX            A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e0, 0.0e0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER, LQUERY, WANTZ
      INTEGER            IINFO, IMAX, INDE, INDTAU, INDWRK, ISCALE,
     $                   LLWORK, LWMIN, LHTRD, LWTRD, KD, IB, INDHOUS
      REAL               ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
     $                   SMLNUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV2STAGE
      REAL               SLAMCH, CLANHE, SROUNDUP_LWORK
      EXTERNAL           lsame, slamch, clanhe, ilaenv2stage,
     $                   sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sscal, ssterf, xerbla, clascl,
     $                   csteqr,
     $                   cungtr, chetrd_2stage
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      wantz = lsame( jobz, 'V' )
      lower = lsame( uplo, 'L' )
      lquery = ( lwork.EQ.-1 )
*
      info = 0
      IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
*
      IF( info.EQ.0 ) THEN
         kd    = ilaenv2stage( 1, 'CHETRD_2STAGE', jobz, n, -1, -1,
     $                         -1 )
         ib    = ilaenv2stage( 2, 'CHETRD_2STAGE', jobz, n, kd, -1,
     $                         -1 )
         lhtrd = ilaenv2stage( 3, 'CHETRD_2STAGE', jobz, n, kd, ib,
     $                         -1 )
         lwtrd = ilaenv2stage( 4, 'CHETRD_2STAGE', jobz, n, kd, ib,
     $                         -1 )
         lwmin = n + lhtrd + lwtrd
         work( 1 )  = sroundup_lwork(lwmin)
*
         IF( lwork.LT.lwmin .AND. .NOT.lquery )
     $      info = -8
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHEEV_2STAGE ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         RETURN
      END IF
*
      IF( n.EQ.1 ) THEN
         w( 1 ) = real( a( 1, 1 ) )
         work( 1 ) = 1
         IF( wantz )
     $      a( 1, 1 ) = cone
         RETURN
      END IF
*
*     Get machine constants.
*
      safmin = slamch( 'Safe minimum' )
      eps    = slamch( 'Precision' )
      smlnum = safmin / eps
      bignum = one / smlnum
      rmin   = sqrt( smlnum )
      rmax   = sqrt( bignum )
*
*     Scale matrix to allowable range, if necessary.
*
      anrm = clanhe( 'M', uplo, n, a, lda, rwork )
      iscale = 0
      IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
         iscale = 1
         sigma = rmin / anrm
      ELSE IF( anrm.GT.rmax ) THEN
         iscale = 1
         sigma = rmax / anrm
      END IF
      IF( iscale.EQ.1 )
     $   CALL clascl( uplo, 0, 0, one, sigma, n, n, a, lda, info )
*
*     Call CHETRD_2STAGE to reduce Hermitian matrix to tridiagonal form.
*
      inde    = 1
      indtau  = 1
      indhous = indtau + n
      indwrk  = indhous + lhtrd
      llwork  = lwork - indwrk + 1
*
      CALL chetrd_2stage( jobz, uplo, n, a, lda, w, rwork( inde ),
     $                    work( indtau ), work( indhous ), lhtrd,
     $                    work( indwrk ), llwork, iinfo )
*
*     For eigenvalues only, call SSTERF.  For eigenvectors, first call
*     CUNGTR to generate the unitary matrix, then call CSTEQR.
*
      IF( .NOT.wantz ) THEN
         CALL ssterf( n, w, rwork( inde ), info )
      ELSE
         CALL cungtr( uplo, n, a, lda, work( indtau ),
     $                work( indwrk ),
     $                llwork, iinfo )
         indwrk = inde + n
         CALL csteqr( jobz, n, w, rwork( inde ), a, lda,
     $                rwork( indwrk ), info )
      END IF
*
*     If matrix was scaled, then rescale eigenvalues appropriately.
*
      IF( iscale.EQ.1 ) THEN
         IF( info.EQ.0 ) THEN
            imax = n
         ELSE
            imax = info - 1
         END IF
         CALL sscal( imax, one / sigma, w, 1 )
      END IF
*
*     Set WORK(1) to optimal complex workspace size.
*
      work( 1 ) = sroundup_lwork(lwmin)
*
      RETURN
*
*     End of CHEEV_2STAGE
*

Here is the call graph for this function:

Here is the caller graph for this function: