sget10()

subroutine sget10	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	work,
		real	result )

SGET10

Purpose:

!>
!> SGET10 compares two matrices A and B and computes the ratio
!> RESULT = norm( A - B ) / ( norm(A) * M * EPS )
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrices A and B. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and B. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The m by n matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in]	B	!> B is REAL array, dimension (LDB,N) !> The m by n matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,M). !>
[out]	WORK	!> WORK is REAL array, dimension (M) !>
[out]	RESULT	!> RESULT is REAL !> RESULT = norm( A - B ) / ( norm(A) * M * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 92 of file sget10.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, M, N
      REAL               RESULT
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      REAL               ANORM, EPS, UNFL, WNORM
*     ..
*     .. External Functions ..
      REAL               SASUM, SLAMCH, SLANGE
      EXTERNAL           sasum, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         result = zero
         RETURN
      END IF
*
      unfl = slamch( 'Safe minimum' )
      eps = slamch( 'Precision' )
*
      wnorm = zero
      DO 10 j = 1, n
         CALL scopy( m, a( 1, j ), 1, work, 1 )
         CALL saxpy( m, -one, b( 1, j ), 1, work, 1 )
         wnorm = max( wnorm, sasum( n, work, 1 ) )
   10 CONTINUE
*
      anorm = max( slange( '1', m, n, a, lda, work ), unfl )
*
      IF( anorm.GT.wnorm ) THEN
         result = ( wnorm / anorm ) / ( m*eps )
      ELSE
         IF( anorm.LT.one ) THEN
            result = ( min( wnorm, m*anorm ) / anorm ) / ( m*eps )
         ELSE
            result = min( wnorm / anorm, real( m ) ) / ( m*eps )
         END IF
      END IF
*
      RETURN
*
*     End of SGET10
*

Here is the call graph for this function:

Here is the caller graph for this function: