LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cgelqt3()

recursive subroutine cgelqt3 ( integer  M,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldt, * )  T,
integer  LDT,
integer  INFO 
)

CGELQT3

Purpose:
 CGELQT3 recursively computes a LQ factorization of a complex M-by-N
 matrix A, using the compact WY representation of Q.

 Based on the algorithm of Elmroth and Gustavson,
 IBM J. Res. Develop. Vol 44 No. 4 July 2000.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M =< N.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the complex M-by-N matrix A.  On exit, the elements on and
          below the diagonal contain the N-by-N lower triangular matrix L; the
          elements above the diagonal are the rows of V.  See below for
          further details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]T
          T is COMPLEX array, dimension (LDT,N)
          The N-by-N upper triangular factor of the block reflector.
          The elements on and above the diagonal contain the block
          reflector T; the elements below the diagonal are not used.
          See below for further details.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  The matrix V stores the elementary reflectors H(i) in the i-th row
  above the diagonal. For example, if M=5 and N=3, the matrix V is

               V = (  1  v1 v1 v1 v1 )
                   (     1  v2 v2 v2 )
                   (     1  v3 v3 v3 )


  where the vi's represent the vectors which define H(i), which are returned
  in the matrix A.  The 1's along the diagonal of V are not stored in A.  The
  block reflector H is then given by

               H = I - V * T * V**T

  where V**T is the transpose of V.

  For details of the algorithm, see Elmroth and Gustavson (cited above).

Definition at line 115 of file cgelqt3.f.

116*
117* -- LAPACK computational routine --
118* -- LAPACK is a software package provided by Univ. of Tennessee, --
119* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120*
121* .. Scalar Arguments ..
122 INTEGER INFO, LDA, M, N, LDT
123* ..
124* .. Array Arguments ..
125 COMPLEX A( LDA, * ), T( LDT, * )
126* ..
127*
128* =====================================================================
129*
130* .. Parameters ..
131 COMPLEX ONE, ZERO
132 parameter( one = (1.0e+00,0.0e+00) )
133 parameter( zero = (0.0e+00,0.0e+00))
134* ..
135* .. Local Scalars ..
136 INTEGER I, I1, J, J1, M1, M2, IINFO
137* ..
138* .. External Subroutines ..
139 EXTERNAL clarfg, ctrmm, cgemm, xerbla
140* ..
141* .. Executable Statements ..
142*
143 info = 0
144 IF( m .LT. 0 ) THEN
145 info = -1
146 ELSE IF( n .LT. m ) THEN
147 info = -2
148 ELSE IF( lda .LT. max( 1, m ) ) THEN
149 info = -4
150 ELSE IF( ldt .LT. max( 1, m ) ) THEN
151 info = -6
152 END IF
153 IF( info.NE.0 ) THEN
154 CALL xerbla( 'CGELQT3', -info )
155 RETURN
156 END IF
157*
158 IF( m.EQ.1 ) THEN
159*
160* Compute Householder transform when M=1
161*
162 CALL clarfg( n, a, a( 1, min( 2, n ) ), lda, t )
163 t(1,1)=conjg(t(1,1))
164*
165 ELSE
166*
167* Otherwise, split A into blocks...
168*
169 m1 = m/2
170 m2 = m-m1
171 i1 = min( m1+1, m )
172 j1 = min( m+1, n )
173*
174* Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
175*
176 CALL cgelqt3( m1, n, a, lda, t, ldt, iinfo )
177*
178* Compute A(J1:M,1:N) = A(J1:M,1:N) Q1^H [workspace: T(1:N1,J1:N)]
179*
180 DO i=1,m2
181 DO j=1,m1
182 t( i+m1, j ) = a( i+m1, j )
183 END DO
184 END DO
185 CALL ctrmm( 'R', 'U', 'C', 'U', m2, m1, one,
186 & a, lda, t( i1, 1 ), ldt )
187*
188 CALL cgemm( 'N', 'C', m2, m1, n-m1, one, a( i1, i1 ), lda,
189 & a( 1, i1 ), lda, one, t( i1, 1 ), ldt)
190*
191 CALL ctrmm( 'R', 'U', 'N', 'N', m2, m1, one,
192 & t, ldt, t( i1, 1 ), ldt )
193*
194 CALL cgemm( 'N', 'N', m2, n-m1, m1, -one, t( i1, 1 ), ldt,
195 & a( 1, i1 ), lda, one, a( i1, i1 ), lda )
196*
197 CALL ctrmm( 'R', 'U', 'N', 'U', m2, m1 , one,
198 & a, lda, t( i1, 1 ), ldt )
199*
200 DO i=1,m2
201 DO j=1,m1
202 a( i+m1, j ) = a( i+m1, j ) - t( i+m1, j )
203 t( i+m1, j )= zero
204 END DO
205 END DO
206*
207* Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
208*
209 CALL cgelqt3( m2, n-m1, a( i1, i1 ), lda,
210 & t( i1, i1 ), ldt, iinfo )
211*
212* Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
213*
214 DO i=1,m2
215 DO j=1,m1
216 t( j, i+m1 ) = (a( j, i+m1 ))
217 END DO
218 END DO
219*
220 CALL ctrmm( 'R', 'U', 'C', 'U', m1, m2, one,
221 & a( i1, i1 ), lda, t( 1, i1 ), ldt )
222*
223 CALL cgemm( 'N', 'C', m1, m2, n-m, one, a( 1, j1 ), lda,
224 & a( i1, j1 ), lda, one, t( 1, i1 ), ldt )
225*
226 CALL ctrmm( 'L', 'U', 'N', 'N', m1, m2, -one, t, ldt,
227 & t( 1, i1 ), ldt )
228*
229 CALL ctrmm( 'R', 'U', 'N', 'N', m1, m2, one,
230 & t( i1, i1 ), ldt, t( 1, i1 ), ldt )
231*
232*
233*
234* Y = (Y1,Y2); L = [ L1 0 ]; T = [T1 T3]
235* [ A(1:N1,J1:N) L2 ] [ 0 T2]
236*
237 END IF
238*
239 RETURN
240*
241* End of CGELQT3
242*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:187
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:177
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:106
recursive subroutine cgelqt3(M, N, A, LDA, T, LDT, INFO)
CGELQT3
Definition: cgelqt3.f:116
Here is the call graph for this function:
Here is the caller graph for this function: