dlagtm.f

Go to the documentation of this file.

*> \brief \b DLAGTM performs a matrix-matrix product of the form C = αAB+βC, where A is a tridiagonal matrix, B and C are rectangular matrices, and α and β are scalars, which may be 0, 1, or -1.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download DLAGTM + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlagtm.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlagtm.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlagtm.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLAGTM( TRANS, N, NRHS, ALPHA, DL, D, DU, X, LDX, BETA,
*                          B, LDB )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            LDB, LDX, N, NRHS
*       DOUBLE PRECISION   ALPHA, BETA
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   B( LDB, * ), D( * ), DL( * ), DU( * ),
*      $                   X( LDX, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLAGTM performs a matrix-matrix product of the form
*>
*>    B := alpha * A * X + beta * B
*>
*> where A is a tridiagonal matrix of order N, B and X are N by NRHS
*> matrices, and alpha and beta are real scalars, each of which may be
*> 0., 1., or -1.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          Specifies the operation applied to A.
*>          = 'N':  No transpose, B := alpha * A * X + beta * B
*>          = 'T':  Transpose,    B := alpha * A'* X + beta * B
*>          = 'C':  Conjugate transpose = Transpose
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrices X and B.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*>          ALPHA is DOUBLE PRECISION
*>          The scalar alpha.  ALPHA must be 0., 1., or -1.; otherwise,
*>          it is assumed to be 0.
*> \endverbatim
*>
*> \param[in] DL
*> \verbatim
*>          DL is DOUBLE PRECISION array, dimension (N-1)
*>          The (n-1) sub-diagonal elements of T.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (N)
*>          The diagonal elements of T.
*> \endverbatim
*>
*> \param[in] DU
*> \verbatim
*>          DU is DOUBLE PRECISION array, dimension (N-1)
*>          The (n-1) super-diagonal elements of T.
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
*>          The N by NRHS matrix X.
*> \endverbatim
*>
*> \param[in] LDX
*> \verbatim
*>          LDX is INTEGER
*>          The leading dimension of the array X.  LDX >= max(N,1).
*> \endverbatim
*>
*> \param[in] BETA
*> \verbatim
*>          BETA is DOUBLE PRECISION
*>          The scalar beta.  BETA must be 0., 1., or -1.; otherwise,
*>          it is assumed to be 1.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
*>          On entry, the N by NRHS matrix B.
*>          On exit, B is overwritten by the matrix expression
*>          B := alpha * A * X + beta * B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(N,1).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lagtm
*
*  =====================================================================
      SUBROUTINE dlagtm( TRANS, N, NRHS, ALPHA, DL, D, DU, X, LDX,
     $                   BETA,
     $                   B, LDB )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDB, LDX, N, NRHS
      DOUBLE PRECISION   ALPHA, BETA
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), D( * ), DL( * ), DU( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      PARAMETER          ( ONE = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           LSAME
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Multiply B by BETA if BETA.NE.1.
*
      IF( beta.EQ.zero ) THEN
         DO 20 j = 1, nrhs
            DO 10 i = 1, n
               b( i, j ) = zero
   10       CONTINUE
   20    CONTINUE
      ELSE IF( beta.EQ.-one ) THEN
         DO 40 j = 1, nrhs
            DO 30 i = 1, n
               b( i, j ) = -b( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
*
      IF( alpha.EQ.one ) THEN
         IF( lsame( trans, 'N' ) ) THEN
*
*           Compute B := B + A*X
*
            DO 60 j = 1, nrhs
               IF( n.EQ.1 ) THEN
                  b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j )
               ELSE
                  b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j ) +
     $                        du( 1 )*x( 2, j )
                  b( n, j ) = b( n, j ) + dl( n-1 )*x( n-1, j ) +
     $                        d( n )*x( n, j )
                  DO 50 i = 2, n - 1
                     b( i, j ) = b( i, j ) + dl( i-1 )*x( i-1, j ) +
     $                           d( i )*x( i, j ) + du( i )*x( i+1, j )
   50             CONTINUE
               END IF
   60       CONTINUE
         ELSE
*
*           Compute B := B + A**T*X
*
            DO 80 j = 1, nrhs
               IF( n.EQ.1 ) THEN
                  b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j )
               ELSE
                  b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j ) +
     $                        dl( 1 )*x( 2, j )
                  b( n, j ) = b( n, j ) + du( n-1 )*x( n-1, j ) +
     $                        d( n )*x( n, j )
                  DO 70 i = 2, n - 1
                     b( i, j ) = b( i, j ) + du( i-1 )*x( i-1, j ) +
     $                           d( i )*x( i, j ) + dl( i )*x( i+1, j )
   70             CONTINUE
               END IF
   80       CONTINUE
         END IF
      ELSE IF( alpha.EQ.-one ) THEN
         IF( lsame( trans, 'N' ) ) THEN
*
*           Compute B := B - A*X
*
            DO 100 j = 1, nrhs
               IF( n.EQ.1 ) THEN
                  b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j )
               ELSE
                  b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j ) -
     $                        du( 1 )*x( 2, j )
                  b( n, j ) = b( n, j ) - dl( n-1 )*x( n-1, j ) -
     $                        d( n )*x( n, j )
                  DO 90 i = 2, n - 1
                     b( i, j ) = b( i, j ) - dl( i-1 )*x( i-1, j ) -
     $                           d( i )*x( i, j ) - du( i )*x( i+1, j )
   90             CONTINUE
               END IF
  100       CONTINUE
         ELSE
*
*           Compute B := B - A**T*X
*
            DO 120 j = 1, nrhs
               IF( n.EQ.1 ) THEN
                  b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j )
               ELSE
                  b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j ) -
     $                        dl( 1 )*x( 2, j )
                  b( n, j ) = b( n, j ) - du( n-1 )*x( n-1, j ) -
     $                        d( n )*x( n, j )
                  DO 110 i = 2, n - 1
                     b( i, j ) = b( i, j ) - du( i-1 )*x( i-1, j ) -
     $                           d( i )*x( i, j ) - dl( i )*x( i+1, j )
  110             CONTINUE
               END IF
  120       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of DLAGTM
*
      END