dlat2s()

subroutine dlat2s	(	character	uplo,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldsa, * )	sa,
		integer	ldsa,
		integer	info
	)

DLAT2S converts a double-precision triangular matrix to a single-precision triangular matrix.

Download DLAT2S + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLAT2S converts a DOUBLE PRECISION triangular matrix, SA, to a SINGLE
 PRECISION triangular matrix, A.

 RMAX is the overflow for the SINGLE PRECISION arithmetic
 DLAS2S checks that all the entries of A are between -RMAX and
 RMAX. If not the conversion is aborted and a flag is raised.

 This is an auxiliary routine so there is no argument checking.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': A is upper triangular; = 'L': A is lower triangular.
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the N-by-N triangular coefficient matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	SA	SA is REAL array, dimension (LDSA,N) Only the UPLO part of SA is referenced. On exit, if INFO=0, the N-by-N coefficient matrix SA; if INFO>0, the content of the UPLO part of SA is unspecified.
[in]	LDSA	LDSA is INTEGER The leading dimension of the array SA. LDSA >= max(1,M).
[out]	INFO	INFO is INTEGER = 0: successful exit. = 1: an entry of the matrix A is greater than the SINGLE PRECISION overflow threshold, in this case, the content of the UPLO part of SA in exit is unspecified.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 110 of file dlat2s.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, LDSA, N
*     ..
*     .. Array Arguments ..
      REAL               SA( LDSA, * )
      DOUBLE PRECISION   A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   RMAX
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      LOGICAL            LSAME
      EXTERNAL           slamch, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
      rmax = slamch( 'O' )
      upper = lsame( uplo, 'U' )
      IF( upper ) THEN
         DO 20 j = 1, n
            DO 10 i = 1, j
               IF( ( a( i, j ).LT.-rmax ) .OR. ( a( i, j ).GT.rmax ) )
     $             THEN
                  info = 1
                  GO TO 50
               END IF
               sa( i, j ) = real( a( i, j ) )
   10       CONTINUE
   20    CONTINUE
      ELSE
         DO 40 j = 1, n
            DO 30 i = j, n
               IF( ( a( i, j ).LT.-rmax ) .OR. ( a( i, j ).GT.rmax ) )
     $             THEN
                  info = 1
                  GO TO 50
               END IF
               sa( i, j ) = real( a( i, j ) )
   30       CONTINUE
   40    CONTINUE
      END IF
   50 CONTINUE
*
      RETURN
*
*     End of DLAT2S
*

Here is the caller graph for this function: