zlatb5()

subroutine zlatb5	(	character*3	path,
		integer	imat,
		integer	n,
		character	type,
		integer	kl,
		integer	ku,
		double precision	anorm,
		integer	mode,
		double precision	cndnum,
		character	dist
	)

ZLATB5

Purpose:

 ZLATB5 sets parameters for the matrix generator based on the type
 of matrix to be generated.

Parameters

[in]	PATH	PATH is CHARACTER*3 The LAPACK path name.
[in]	IMAT	IMAT is INTEGER An integer key describing which matrix to generate for this path.
[in]	N	N is INTEGER The number of rows and columns in the matrix to be generated.
[out]	TYPE	TYPE is CHARACTER*1 The type of the matrix to be generated: = 'S': symmetric matrix = 'P': symmetric positive (semi)definite matrix = 'N': nonsymmetric matrix
[out]	KL	KL is INTEGER The lower band width of the matrix to be generated.
[out]	KU	KU is INTEGER The upper band width of the matrix to be generated.
[out]	ANORM	ANORM is DOUBLE PRECISION The desired norm of the matrix to be generated. The diagonal matrix of singular values or eigenvalues is scaled by this value.
[out]	MODE	MODE is INTEGER A key indicating how to choose the vector of eigenvalues.
[out]	CNDNUM	CNDNUM is DOUBLE PRECISION The desired condition number.
[out]	DIST	DIST is CHARACTER*1 The type of distribution to be used by the random number generator.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 112 of file zlatb5.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   ANORM, CNDNUM
      INTEGER            IMAT, KL, KU, MODE, N
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   SHRINK, TENTH
      parameter( shrink = 0.25d0, tenth = 0.1d+0 )
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
      DOUBLE PRECISION   TWO
      parameter( two = 2.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   BADC1, BADC2, EPS, LARGE, SMALL
      LOGICAL            FIRST
      CHARACTER*2        C2
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Save statement ..
      SAVE               eps, small, large, badc1, badc2, first
*     ..
*     .. Data statements ..
      DATA               first / .true. /
*     ..
*     .. Executable Statements ..
*
*     Set some constants for use in the subroutine.
*
      IF( first ) THEN
         first = .false.
         eps = dlamch( 'Precision' )
         badc2 = tenth / eps
         badc1 = sqrt( badc2 )
         small = dlamch( 'Safe minimum' )
         large = one / small
         small = shrink*( small / eps )
         large = one / small
      END IF
*
      c2 = path( 2: 3 )
*
*     Set some parameters
*
      dist = 'S'
      mode = 3
*
*     Set TYPE, the type of matrix to be generated.
*
      TYPE = c2( 1: 1 )
*
*     Set the lower and upper bandwidths.
*
      IF( imat.EQ.1 ) THEN
         kl = 0
      ELSE
         kl = max( n-1, 0 )
      END IF
      ku = kl
*
*     Set the condition number and norm.etc
*
      IF( imat.EQ.3 ) THEN
         cndnum = 1.0d12
         mode = 2
      ELSE IF( imat.EQ.4 ) THEN
         cndnum = 1.0d12
         mode = 1
      ELSE IF( imat.EQ.5 ) THEN
         cndnum = 1.0d12
         mode = 3
      ELSE IF( imat.EQ.6 ) THEN
         cndnum = badc1
      ELSE IF( imat.EQ.7 ) THEN
         cndnum = badc2
      ELSE
         cndnum = two
      END IF
*
      IF( imat.EQ.8 ) THEN
         anorm = small
      ELSE IF( imat.EQ.9 ) THEN
         anorm = large
      ELSE
         anorm = one
      END IF
*
      IF( n.LE.1 )
     $   cndnum = one
*
      RETURN
*
*     End of ZLATB5
*

Here is the caller graph for this function: