ztrt06()

subroutine ztrt06	(	double precision	rcond,
		double precision	rcondc,
		character	uplo,
		character	diag,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	rwork,
		double precision	rat )

ZTRT06

Purpose:

!>
!> ZTRT06 computes a test ratio comparing RCOND (the reciprocal
!> condition number of a triangular matrix A) and RCONDC, the estimate
!> computed by ZTRCON.  Information about the triangular matrix A is
!> used if one estimate is zero and the other is non-zero to decide if
!> underflow in the estimate is justified.
!> 

Parameters

[in]	RCOND	!> RCOND is DOUBLE PRECISION !> The estimate of the reciprocal condition number obtained by !> forming the explicit inverse of the matrix A and computing !> RCOND = 1/( norm(A) * norm(inv(A)) ). !>
[in]	RCONDC	!> RCONDC is DOUBLE PRECISION !> The estimate of the reciprocal condition number computed by !> ZTRCON. !>
[in]	UPLO	!> UPLO is CHARACTER !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	DIAG	!> DIAG is CHARACTER !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The triangular matrix A. If UPLO = 'U', the leading n by n !> upper triangular part of the array A contains the upper !> triangular matrix, and the strictly lower triangular part of !> A is not referenced. If UPLO = 'L', the leading n by n lower !> triangular part of the array A contains the lower triangular !> matrix, and the strictly upper triangular part of A is not !> referenced. If DIAG = 'U', the diagonal elements of A are !> also not referenced and are assumed to be 1. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RAT	!> RAT is DOUBLE PRECISION !> The test ratio. If both RCOND and RCONDC are nonzero, !> RAT = MAX( RCOND, RCONDC )/MIN( RCOND, RCONDC ) - 1. !> If RAT = 0, the two estimates are exactly the same. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 120 of file ztrt06.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            LDA, N
      DOUBLE PRECISION   RAT, RCOND, RCONDC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ANORM, BIGNUM, EPS, RMAX, RMIN
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANTR
      EXTERNAL           dlamch, zlantr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      rmax = max( rcond, rcondc )
      rmin = min( rcond, rcondc )
*
*     Do the easy cases first.
*
      IF( rmin.LT.zero ) THEN
*
*        Invalid value for RCOND or RCONDC, return 1/EPS.
*
         rat = one / eps
*
      ELSE IF( rmin.GT.zero ) THEN
*
*        Both estimates are positive, return RMAX/RMIN - 1.
*
         rat = rmax / rmin - one
*
      ELSE IF( rmax.EQ.zero ) THEN
*
*        Both estimates zero.
*
         rat = zero
*
      ELSE
*
*        One estimate is zero, the other is non-zero.  If the matrix is
*        ill-conditioned, return the nonzero estimate multiplied by
*        1/EPS; if the matrix is badly scaled, return the nonzero
*        estimate multiplied by BIGNUM/TMAX, where TMAX is the maximum
*        element in absolute value in A.
*
         bignum = one / dlamch( 'Safe minimum' )
         anorm = zlantr( 'M', uplo, diag, n, n, a, lda, rwork )
*
         rat = rmax*( min( bignum / max( one, anorm ), one / eps ) )
      END IF
*
      RETURN
*
*     End of ZTRT06
*

Here is the caller graph for this function: