zlarfgp()

subroutine zlarfgp	(	integer	n,
		complex*16	alpha,
		complex*16, dimension( * )	x,
		integer	incx,
		complex*16	tau )

ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.

Download ZLARFGP + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLARFGP generates a complex elementary reflector H of order n, such
!> that
!>
!>       H**H * ( alpha ) = ( beta ),   H**H * H = I.
!>              (   x   )   (   0  )
!>
!> where alpha and beta are scalars, beta is real and non-negative, and
!> x is an (n-1)-element complex vector.  H is represented in the form
!>
!>       H = I - tau * ( 1 ) * ( 1 v**H ) ,
!>                     ( v )
!>
!> where tau is a complex scalar and v is a complex (n-1)-element
!> vector. Note that H is not hermitian.
!>
!> If the elements of x are all zero and alpha is real, then tau = 0
!> and H is taken to be the unit matrix.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the elementary reflector. !>
[in,out]	ALPHA	!> ALPHA is COMPLEX*16 !> On entry, the value alpha. !> On exit, it is overwritten with the value beta. !>
[in,out]	X	!> X is COMPLEX*16 array, dimension !> (1+(N-2)*abs(INCX)) !> On entry, the vector x. !> On exit, it is overwritten with the vector v. !>
[in]	INCX	!> INCX is INTEGER !> The increment between elements of X. INCX > 0. !>
[out]	TAU	!> TAU is COMPLEX*16 !> The value tau. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file zlarfgp.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      COMPLEX*16         ALPHA, TAU
*     ..
*     .. Array Arguments ..
      COMPLEX*16         X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   TWO, ONE, ZERO
      parameter( two = 2.0d+0, one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J, KNT
      DOUBLE PRECISION   ALPHI, ALPHR, BETA, BIGNUM, EPS, SMLNUM, XNORM
      COMPLEX*16         SAVEALPHA
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLAPY3, DLAPY2, DZNRM2
      COMPLEX*16         ZLADIV
      EXTERNAL           dlamch, dlapy3, dlapy2, dznrm2,
     $                   zladiv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dimag, sign
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal, zscal
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 ) THEN
         tau = zero
         RETURN
      END IF
*
      eps = dlamch( 'Precision' )
      xnorm = dznrm2( n-1, x, incx )
      alphr = dble( alpha )
      alphi = dimag( alpha )
*
      IF( xnorm.LE.eps*abs(alpha) .AND. alphi.EQ.zero ) THEN
*
*        H  =  [1-alpha/abs(alpha) 0; 0 I], sign chosen so ALPHA >= 0.
*
         IF( alphr.GE.zero ) THEN
*           When TAU.eq.ZERO, the vector is special-cased to be
*           all zeros in the application routines.  We do not need
*           to clear it.
            tau = zero
         ELSE
*           However, the application routines rely on explicit
*           zero checks when TAU.ne.ZERO, and we must clear X.
            tau = two
            DO j = 1, n-1
               x( 1 + (j-1)*incx ) = zero
            END DO
            alpha = -alpha
         END IF
      ELSE
*
*        general case
*
         beta = sign( dlapy3( alphr, alphi, xnorm ), alphr )
         smlnum = dlamch( 'S' ) / dlamch( 'E' )
         bignum = one / smlnum
*
         knt = 0
         IF( abs( beta ).LT.smlnum ) THEN
*
*           XNORM, BETA may be inaccurate; scale X and recompute them
*
   10       CONTINUE
            knt = knt + 1
            CALL zdscal( n-1, bignum, x, incx )
            beta = beta*bignum
            alphi = alphi*bignum
            alphr = alphr*bignum
            IF( (abs( beta ).LT.smlnum) .AND. (knt .LT. 20) )
     $         GO TO 10
*
*           New BETA is at most 1, at least SMLNUM
*
            xnorm = dznrm2( n-1, x, incx )
            alpha = dcmplx( alphr, alphi )
            beta = sign( dlapy3( alphr, alphi, xnorm ), alphr )
         END IF
         savealpha = alpha
         alpha = alpha + beta
         IF( beta.LT.zero ) THEN
            beta = -beta
            tau = -alpha / beta
         ELSE
            alphr = alphi * (alphi/dble( alpha ))
            alphr = alphr + xnorm * (xnorm/dble( alpha ))
            tau = dcmplx( alphr/beta, -alphi/beta )
            alpha = dcmplx( -alphr, alphi )
         END IF
         alpha = zladiv( dcmplx( one ), alpha )
*
         IF ( abs(tau).LE.smlnum ) THEN
*
*           In the case where the computed TAU ends up being a denormalized number,
*           it loses relative accuracy. This is a BIG problem. Solution: flush TAU
*           to ZERO (or TWO or whatever makes a nonnegative real number for BETA).
*
*           (Bug report provided by Pat Quillen from MathWorks on Jul 29, 2009.)
*           (Thanks Pat. Thanks MathWorks.)
*
            alphr = dble( savealpha )
            alphi = dimag( savealpha )
            IF( alphi.EQ.zero ) THEN
               IF( alphr.GE.zero ) THEN
                  tau = zero
               ELSE
                  tau = two
                  DO j = 1, n-1
                     x( 1 + (j-1)*incx ) = zero
                  END DO
                  beta = dble( -savealpha )
               END IF
            ELSE
               xnorm = dlapy2( alphr, alphi )
               tau = dcmplx( one - alphr / xnorm, -alphi / xnorm )
               DO j = 1, n-1
                  x( 1 + (j-1)*incx ) = zero
               END DO
               beta = xnorm
            END IF
*
         ELSE
*
*           This is the general case.
*
            CALL zscal( n-1, alpha, x, incx )
*
         END IF
*
*        If BETA is subnormal, it may lose relative accuracy
*
         DO 20 j = 1, knt
            beta = beta*smlnum
 20      CONTINUE
         alpha = beta
      END IF
*
      RETURN
*
*     End of ZLARFGP
*

Here is the call graph for this function:

Here is the caller graph for this function: