clatb5.f

Go to the documentation of this file.

*> \brief \b CLATB5
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLATB5( PATH, IMAT, N, TYPE, KL, KU, ANORM, MODE,
*                          CNDNUM, DIST )
*
*       .. Scalar Arguments ..
*       REAL               ANORM, CNDNUM
*       INTEGER            IMAT, KL, KU, MODE, N
*       CHARACTER          DIST, TYPE
*       CHARACTER*3        PATH
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLATB5 sets parameters for the matrix generator based on the type
*> of matrix to be generated.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] PATH
*> \verbatim
*>          PATH is CHARACTER*3
*>          The LAPACK path name.
*> \endverbatim
*>
*> \param[in] IMAT
*> \verbatim
*>          IMAT is INTEGER
*>          An integer key describing which matrix to generate for this
*>          path.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns in the matrix to be generated.
*> \endverbatim
*>
*> \param[out] TYPE
*> \verbatim
*>          TYPE is CHARACTER*1
*>          The type of the matrix to be generated:
*>          = 'S':  symmetric matrix
*>          = 'P':  symmetric positive (semi)definite matrix
*>          = 'N':  nonsymmetric matrix
*> \endverbatim
*>
*> \param[out] KL
*> \verbatim
*>          KL is INTEGER
*>          The lower band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] KU
*> \verbatim
*>          KU is INTEGER
*>          The upper band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] ANORM
*> \verbatim
*>          ANORM is REAL
*>          The desired norm of the matrix to be generated.  The diagonal
*>          matrix of singular values or eigenvalues is scaled by this
*>          value.
*> \endverbatim
*>
*> \param[out] MODE
*> \verbatim
*>          MODE is INTEGER
*>          A key indicating how to choose the vector of eigenvalues.
*> \endverbatim
*>
*> \param[out] CNDNUM
*> \verbatim
*>          CNDNUM is REAL
*>          The desired condition number.
*> \endverbatim
*>
*> \param[out] DIST
*> \verbatim
*>          DIST is CHARACTER*1
*>          The type of distribution to be used by the random number
*>          generator.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE clatb5( PATH, IMAT, N, TYPE, KL, KU, ANORM, MODE,
     $                   CNDNUM, DIST )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               ANORM, CNDNUM
      INTEGER            IMAT, KL, KU, MODE, N
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               SHRINK, TENTH
      parameter( shrink = 0.25e0, tenth = 0.1e+0 )
      REAL               ONE
      parameter( one = 1.0e+0 )
      REAL               TWO
      parameter( two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               BADC1, BADC2, EPS, LARGE, SMALL
      LOGICAL            FIRST
      CHARACTER*2        C2
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Save statement ..
      SAVE               eps, small, large, badc1, badc2, first
*     ..
*     .. Data statements ..
      DATA               first / .true. /
*     ..
*     .. Executable Statements ..
*
*     Set some constants for use in the subroutine.
*
      IF( first ) THEN
         first = .false.
         eps = slamch( 'Precision' )
         badc2 = tenth / eps
         badc1 = sqrt( badc2 )
         small = slamch( 'Safe minimum' )
         large = one / small
         small = shrink*( small / eps )
         large = one / small
      END IF
*
      c2 = path( 2: 3 )
*
*     Set some parameters
*
      dist = 'S'
      mode = 3
*
*     Set TYPE, the type of matrix to be generated.
*
      TYPE = c2( 1: 1 )
*
*     Set the lower and upper bandwidths.
*
      IF( imat.EQ.1 ) THEN
         kl = 0
      ELSE
         kl = max( n-1, 0 )
      END IF
      ku = kl
*
*     Set the condition number and norm.etc
*
      IF( imat.EQ.3 ) THEN
         cndnum = 1.0e4
         mode = 2
      ELSE IF( imat.EQ.4 ) THEN
         cndnum = 1.0e4
         mode = 1
      ELSE IF( imat.EQ.5 ) THEN
         cndnum = 1.0e4
         mode = 3
      ELSE IF( imat.EQ.6 ) THEN
         cndnum = badc1
      ELSE IF( imat.EQ.7 ) THEN
         cndnum = badc2
      ELSE
         cndnum = two
      END IF
*
      IF( imat.EQ.8 ) THEN
         anorm = small
      ELSE IF( imat.EQ.9 ) THEN
         anorm = large
      ELSE
         anorm = one
      END IF
*
      IF( n.LE.1 )
     $   cndnum = one
*
      RETURN
*
*     End of CLATB5
*
      END