spotrf.f

Go to the documentation of this file.

C> \brief \b SPOTRF VARIANT: top-looking block version of the algorithm, calling Level 3 BLAS.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SPOTRF ( UPLO, N, A, LDA, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, N
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * )
*       ..
*
*  Purpose
*  =======
*
C>\details \b Purpose:
C>\verbatim
C>
C> SPOTRF computes the Cholesky factorization of a real symmetric
C> positive definite matrix A.
C>
C> The factorization has the form
C>    A = U**T * U,  if UPLO = 'U', or
C>    A = L  * L**T,  if UPLO = 'L',
C> where U is an upper triangular matrix and L is lower triangular.
C>
C> This is the top-looking block version of the algorithm, calling Level 3 BLAS.
C>
C>\endverbatim
*
*  Arguments:
*  ==========
*
C> \param[in] UPLO
C> \verbatim
C>          UPLO is CHARACTER*1
C>          = 'U':  Upper triangle of A is stored;
C>          = 'L':  Lower triangle of A is stored.
C> \endverbatim
C>
C> \param[in] N
C> \verbatim
C>          N is INTEGER
C>          The order of the matrix A.  N >= 0.
C> \endverbatim
C>
C> \param[in,out] A
C> \verbatim
C>          A is REAL array, dimension (LDA,N)
C>          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
C>          N-by-N upper triangular part of A contains the upper
C>          triangular part of the matrix A, and the strictly lower
C>          triangular part of A is not referenced.  If UPLO = 'L', the
C>          leading N-by-N lower triangular part of A contains the lower
C>          triangular part of the matrix A, and the strictly upper
C>          triangular part of A is not referenced.
C> \endverbatim
C> \verbatim
C>          On exit, if INFO = 0, the factor U or L from the Cholesky
C>          factorization A = U**T*U or A = L*L**T.
C> \endverbatim
C>
C> \param[in] LDA
C> \verbatim
C>          LDA is INTEGER
C>          The leading dimension of the array A.  LDA >= max(1,N).
C> \endverbatim
C>
C> \param[out] INFO
C> \verbatim
C>          INFO is INTEGER
C>          = 0:  successful exit
C>          < 0:  if INFO = -i, the i-th argument had an illegal value
C>          > 0:  if INFO = i, the leading minor of order i is not
C>                positive definite, and the factorization could not be
C>                completed.
C> \endverbatim
C>
*
*  Authors:
*  ========
*
C> \author Univ. of Tennessee
C> \author Univ. of California Berkeley
C> \author Univ. of Colorado Denver
C> \author NAG Ltd.
*
C> \date December 2016
*
C> \ingroup variantsPOcomputational
*
*  =====================================================================
      SUBROUTINE spotrf ( UPLO, N, A, LDA, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, JB, NB
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, spotf2, ssyrk, strsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SPOTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'SPOTRF', uplo, n, -1, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code.
*
         CALL spotf2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code.
*
         IF( upper ) THEN
*
*           Compute the Cholesky factorization A = U'*U.
*
            DO 10 j = 1, n, nb
 
               jb = min( nb, n-j+1 )
*
*              Compute the current block.
*
               CALL strsm( 'Left', 'Upper', 'Transpose', 'Non-unit',
     $                      j-1, jb, one, a( 1, 1 ), lda,
     $                      a( 1, j ), lda )
 
               CALL ssyrk( 'Upper', 'Transpose', jb, j-1, -one,
     $                      a( 1, j ), lda,
     $                      one, a( j, j ), lda )
*
*              Update and factorize the current diagonal block and test
*              for non-positive-definiteness.
*
               CALL spotf2( 'Upper', jb, a( j, j ), lda, info )
               IF( info.NE.0 )
     $            GO TO 30
 
   10       CONTINUE
*
         ELSE
*
*           Compute the Cholesky factorization A = L*L'.
*
            DO 20 j = 1, n, nb
 
               jb = min( nb, n-j+1 )
*
*              Compute the current block.
*
               CALL strsm( 'Right', 'Lower', 'Transpose', 'Non-unit',
     $                     jb, j-1, one, a( 1, 1 ), lda,
     $                     a( j, 1 ), lda )
 
               CALL ssyrk( 'Lower', 'No Transpose', jb, j-1,
     $                     -one, a( j, 1 ), lda,
     $                     one, a( j, j ), lda )
*
*              Update and factorize the current diagonal block and test
*              for non-positive-definiteness.
*
               CALL spotf2( 'Lower', jb, a( j, j ), lda, info )
               IF( info.NE.0 )
     $            GO TO 30
 
   20       CONTINUE
         END IF
      END IF
      GO TO 40
*
   30 CONTINUE
      info = info + j - 1
*
   40 CONTINUE
      RETURN
*
*     End of SPOTRF
*
      END