zpptrs()

subroutine zpptrs	(	character	uplo,
		integer	n,
		integer	nrhs,
		complex*16, dimension( * )	ap,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		integer	info
	)

ZPPTRS

Download ZPPTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZPPTRS solves a system of linear equations A*X = B with a Hermitian
 positive definite matrix A in packed storage using the Cholesky
 factorization A = U**H * U or A = L * L**H computed by ZPPTRF.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	AP	AP is COMPLEX*16 array, dimension (N*(N+1)/2) The triangular factor U or L from the Cholesky factorization A = U**H * U or A = L * L**H, packed columnwise in a linear array. The j-th column of U or L is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 107 of file zpptrs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         AP( * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, ztpsv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPPTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B where A = U**H * U.
*
         DO 10 i = 1, nrhs
*
*           Solve U**H *X = B, overwriting B with X.
*
            CALL ztpsv( 'Upper', 'Conjugate transpose', 'Non-unit', n,
     $                  ap, b( 1, i ), 1 )
*
*           Solve U*X = B, overwriting B with X.
*
            CALL ztpsv( 'Upper', 'No transpose', 'Non-unit', n, ap,
     $                  b( 1, i ), 1 )
   10    CONTINUE
      ELSE
*
*        Solve A*X = B where A = L * L**H.
*
         DO 20 i = 1, nrhs
*
*           Solve L*Y = B, overwriting B with X.
*
            CALL ztpsv( 'Lower', 'No transpose', 'Non-unit', n, ap,
     $                  b( 1, i ), 1 )
*
*           Solve L**H *X = Y, overwriting B with X.
*
            CALL ztpsv( 'Lower', 'Conjugate transpose', 'Non-unit', n,
     $                  ap, b( 1, i ), 1 )
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of ZPPTRS
*

Here is the call graph for this function:

Here is the caller graph for this function: