schkorhr_col.f

Go to the documentation of this file.

*> \brief \b SCHKORHR_COL
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKORHR_COL( THRESH, TSTERR, NM, MVAL, NN, NVAL, NNB,
*                                NBVAL, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NM, NN, NNB, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       INTEGER            MVAL( * ), NBVAL( * ), NVAL( * )
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKORHR_COL tests:
*>   1) SORGTSQR and SORHR_COL using SLATSQR, SGEMQRT,
*>   2) SORGTSQR_ROW and SORHR_COL inside DGETSQRHRT
*>      (which calls SLATSQR, SORGTSQR_ROW and SORHR_COL) using SGEMQRT.
*> Therefore, SLATSQR (part of SGEQR), SGEMQRT (part of SGEMQR)
*> have to be tested before this test.
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB contained in the vector NBVAL.
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE schkorhr_col( THRESH, TSTERR, NM, MVAL, NN, NVAL,
     $                         NNB, NBVAL, NOUT )
      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NN, NNB, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            MVAL( * ), NBVAL( * ), NVAL( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTESTS
      parameter( ntests = 6 )
*     ..
*     .. Local Scalars ..
      CHARACTER(LEN=3)   PATH
      INTEGER            I, IMB1, INB1, INB2, J, T, M, N, MB1, NB1,
     $                   nb2, nfail, nerrs, nrun
*
*     .. Local Arrays ..
      REAL               RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahd, alasum, serrorhr_col, sorhr_col01,
     $                   sorhr_col02
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER(LEN=32)  SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Initialize constants
*
      path( 1: 1 ) = 'S'
      path( 2: 3 ) = 'HH'
      nrun = 0
      nfail = 0
      nerrs = 0
*
*     Test the error exits
*
      IF( tsterr ) CALL serrorhr_col( path, nout )
      infot = 0
*
*     Do for each value of M in MVAL.
*
      DO i = 1, nm
         m = mval( i )
*
*        Do for each value of N in NVAL.
*
         DO j = 1, nn
            n = nval( j )
*
*           Only for M >= N
*
            IF ( min( m, n ).GT.0 .AND. m.GE.n ) THEN
*
*              Do for each possible value of MB1
*
               DO imb1 = 1, nnb
                  mb1 = nbval( imb1 )
*
*                 Only for MB1 > N
*
                  IF ( mb1.GT.n ) THEN
*
*                    Do for each possible value of NB1
*
                     DO inb1 = 1, nnb
                        nb1 = nbval( inb1 )
*
*                       Do for each possible value of NB2
*
                        DO inb2 = 1, nnb
                           nb2 = nbval( inb2 )
*
                           IF( nb1.GT.0 .AND. nb2.GT.0 ) THEN
*
*                             Test SORHR_COL
*
                              CALL sorhr_col01( m, n, mb1, nb1,
     $                                          nb2, result )
*
*                             Print information about the tests that did
*                             not pass the threshold.
*
                              DO t = 1, ntests
                                 IF( result( t ).GE.thresh ) THEN
                                    IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                              CALL alahd( nout, path )
                                    WRITE( nout, fmt = 9999 ) m, n, mb1,
     $                                     nb1, nb2, t, result( t )
                                    nfail = nfail + 1
                                 END IF
                              END DO
                              nrun = nrun + ntests
                           END IF
                        END DO
                     END DO
                  END IF
                END DO
            END IF
         END DO
      END DO
*
*     Do for each value of M in MVAL.
*
      DO i = 1, nm
         m = mval( i )
*
*        Do for each value of N in NVAL.
*
         DO j = 1, nn
            n = nval( j )
*
*           Only for M >= N
*
            IF ( min( m, n ).GT.0 .AND. m.GE.n ) THEN
*
*              Do for each possible value of MB1
*
               DO imb1 = 1, nnb
                  mb1 = nbval( imb1 )
*
*                 Only for MB1 > N
*
                  IF ( mb1.GT.n ) THEN
*
*                    Do for each possible value of NB1
*
                     DO inb1 = 1, nnb
                        nb1 = nbval( inb1 )
*
*                       Do for each possible value of NB2
*
                        DO inb2 = 1, nnb
                           nb2 = nbval( inb2 )
*
                           IF( nb1.GT.0 .AND. nb2.GT.0 ) THEN
*
*                             Test SORHR_COL
*
                              CALL sorhr_col02( m, n, mb1, nb1,
     $                                          nb2, result )
*
*                             Print information about the tests that did
*                             not pass the threshold.
*
                              DO t = 1, ntests
                                 IF( result( t ).GE.thresh ) THEN
                                    IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                              CALL alahd( nout, path )
                                    WRITE( nout, fmt = 9998 ) m, n, mb1,
     $                                     nb1, nb2, t, result( t )
                                    nfail = nfail + 1
                                 END IF
                              END DO
                              nrun = nrun + ntests
                           END IF
                        END DO
                     END DO
                  END IF
                END DO
            END IF
         END DO
      END DO
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 'SORGTSQR and SORHR_COL: M=', i5, ', N=', i5,
     $        ', MB1=', i5, ', NB1=', i5, ', NB2=', i5,
     $        ' test(', i2, ')=', g12.5 )
 9998 FORMAT( 'SORGTSQR_ROW and SORHR_COL: M=', i5, ', N=', i5,
     $        ', MB1=', i5, ', NB1=', i5, ', NB2=', i5,
     $        ' test(', i2, ')=', g12.5 )
      RETURN
*
*     End of SCHKORHR_COL
*
      END