zchkhp.f

Go to the documentation of this file.

*> \brief \b ZCHKHP
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKHP( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          NMAX, A, AFAC, AINV, B, X, XACT, WORK, RWORK,
*                          IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNS, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
*      $                   WORK( * ), X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKHP tests ZHPTRF, -TRI, -TRS, -RFS, and -CON
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is COMPLEX*16 array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] AINV
*> \verbatim
*>          AINV is COMPLEX*16 array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension
*>                      (NMAX*max(2,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array,
*>                                 dimension (NMAX+2*NSMAX)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zchkhp( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   NMAX, A, AFAC, AINV, B, X, XACT, WORK, RWORK,
     $                   IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      PARAMETER          ( ZERO = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 10 )
      INTEGER            NTESTS
      parameter( ntests = 8 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, PACKIT, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, I1, I2, IMAT, IN, INFO, IOFF, IRHS, IUPLO,
     $                   izero, j, k, kl, ku, lda, mode, n, nerrs,
     $                   nfail, nimat, npp, nrhs, nrun, nt
      DOUBLE PRECISION   ANORM, CNDNUM, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DGET06, ZLANHP
      EXTERNAL           lsame, dget06, zlanhp
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, zcopy, zerrsy, zget04,
     $                   zhpcon, zhprfs, zhpt01, zhptrf, zhptri, zhptrs,
     $                   zlacpy, zlaipd, zlarhs, zlatb4, zlatms, zppt02,
     $                   zppt03, zppt05
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'HP'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrsy( path, nout )
      infot = 0
*
*     Do for each value of N in NVAL
*
      DO 170 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
         DO 160 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 160
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 160
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 150 iuplo = 1, 2
               uplo = uplos( iuplo )
               IF( lsame( uplo, 'U' ) ) THEN
                  packit = 'C'
               ELSE
                  packit = 'R'
               END IF
*
*              Set up parameters with ZLATB4 and generate a test matrix
*              with ZLATMS.
*
               CALL zlatb4( path, imat, n, n, TYPE, kl, ku, anorm, mode,
     $                      cndnum, dist )
*
               srnamt = 'ZLATMS'
               CALL zlatms( n, n, dist, iseed, TYPE, rwork, mode,
     $                      cndnum, anorm, kl, ku, packit, a, lda, work,
     $                      info )
*
*              Check error code from ZLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'ZLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 150
               END IF
*
*              For types 3-6, zero one or more rows and columns of
*              the matrix to test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
                  IF( imat.LT.6 ) THEN
*
*                    Set row and column IZERO to zero.
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*izero / 2
                        DO 20 i = 1, izero - 1
                           a( ioff+i ) = zero
   20                   CONTINUE
                        ioff = ioff + izero
                        DO 30 i = izero, n
                           a( ioff ) = zero
                           ioff = ioff + i
   30                   CONTINUE
                     ELSE
                        ioff = izero
                        DO 40 i = 1, izero - 1
                           a( ioff ) = zero
                           ioff = ioff + n - i
   40                   CONTINUE
                        ioff = ioff - izero
                        DO 50 i = izero, n
                           a( ioff+i ) = zero
   50                   CONTINUE
                     END IF
                  ELSE
                     ioff = 0
                     IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                        DO 70 j = 1, n
                           i2 = min( j, izero )
                           DO 60 i = 1, i2
                              a( ioff+i ) = zero
   60                      CONTINUE
                           ioff = ioff + j
   70                   CONTINUE
                     ELSE
*
*                       Set the last IZERO rows and columns to zero.
*
                        DO 90 j = 1, n
                           i1 = max( j, izero )
                           DO 80 i = i1, n
                              a( ioff+i ) = zero
   80                      CONTINUE
                           ioff = ioff + n - j
   90                   CONTINUE
                     END IF
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              Set the imaginary part of the diagonals.
*
               IF( iuplo.EQ.1 ) THEN
                  CALL zlaipd( n, a, 2, 1 )
               ELSE
                  CALL zlaipd( n, a, n, -1 )
               END IF
*
*              Compute the L*D*L' or U*D*U' factorization of the matrix.
*
               npp = n*( n+1 ) / 2
               CALL zcopy( npp, a, 1, afac, 1 )
               srnamt = 'ZHPTRF'
               CALL zhptrf( uplo, n, afac, iwork, info )
*
*              Adjust the expected value of INFO to account for
*              pivoting.
*
               k = izero
               IF( k.GT.0 ) THEN
  100             CONTINUE
                  IF( iwork( k ).LT.0 ) THEN
                     IF( iwork( k ).NE.-k ) THEN
                        k = -iwork( k )
                        GO TO 100
                     END IF
                  ELSE IF( iwork( k ).NE.k ) THEN
                     k = iwork( k )
                     GO TO 100
                  END IF
               END IF
*
*              Check error code from ZHPTRF.
*
               IF( info.NE.k )
     $            CALL alaerh( path, 'ZHPTRF', info, k, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
               IF( info.NE.0 ) THEN
                  trfcon = .true.
               ELSE
                  trfcon = .false.
               END IF
*
*+    TEST 1
*              Reconstruct matrix from factors and compute residual.
*
               CALL zhpt01( uplo, n, a, afac, iwork, ainv, lda, rwork,
     $                      result( 1 ) )
               nt = 1
*
*+    TEST 2
*              Form the inverse and compute the residual.
*
               IF( .NOT.trfcon ) THEN
                  CALL zcopy( npp, afac, 1, ainv, 1 )
                  srnamt = 'ZHPTRI'
                  CALL zhptri( uplo, n, ainv, iwork, work, info )
*
*              Check error code from ZHPTRI.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZHPTRI', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL zppt03( uplo, n, a, ainv, work, lda, rwork,
     $                         rcondc, result( 2 ) )
                  nt = 2
               END IF
*
*              Print information about the tests that did not pass
*              the threshold.
*
               DO 110 k = 1, nt
                  IF( result( k ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9999 )uplo, n, imat, k,
     $                  result( k )
                     nfail = nfail + 1
                  END IF
  110          CONTINUE
               nrun = nrun + nt
*
*              Do only the condition estimate if INFO is not 0.
*
               IF( trfcon ) THEN
                  rcondc = zero
                  GO TO 140
               END IF
*
               DO 130 irhs = 1, nns
                  nrhs = nsval( irhs )
*
*+    TEST 3
*              Solve and compute residual for  A * X = B.
*
                  srnamt = 'ZLARHS'
                  CALL zlarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                         nrhs, a, lda, xact, lda, b, lda, iseed,
     $                         info )
                  xtype = 'C'
                  CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                  srnamt = 'ZHPTRS'
                  CALL zhptrs( uplo, n, nrhs, afac, iwork, x, lda,
     $                         info )
*
*              Check error code from ZHPTRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZHPTRS', info, 0, uplo, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL zlacpy( 'Full', n, nrhs, b, lda, work, lda )
                  CALL zppt02( uplo, n, nrhs, a, x, lda, work, lda,
     $                         rwork, result( 3 ) )
*
*+    TEST 4
*              Check solution from generated exact solution.
*
                  CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 4 ) )
*
*+    TESTS 5, 6, and 7
*              Use iterative refinement to improve the solution.
*
                  srnamt = 'ZHPRFS'
                  CALL zhprfs( uplo, n, nrhs, a, afac, iwork, b, lda, x,
     $                         lda, rwork, rwork( nrhs+1 ), work,
     $                         rwork( 2*nrhs+1 ), info )
*
*              Check error code from ZHPRFS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZHPRFS', info, 0, uplo, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 5 ) )
                  CALL zppt05( uplo, n, nrhs, a, b, lda, x, lda, xact,
     $                         lda, rwork, rwork( nrhs+1 ),
     $                         result( 6 ) )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 120 k = 3, 7
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 )uplo, n, nrhs, imat,
     $                     k, result( k )
                        nfail = nfail + 1
                     END IF
  120             CONTINUE
                  nrun = nrun + 5
  130          CONTINUE
*
*+    TEST 8
*              Get an estimate of RCOND = 1/CNDNUM.
*
  140          CONTINUE
               anorm = zlanhp( '1', uplo, n, a, rwork )
               srnamt = 'ZHPCON'
               CALL zhpcon( uplo, n, afac, iwork, anorm, rcond, work,
     $                      info )
*
*              Check error code from ZHPCON.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'ZHPCON', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
               result( 8 ) = dget06( rcond, rcondc )
*
*              Print the test ratio if it is .GE. THRESH.
*
               IF( result( 8 ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  WRITE( nout, fmt = 9999 )uplo, n, imat, 8,
     $               result( 8 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
  150       CONTINUE
  160    CONTINUE
  170 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', type ', i2, ', test ',
     $      i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of ZCHKHP
*
      END