zlaghe()

subroutine zlaghe	(	integer	n,
		integer	k,
		double precision, dimension( * )	d,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( 4 )	iseed,
		complex*16, dimension( * )	work,
		integer	info
	)

ZLAGHE

Purpose:

 ZLAGHE generates a complex hermitian matrix A, by pre- and post-
 multiplying a real diagonal matrix D with a random unitary matrix:
 A = U*D*U'. The semi-bandwidth may then be reduced to k by additional
 unitary transformations.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	K	K is INTEGER The number of nonzero subdiagonals within the band of A. 0 <= K <= N-1.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The diagonal elements of the diagonal matrix D.
[out]	A	A is COMPLEX*16 array, dimension (LDA,N) The generated n by n hermitian matrix A (the full matrix is stored).
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= N.
[in,out]	ISEED	ISEED is INTEGER array, dimension (4) On entry, the seed of the random number generator; the array elements must be between 0 and 4095, and ISEED(4) must be odd. On exit, the seed is updated.
[out]	WORK	WORK is COMPLEX*16 array, dimension (2*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file zlaghe.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      DOUBLE PRECISION   D( * )
      COMPLEX*16         A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ZERO, ONE, HALF
      parameter( zero = ( 0.0d+0, 0.0d+0 ),
     $                   one = ( 1.0d+0, 0.0d+0 ),
     $                   half = ( 0.5d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   WN
      COMPLEX*16         ALPHA, TAU, WA, WB
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zgemv, zgerc, zhemv, zher2,
     $                   zlarnv, zscal
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DZNRM2
      COMPLEX*16         ZDOTC
      EXTERNAL           dznrm2, zdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( k.LT.0 .OR. k.GT.n-1 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'ZLAGHE', -info )
         RETURN
      END IF
*
*     initialize lower triangle of A to diagonal matrix
*
      DO 20 j = 1, n
         DO 10 i = j + 1, n
            a( i, j ) = zero
   10    CONTINUE
   20 CONTINUE
      DO 30 i = 1, n
         a( i, i ) = d( i )
   30 CONTINUE
*
*     Generate lower triangle of hermitian matrix
*
      DO 40 i = n - 1, 1, -1
*
*        generate random reflection
*
         CALL zlarnv( 3, iseed, n-i+1, work )
         wn = dznrm2( n-i+1, work, 1 )
         wa = ( wn / abs( work( 1 ) ) )*work( 1 )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = work( 1 ) + wa
            CALL zscal( n-i, one / wb, work( 2 ), 1 )
            work( 1 ) = one
            tau = dble( wb / wa )
         END IF
*
*        apply random reflection to A(i:n,i:n) from the left
*        and the right
*
*        compute  y := tau * A * u
*
         CALL zhemv( 'Lower', n-i+1, tau, a( i, i ), lda, work, 1, zero,
     $               work( n+1 ), 1 )
*
*        compute  v := y - 1/2 * tau * ( y, u ) * u
*
         alpha = -half*tau*zdotc( n-i+1, work( n+1 ), 1, work, 1 )
         CALL zaxpy( n-i+1, alpha, work, 1, work( n+1 ), 1 )
*
*        apply the transformation as a rank-2 update to A(i:n,i:n)
*
         CALL zher2( 'Lower', n-i+1, -one, work, 1, work( n+1 ), 1,
     $               a( i, i ), lda )
   40 CONTINUE
*
*     Reduce number of subdiagonals to K
*
      DO 60 i = 1, n - 1 - k
*
*        generate reflection to annihilate A(k+i+1:n,i)
*
         wn = dznrm2( n-k-i+1, a( k+i, i ), 1 )
         wa = ( wn / abs( a( k+i, i ) ) )*a( k+i, i )
         IF( wn.EQ.zero ) THEN
            tau = zero
         ELSE
            wb = a( k+i, i ) + wa
            CALL zscal( n-k-i, one / wb, a( k+i+1, i ), 1 )
            a( k+i, i ) = one
            tau = dble( wb / wa )
         END IF
*
*        apply reflection to A(k+i:n,i+1:k+i-1) from the left
*
         CALL zgemv( 'Conjugate transpose', n-k-i+1, k-1, one,
     $               a( k+i, i+1 ), lda, a( k+i, i ), 1, zero, work, 1 )
         CALL zgerc( n-k-i+1, k-1, -tau, a( k+i, i ), 1, work, 1,
     $               a( k+i, i+1 ), lda )
*
*        apply reflection to A(k+i:n,k+i:n) from the left and the right
*
*        compute  y := tau * A * u
*
         CALL zhemv( 'Lower', n-k-i+1, tau, a( k+i, k+i ), lda,
     $               a( k+i, i ), 1, zero, work, 1 )
*
*        compute  v := y - 1/2 * tau * ( y, u ) * u
*
         alpha = -half*tau*zdotc( n-k-i+1, work, 1, a( k+i, i ), 1 )
         CALL zaxpy( n-k-i+1, alpha, a( k+i, i ), 1, work, 1 )
*
*        apply hermitian rank-2 update to A(k+i:n,k+i:n)
*
         CALL zher2( 'Lower', n-k-i+1, -one, a( k+i, i ), 1, work, 1,
     $               a( k+i, k+i ), lda )
*
         a( k+i, i ) = -wa
         DO 50 j = k + i + 1, n
            a( j, i ) = zero
   50    CONTINUE
   60 CONTINUE
*
*     Store full hermitian matrix
*
      DO 80 j = 1, n
         DO 70 i = j + 1, n
            a( j, i ) = dconjg( a( i, j ) )
   70    CONTINUE
   80 CONTINUE
      RETURN
*
*     End of ZLAGHE
*

Here is the call graph for this function:

Here is the caller graph for this function: