zpot01()

subroutine zpot01	(	character	uplo,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldafac, * )	afac,
		integer	ldafac,
		double precision, dimension( * )	rwork,
		double precision	resid )

ZPOT01

Purpose:

!>
!> ZPOT01 reconstructs a Hermitian positive definite matrix  A  from
!> its L*L' or U'*U factorization and computes the residual
!>    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
!>    norm( U'*U - A ) / ( N * norm(A) * EPS ),
!> where EPS is the machine epsilon, L' is the conjugate transpose of L,
!> and U' is the conjugate transpose of U.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The original Hermitian matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N) !>
[in,out]	AFAC	!> AFAC is COMPLEX*16 array, dimension (LDAFAC,N) !> On entry, the factor L or U from the L * L**H or U**H * U !> factorization of A. !> Overwritten with the reconstructed matrix, and then with !> the difference L * L**H - A (or U**H * U - A). !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. LDAFAC >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> If UPLO = 'L', norm(L * L**H - A) / ( N * norm(A) * EPS ) !> If UPLO = 'U', norm(U**H * U - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 105 of file zpot01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAFAC, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), AFAC( LDAFAC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      DOUBLE PRECISION   ANORM, EPS, TR
      COMPLEX*16         TC
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANHE
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, dlamch, zlanhe, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zher, zscal, ztrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhe( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO 10 j = 1, n
         IF( dimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            RETURN
         END IF
   10 CONTINUE
*
*     Compute the product U**H * U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = dble( zdotc( k, afac( 1, k ), 1, afac( 1, k ), 1 ) )
            afac( k, k ) = tr
*
*           Compute the rest of column K.
*
            CALL ztrmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
   20    CONTINUE
*
*     Compute the product L * L**H, overwriting L.
*
      ELSE
         DO 30 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL zher( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            tc = afac( k, k )
            CALL zscal( n-k+1, tc, afac( k, k ), 1 )
*
   30    CONTINUE
      END IF
*
*     Compute the difference L * L**H - A (or U**H * U - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 50 j = 1, n
            DO 40 i = 1, j - 1
               afac( i, j ) = afac( i, j ) - a( i, j )
   40       CONTINUE
            afac( j, j ) = afac( j, j ) - dble( a( j, j ) )
   50    CONTINUE
      ELSE
         DO 70 j = 1, n
            afac( j, j ) = afac( j, j ) - dble( a( j, j ) )
            DO 60 i = j + 1, n
               afac( i, j ) = afac( i, j ) - a( i, j )
   60       CONTINUE
   70    CONTINUE
      END IF
*
*     Compute norm(L*U - A) / ( N * norm(A) * EPS )
*
      resid = zlanhe( '1', uplo, n, afac, ldafac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of ZPOT01
*

Here is the call graph for this function:

Here is the caller graph for this function: