ddrges()

subroutine ddrges	(	integer	nsizes,
		integer, dimension( * )	nn,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer, dimension( 4 )	iseed,
		double precision	thresh,
		integer	nounit,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( lda, * )	b,
		double precision, dimension( lda, * )	s,
		double precision, dimension( lda, * )	t,
		double precision, dimension( ldq, * )	q,
		integer	ldq,
		double precision, dimension( ldq, * )	z,
		double precision, dimension( * )	alphar,
		double precision, dimension( * )	alphai,
		double precision, dimension( * )	beta,
		double precision, dimension( * )	work,
		integer	lwork,
		double precision, dimension( 13 )	result,
		logical, dimension( * )	bwork,
		integer	info )

DDRGES

Purpose:

!>
!> DDRGES checks the nonsymmetric generalized eigenvalue (Schur form)
!> problem driver DGGES.
!>
!> DGGES factors A and B as Q S Z'  and Q T Z' , where ' means
!> transpose, T is upper triangular, S is in generalized Schur form
!> (block upper triangular, with 1x1 and 2x2 blocks on the diagonal,
!> the 2x2 blocks corresponding to complex conjugate pairs of
!> generalized eigenvalues), and Q and Z are orthogonal. It also
!> computes the generalized eigenvalues (alpha(j),beta(j)), j=1,...,n,
!> Thus, w(j) = alpha(j)/beta(j) is a root of the characteristic
!> equation
!>                 det( A - w(j) B ) = 0
!> Optionally it also reorder the eigenvalues so that a selected
!> cluster of eigenvalues appears in the leading diagonal block of the
!> Schur forms.
!>
!> When DDRGES is called, a number of matrix  () and a
!> number of matrix  are specified.  For each size ()
!> and each TYPE of matrix, a pair of matrices (A, B) will be generated
!> and used for testing. For each matrix pair, the following 13 tests
!> will be performed and compared with the threshold THRESH except
!> the tests (5), (11) and (13).
!>
!>
!> (1)   | A - Q S Z' | / ( |A| n ulp ) (no sorting of eigenvalues)
!>
!>
!> (2)   | B - Q T Z' | / ( |B| n ulp ) (no sorting of eigenvalues)
!>
!>
!> (3)   | I - QQ' | / ( n ulp ) (no sorting of eigenvalues)
!>
!>
!> (4)   | I - ZZ' | / ( n ulp ) (no sorting of eigenvalues)
!>
!> (5)   if A is in Schur form (i.e. quasi-triangular form)
!>       (no sorting of eigenvalues)
!>
!> (6)   if eigenvalues = diagonal blocks of the Schur form (S, T),
!>       i.e., test the maximum over j of D(j)  where:
!>
!>       if alpha(j) is real:
!>                     |alpha(j) - S(j,j)|        |beta(j) - T(j,j)|
!>           D(j) = ------------------------ + -----------------------
!>                  max(|alpha(j)|,|S(j,j)|)   max(|beta(j)|,|T(j,j)|)
!>
!>       if alpha(j) is complex:
!>                                 | det( s S - w T ) |
!>           D(j) = ---------------------------------------------------
!>                  ulp max( s norm(S), |w| norm(T) )*norm( s S - w T )
!>
!>       and S and T are here the 2 x 2 diagonal blocks of S and T
!>       corresponding to the j-th and j+1-th eigenvalues.
!>       (no sorting of eigenvalues)
!>
!> (7)   | (A,B) - Q (S,T) Z' | / ( | (A,B) | n ulp )
!>            (with sorting of eigenvalues).
!>
!> (8)   | I - QQ' | / ( n ulp ) (with sorting of eigenvalues).
!>
!> (9)   | I - ZZ' | / ( n ulp ) (with sorting of eigenvalues).
!>
!> (10)  if A is in Schur form (i.e. quasi-triangular form)
!>       (with sorting of eigenvalues).
!>
!> (11)  if eigenvalues = diagonal blocks of the Schur form (S, T),
!>       i.e. test the maximum over j of D(j)  where:
!>
!>       if alpha(j) is real:
!>                     |alpha(j) - S(j,j)|        |beta(j) - T(j,j)|
!>           D(j) = ------------------------ + -----------------------
!>                  max(|alpha(j)|,|S(j,j)|)   max(|beta(j)|,|T(j,j)|)
!>
!>       if alpha(j) is complex:
!>                                 | det( s S - w T ) |
!>           D(j) = ---------------------------------------------------
!>                  ulp max( s norm(S), |w| norm(T) )*norm( s S - w T )
!>
!>       and S and T are here the 2 x 2 diagonal blocks of S and T
!>       corresponding to the j-th and j+1-th eigenvalues.
!>       (with sorting of eigenvalues).
!>
!> (12)  if sorting worked and SDIM is the number of eigenvalues
!>       which were SELECTed.
!>
!> Test Matrices
!> =============
!>
!> The sizes of the test matrices are specified by an array
!> NN(1:NSIZES); the value of each element NN(j) specifies one size.
!> The  are specified by a logical array DOTYPE( 1:NTYPES ); if
!> DOTYPE(j) is .TRUE., then matrix type  will be generated.
!> Currently, the list of possible types is:
!>
!> (1)  ( 0, 0 )         (a pair of zero matrices)
!>
!> (2)  ( I, 0 )         (an identity and a zero matrix)
!>
!> (3)  ( 0, I )         (an identity and a zero matrix)
!>
!> (4)  ( I, I )         (a pair of identity matrices)
!>
!>         t   t
!> (5)  ( J , J  )       (a pair of transposed Jordan blocks)
!>
!>                                     t                ( I   0  )
!> (6)  ( X, Y )         where  X = ( J   0  )  and Y = (      t )
!>                                  ( 0   I  )          ( 0   J  )
!>                       and I is a k x k identity and J a (k+1)x(k+1)
!>                       Jordan block; k=(N-1)/2
!>
!> (7)  ( D, I )         where D is diag( 0, 1,..., N-1 ) (a diagonal
!>                       matrix with those diagonal entries.)
!> (8)  ( I, D )
!>
!> (9)  ( big*D, small*I ) where  is near overflow and small=1/big
!>
!> (10) ( small*D, big*I )
!>
!> (11) ( big*I, small*D )
!>
!> (12) ( small*I, big*D )
!>
!> (13) ( big*D, big*I )
!>
!> (14) ( small*D, small*I )
!>
!> (15) ( D1, D2 )        where D1 is diag( 0, 0, 1, ..., N-3, 0 ) and
!>                        D2 is diag( 0, N-3, N-4,..., 1, 0, 0 )
!>           t   t
!> (16) Q ( J , J ) Z     where Q and Z are random orthogonal matrices.
!>
!> (17) Q ( T1, T2 ) Z    where T1 and T2 are upper triangular matrices
!>                        with random O(1) entries above the diagonal
!>                        and diagonal entries diag(T1) =
!>                        ( 0, 0, 1, ..., N-3, 0 ) and diag(T2) =
!>                        ( 0, N-3, N-4,..., 1, 0, 0 )
!>
!> (18) Q ( T1, T2 ) Z    diag(T1) = ( 0, 0, 1, 1, s, ..., s, 0 )
!>                        diag(T2) = ( 0, 1, 0, 1,..., 1, 0 )
!>                        s = machine precision.
!>
!> (19) Q ( T1, T2 ) Z    diag(T1)=( 0,0,1,1, 1-d, ..., 1-(N-5)*d=s, 0 )
!>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0 )
!>
!>                                                        N-5
!> (20) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, 1, a, ..., a   =s, 0 )
!>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
!>
!> (21) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, r1, r2, ..., r(N-4), 0 )
!>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
!>                        where r1,..., r(N-4) are random.
!>
!> (22) Q ( big*T1, small*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
!>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
!>
!> (23) Q ( small*T1, big*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
!>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
!>
!> (24) Q ( small*T1, small*T2 ) Z  diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
!>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
!>
!> (25) Q ( big*T1, big*T2 ) Z      diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
!>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
!>
!> (26) Q ( T1, T2 ) Z     where T1 and T2 are random upper-triangular
!>                         matrices.
!>
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of sizes of matrices to use. If it is zero, !> DDRGES does nothing. NSIZES >= 0. !>
[in]	NN	!> NN is INTEGER array, dimension (NSIZES) !> An array containing the sizes to be used for the matrices. !> Zero values will be skipped. NN >= 0. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. If it is zero, DDRGES !> does nothing. It must be at least zero. If it is MAXTYP+1 !> and NSIZES is 1, then an additional type, MAXTYP+1 is !> defined, which is to use whatever matrix is in A on input. !> This is only useful if DOTYPE(1:MAXTYP) is .FALSE. and !> DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size in NN a !> matrix of that size and of type j will be generated. !> If NTYPES is smaller than the maximum number of types !> defined (PARAMETER MAXTYP), then types NTYPES+1 through !> MAXTYP will not be generated. If NTYPES is larger !> than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES) !> will be ignored. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The random number generator uses a linear !> congruential sequence limited to small integers, and so !> should produce machine independent random numbers. The !> values of ISEED are changed on exit, and can be used in the !> next call to DDRGES to continue the same random number !> sequence. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> A test will count as if the , computed as !> described above, exceeds THRESH. Note that the error is !> scaled to be O(1), so THRESH should be a reasonably small !> multiple of 1, e.g., 10 or 100. In particular, it should !> not depend on the precision (single vs. double) or the size !> of the matrix. THRESH >= 0. !>
[in]	NOUNIT	!> NOUNIT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns IINFO not equal to 0.) !>
[in,out]	A	!> A is DOUBLE PRECISION array, !> dimension(LDA, max(NN)) !> Used to hold the original A matrix. Used as input only !> if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and !> DOTYPE(MAXTYP+1)=.TRUE. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A, B, S, and T. !> It must be at least 1 and at least max( NN ). !>
[in,out]	B	!> B is DOUBLE PRECISION array, !> dimension(LDA, max(NN)) !> Used to hold the original B matrix. Used as input only !> if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and !> DOTYPE(MAXTYP+1)=.TRUE. !>
[out]	S	!> S is DOUBLE PRECISION array, dimension (LDA, max(NN)) !> The Schur form matrix computed from A by DGGES. On exit, S !> contains the Schur form matrix corresponding to the matrix !> in A. !>
[out]	T	!> T is DOUBLE PRECISION array, dimension (LDA, max(NN)) !> The upper triangular matrix computed from B by DGGES. !>
[out]	Q	!> Q is DOUBLE PRECISION array, dimension (LDQ, max(NN)) !> The (left) orthogonal matrix computed by DGGES. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of Q and Z. It must !> be at least 1 and at least max( NN ). !>
[out]	Z	!> Z is DOUBLE PRECISION array, dimension( LDQ, max(NN) ) !> The (right) orthogonal matrix computed by DGGES. !>
[out]	ALPHAR	!> ALPHAR is DOUBLE PRECISION array, dimension (max(NN)) !>
[out]	ALPHAI	!> ALPHAI is DOUBLE PRECISION array, dimension (max(NN)) !>
[out]	BETA	!> BETA is DOUBLE PRECISION array, dimension (max(NN)) !> !> The generalized eigenvalues of (A,B) computed by DGGES. !> ( ALPHAR(k)+ALPHAI(k)*i ) / BETA(k) is the k-th !> generalized eigenvalue of A and B. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> LWORK >= MAX( 10*(N+1), 3*N*N ), where N is the largest !> matrix dimension. !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (15) !> The values computed by the tests described above. !> The values are currently limited to 1/ulp, to avoid overflow. !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: A routine returned an error code. INFO is the !> absolute value of the INFO value returned. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 399 of file ddrges.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDQ, LWORK, NOUNIT, NSIZES, NTYPES
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * ), DOTYPE( * )
      INTEGER            ISEED( 4 ), NN( * )
      DOUBLE PRECISION   A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
     $                   B( LDA, * ), BETA( * ), Q( LDQ, * ),
     $                   RESULT( 13 ), S( LDA, * ), T( LDA, * ),
     $                   WORK( * ), Z( LDQ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      INTEGER            MAXTYP
      parameter( maxtyp = 26 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN, ILABAD
      CHARACTER          SORT
      INTEGER            I, I1, IADD, IERR, IINFO, IN, ISORT, J, JC, JR,
     $                   JSIZE, JTYPE, KNTEIG, MAXWRK, MINWRK, MTYPES,
     $                   N, N1, NB, NERRS, NMATS, NMAX, NTEST, NTESTT,
     $                   RSUB, SDIM
      DOUBLE PRECISION   SAFMAX, SAFMIN, TEMP1, TEMP2, ULP, ULPINV
*     ..
*     .. Local Arrays ..
      INTEGER            IASIGN( MAXTYP ), IBSIGN( MAXTYP ),
     $                   IOLDSD( 4 ), KADD( 6 ), KAMAGN( MAXTYP ),
     $                   KATYPE( MAXTYP ), KAZERO( MAXTYP ),
     $                   KBMAGN( MAXTYP ), KBTYPE( MAXTYP ),
     $                   KBZERO( MAXTYP ), KCLASS( MAXTYP ),
     $                   KTRIAN( MAXTYP ), KZ1( 6 ), KZ2( 6 )
      DOUBLE PRECISION   RMAGN( 0: 3 )
*     ..
*     .. External Functions ..
      LOGICAL            DLCTES
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, DLARND
      EXTERNAL           dlctes, ilaenv, dlamch, dlarnd
*     ..
*     .. External Subroutines ..
      EXTERNAL           alasvm, dget51, dget53, dget54, dgges, dlacpy,
     $                   dlarfg, dlaset, dlatm4, dorm2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min, sign
*     ..
*     .. Data statements ..
      DATA               kclass / 15*1, 10*2, 1*3 /
      DATA               kz1 / 0, 1, 2, 1, 3, 3 /
      DATA               kz2 / 0, 0, 1, 2, 1, 1 /
      DATA               kadd / 0, 0, 0, 0, 3, 2 /
      DATA               katype / 0, 1, 0, 1, 2, 3, 4, 1, 4, 4, 1, 1, 4,
     $                   4, 4, 2, 4, 5, 8, 7, 9, 4*4, 0 /
      DATA               kbtype / 0, 0, 1, 1, 2, -3, 1, 4, 1, 1, 4, 4,
     $                   1, 1, -4, 2, -4, 8*8, 0 /
      DATA               kazero / 6*1, 2, 1, 2*2, 2*1, 2*2, 3, 1, 3,
     $                   4*5, 4*3, 1 /
      DATA               kbzero / 6*1, 1, 2, 2*1, 2*2, 2*1, 4, 1, 4,
     $                   4*6, 4*4, 1 /
      DATA               kamagn / 8*1, 2, 3, 2, 3, 2, 3, 7*1, 2, 3, 3,
     $                   2, 1 /
      DATA               kbmagn / 8*1, 3, 2, 3, 2, 2, 3, 7*1, 3, 2, 3,
     $                   2, 1 /
      DATA               ktrian / 16*0, 10*1 /
      DATA               iasign / 6*0, 2, 0, 2*2, 2*0, 3*2, 0, 2, 3*0,
     $                   5*2, 0 /
      DATA               ibsign / 7*0, 2, 2*0, 2*2, 2*0, 2, 0, 2, 9*0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badnn = .false.
      nmax = 1
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldq.LE.1 .OR. ldq.LT.nmax ) THEN
         info = -14
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.
*
      minwrk = 1
      IF( info.EQ.0 .AND. lwork.GE.1 ) THEN
         minwrk = max( 10*( nmax+1 ), 3*nmax*nmax )
         nb = max( 1, ilaenv( 1, 'DGEQRF', ' ', nmax, nmax, -1, -1 ),
     $        ilaenv( 1, 'DORMQR', 'LT', nmax, nmax, nmax, -1 ),
     $        ilaenv( 1, 'DORGQR', ' ', nmax, nmax, nmax, -1 ) )
         maxwrk = max( 10*( nmax+1 ), 2*nmax+nmax*nb, 3*nmax*nmax )
         work( 1 ) = maxwrk
      END IF
*
      IF( lwork.LT.minwrk )
     $   info = -20
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DDRGES', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
      safmin = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
      safmin = safmin / ulp
      safmax = one / safmin
      ulpinv = one / ulp
*
*     The values RMAGN(2:3) depend on N, see below.
*
      rmagn( 0 ) = zero
      rmagn( 1 ) = one
*
*     Loop over matrix sizes
*
      ntestt = 0
      nerrs = 0
      nmats = 0
*
      DO 190 jsize = 1, nsizes
         n = nn( jsize )
         n1 = max( 1, n )
         rmagn( 2 ) = safmax*ulp / dble( n1 )
         rmagn( 3 ) = safmin*ulpinv*dble( n1 )
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
*        Loop over matrix types
*
         DO 180 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 180
            nmats = nmats + 1
            ntest = 0
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Initialize RESULT
*
            DO 30 j = 1, 13
               result( j ) = zero
   30       CONTINUE
*
*           Generate test matrices A and B
*
*           Description of control parameters:
*
*           KZLASS: =1 means w/o rotation, =2 means w/ rotation,
*                   =3 means random.
*           KATYPE: the "type" to be passed to DLATM4 for computing A.
*           KAZERO: the pattern of zeros on the diagonal for A:
*                   =1: ( xxx ), =2: (0, xxx ) =3: ( 0, 0, xxx, 0 ),
*                   =4: ( 0, xxx, 0, 0 ), =5: ( 0, 0, 1, xxx, 0 ),
*                   =6: ( 0, 1, 0, xxx, 0 ).  (xxx means a string of
*                   non-zero entries.)
*           KAMAGN: the magnitude of the matrix: =0: zero, =1: O(1),
*                   =2: large, =3: small.
*           IASIGN: 1 if the diagonal elements of A are to be
*                   multiplied by a random magnitude 1 number, =2 if
*                   randomly chosen diagonal blocks are to be rotated
*                   to form 2x2 blocks.
*           KBTYPE, KBZERO, KBMAGN, IBSIGN: the same, but for B.
*           KTRIAN: =0: don't fill in the upper triangle, =1: do.
*           KZ1, KZ2, KADD: used to implement KAZERO and KBZERO.
*           RMAGN: used to implement KAMAGN and KBMAGN.
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 110
            iinfo = 0
            IF( kclass( jtype ).LT.3 ) THEN
*
*              Generate A (w/o rotation)
*
               IF( abs( katype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL dlaset( 'Full', n, n, zero, zero, a, lda )
               ELSE
                  in = n
               END IF
               CALL dlatm4( katype( jtype ), in, kz1( kazero( jtype ) ),
     $                      kz2( kazero( jtype ) ), iasign( jtype ),
     $                      rmagn( kamagn( jtype ) ), ulp,
     $                      rmagn( ktrian( jtype )*kamagn( jtype ) ), 2,
     $                      iseed, a, lda )
               iadd = kadd( kazero( jtype ) )
               IF( iadd.GT.0 .AND. iadd.LE.n )
     $            a( iadd, iadd ) = one
*
*              Generate B (w/o rotation)
*
               IF( abs( kbtype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL dlaset( 'Full', n, n, zero, zero, b, lda )
               ELSE
                  in = n
               END IF
               CALL dlatm4( kbtype( jtype ), in, kz1( kbzero( jtype ) ),
     $                      kz2( kbzero( jtype ) ), ibsign( jtype ),
     $                      rmagn( kbmagn( jtype ) ), one,
     $                      rmagn( ktrian( jtype )*kbmagn( jtype ) ), 2,
     $                      iseed, b, lda )
               iadd = kadd( kbzero( jtype ) )
               IF( iadd.NE.0 .AND. iadd.LE.n )
     $            b( iadd, iadd ) = one
*
               IF( kclass( jtype ).EQ.2 .AND. n.GT.0 ) THEN
*
*                 Include rotations
*
*                 Generate Q, Z as Householder transformations times
*                 a diagonal matrix.
*
                  DO 50 jc = 1, n - 1
                     DO 40 jr = jc, n
                        q( jr, jc ) = dlarnd( 3, iseed )
                        z( jr, jc ) = dlarnd( 3, iseed )
   40                CONTINUE
                     CALL dlarfg( n+1-jc, q( jc, jc ), q( jc+1, jc ), 1,
     $                            work( jc ) )
                     work( 2*n+jc ) = sign( one, q( jc, jc ) )
                     q( jc, jc ) = one
                     CALL dlarfg( n+1-jc, z( jc, jc ), z( jc+1, jc ), 1,
     $                            work( n+jc ) )
                     work( 3*n+jc ) = sign( one, z( jc, jc ) )
                     z( jc, jc ) = one
   50             CONTINUE
                  q( n, n ) = one
                  work( n ) = zero
                  work( 3*n ) = sign( one, dlarnd( 2, iseed ) )
                  z( n, n ) = one
                  work( 2*n ) = zero
                  work( 4*n ) = sign( one, dlarnd( 2, iseed ) )
*
*                 Apply the diagonal matrices
*
                  DO 70 jc = 1, n
                     DO 60 jr = 1, n
                        a( jr, jc ) = work( 2*n+jr )*work( 3*n+jc )*
     $                                a( jr, jc )
                        b( jr, jc ) = work( 2*n+jr )*work( 3*n+jc )*
     $                                b( jr, jc )
   60                CONTINUE
   70             CONTINUE
                  CALL dorm2r( 'L', 'N', n, n, n-1, q, ldq, work, a,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL dorm2r( 'R', 'T', n, n, n-1, z, ldq, work( n+1 ),
     $                         a, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL dorm2r( 'L', 'N', n, n, n-1, q, ldq, work, b,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL dorm2r( 'R', 'T', n, n, n-1, z, ldq, work( n+1 ),
     $                         b, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
               END IF
            ELSE
*
*              Random matrices
*
               DO 90 jc = 1, n
                  DO 80 jr = 1, n
                     a( jr, jc ) = rmagn( kamagn( jtype ) )*
     $                             dlarnd( 2, iseed )
                     b( jr, jc ) = rmagn( kbmagn( jtype ) )*
     $                             dlarnd( 2, iseed )
   80             CONTINUE
   90          CONTINUE
            END IF
*
  100       CONTINUE
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
  110       CONTINUE
*
            DO 120 i = 1, 13
               result( i ) = -one
  120       CONTINUE
*
*           Test with and without sorting of eigenvalues
*
            DO 150 isort = 0, 1
               IF( isort.EQ.0 ) THEN
                  sort = 'N'
                  rsub = 0
               ELSE
                  sort = 'S'
                  rsub = 5
               END IF
*
*              Call DGGES to compute H, T, Q, Z, alpha, and beta.
*
               CALL dlacpy( 'Full', n, n, a, lda, s, lda )
               CALL dlacpy( 'Full', n, n, b, lda, t, lda )
               ntest = 1 + rsub + isort
               result( 1+rsub+isort ) = ulpinv
               CALL dgges( 'V', 'V', sort, dlctes, n, s, lda, t, lda,
     $                     sdim, alphar, alphai, beta, q, ldq, z, ldq,
     $                     work, lwork, bwork, iinfo )
               IF( iinfo.NE.0 .AND. iinfo.NE.n+2 ) THEN
                  result( 1+rsub+isort ) = ulpinv
                  WRITE( nounit, fmt = 9999 )'DGGES', iinfo, n, jtype,
     $               ioldsd
                  info = abs( iinfo )
                  GO TO 160
               END IF
*
               ntest = 4 + rsub
*
*              Do tests 1--4 (or tests 7--9 when reordering )
*
               IF( isort.EQ.0 ) THEN
                  CALL dget51( 1, n, a, lda, s, lda, q, ldq, z, ldq,
     $                         work, result( 1 ) )
                  CALL dget51( 1, n, b, lda, t, lda, q, ldq, z, ldq,
     $                         work, result( 2 ) )
               ELSE
                  CALL dget54( n, a, lda, b, lda, s, lda, t, lda, q,
     $                         ldq, z, ldq, work, result( 7 ) )
               END IF
               CALL dget51( 3, n, a, lda, t, lda, q, ldq, q, ldq, work,
     $                      result( 3+rsub ) )
               CALL dget51( 3, n, b, lda, t, lda, z, ldq, z, ldq, work,
     $                      result( 4+rsub ) )
*
*              Do test 5 and 6 (or Tests 10 and 11 when reordering):
*              check Schur form of A and compare eigenvalues with
*              diagonals.
*
               ntest = 6 + rsub
               temp1 = zero
*
               DO 130 j = 1, n
                  ilabad = .false.
                  IF( alphai( j ).EQ.zero ) THEN
                     temp2 = ( abs( alphar( j )-s( j, j ) ) /
     $                       max( safmin, abs( alphar( j ) ), abs( s( j,
     $                       j ) ) )+abs( beta( j )-t( j, j ) ) /
     $                       max( safmin, abs( beta( j ) ), abs( t( j,
     $                       j ) ) ) ) / ulp
*
                     IF( j.LT.n ) THEN
                        IF( s( j+1, j ).NE.zero ) THEN
                           ilabad = .true.
                           result( 5+rsub ) = ulpinv
                        END IF
                     END IF
                     IF( j.GT.1 ) THEN
                        IF( s( j, j-1 ).NE.zero ) THEN
                           ilabad = .true.
                           result( 5+rsub ) = ulpinv
                        END IF
                     END IF
*
                  ELSE
                     IF( alphai( j ).GT.zero ) THEN
                        i1 = j
                     ELSE
                        i1 = j - 1
                     END IF
                     IF( i1.LE.0 .OR. i1.GE.n ) THEN
                        ilabad = .true.
                     ELSE IF( i1.LT.n-1 ) THEN
                        IF( s( i1+2, i1+1 ).NE.zero ) THEN
                           ilabad = .true.
                           result( 5+rsub ) = ulpinv
                        END IF
                     ELSE IF( i1.GT.1 ) THEN
                        IF( s( i1, i1-1 ).NE.zero ) THEN
                           ilabad = .true.
                           result( 5+rsub ) = ulpinv
                        END IF
                     END IF
                     IF( .NOT.ilabad ) THEN
                        CALL dget53( s( i1, i1 ), lda, t( i1, i1 ), lda,
     $                               beta( j ), alphar( j ),
     $                               alphai( j ), temp2, ierr )
                        IF( ierr.GE.3 ) THEN
                           WRITE( nounit, fmt = 9998 )ierr, j, n,
     $                        jtype, ioldsd
                           info = abs( ierr )
                        END IF
                     ELSE
                        temp2 = ulpinv
                     END IF
*
                  END IF
                  temp1 = max( temp1, temp2 )
                  IF( ilabad ) THEN
                     WRITE( nounit, fmt = 9997 )j, n, jtype, ioldsd
                  END IF
  130          CONTINUE
               result( 6+rsub ) = temp1
*
               IF( isort.GE.1 ) THEN
*
*                 Do test 12
*
                  ntest = 12
                  result( 12 ) = zero
                  knteig = 0
                  DO 140 i = 1, n
                     IF( dlctes( alphar( i ), alphai( i ),
     $                   beta( i ) ) .OR. dlctes( alphar( i ),
     $                   -alphai( i ), beta( i ) ) ) THEN
                        knteig = knteig + 1
                     END IF
                     IF( i.LT.n ) THEN
                        IF( ( dlctes( alphar( i+1 ), alphai( i+1 ),
     $                      beta( i+1 ) ) .OR. dlctes( alphar( i+1 ),
     $                      -alphai( i+1 ), beta( i+1 ) ) ) .AND.
     $                      ( .NOT.( dlctes( alphar( i ), alphai( i ),
     $                      beta( i ) ) .OR. dlctes( alphar( i ),
     $                      -alphai( i ), beta( i ) ) ) ) .AND.
     $                      iinfo.NE.n+2 ) THEN
                           result( 12 ) = ulpinv
                        END IF
                     END IF
  140             CONTINUE
                  IF( sdim.NE.knteig ) THEN
                     result( 12 ) = ulpinv
                  END IF
               END IF
*
  150       CONTINUE
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  160       CONTINUE
*
            ntestt = ntestt + ntest
*
*           Print out tests which fail.
*
            DO 170 jr = 1, ntest
               IF( result( jr ).GE.thresh ) THEN
*
*                 If this is the first test to fail,
*                 print a header to the data file.
*
                  IF( nerrs.EQ.0 ) THEN
                     WRITE( nounit, fmt = 9996 )'DGS'
*
*                    Matrix types
*
                     WRITE( nounit, fmt = 9995 )
                     WRITE( nounit, fmt = 9994 )
                     WRITE( nounit, fmt = 9993 )'Orthogonal'
*
*                    Tests performed
*
                     WRITE( nounit, fmt = 9992 )'orthogonal', '''',
     $                  'transpose', ( '''', j = 1, 8 )
*
                  END IF
                  nerrs = nerrs + 1
                  IF( result( jr ).LT.10000.0d0 ) THEN
                     WRITE( nounit, fmt = 9991 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  ELSE
                     WRITE( nounit, fmt = 9990 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  END IF
               END IF
  170       CONTINUE
*
  180    CONTINUE
  190 CONTINUE
*
*     Summary
*
      CALL alasvm( 'DGS', nounit, nerrs, ntestt, 0 )
*
      work( 1 ) = maxwrk
*
      RETURN
*
 9999 FORMAT( ' DDRGES: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 4( i4, ',' ), i5, ')' )
*
 9998 FORMAT( ' DDRGES: DGET53 returned INFO=', i1, ' for eigenvalue ',
     $      i6, '.', / 9x, 'N=', i6, ', JTYPE=', i6, ', ISEED=(',
     $      4( i4, ',' ), i5, ')' )
*
 9997 FORMAT( ' DDRGES: S not in Schur form at eigenvalue ', i6, '.',
     $      / 9x, 'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ),
     $      i5, ')' )
*
 9996 FORMAT( / 1x, a3, ' -- Real Generalized Schur form driver' )
*
 9995 FORMAT( ' Matrix types (see DDRGES for details): ' )
*
 9994 FORMAT( ' Special Matrices:', 23x,
     $      '(J''=transposed Jordan block)',
     $      / '   1=(0,0)  2=(I,0)  3=(0,I)  4=(I,I)  5=(J'',J'')  ',
     $      '6=(diag(J'',I), diag(I,J''))', / ' Diagonal Matrices:  ( ',
     $      'D=diag(0,1,2,...) )', / '   7=(D,I)   9=(large*D, small*I',
     $      ')  11=(large*I, small*D)  13=(large*D, large*I)', /
     $      '   8=(I,D)  10=(small*D, large*I)  12=(small*I, large*D) ',
     $      ' 14=(small*D, small*I)', / '  15=(D, reversed D)' )
 9993 FORMAT( ' Matrices Rotated by Random ', a, ' Matrices U, V:',
     $      / '  16=Transposed Jordan Blocks             19=geometric ',
     $      'alpha, beta=0,1', / '  17=arithm. alpha&beta             ',
     $      '      20=arithmetic alpha, beta=0,1', / '  18=clustered ',
     $      'alpha, beta=0,1            21=random alpha, beta=0,1',
     $      / ' Large & Small Matrices:', / '  22=(large, small)   ',
     $      '23=(small,large)    24=(small,small)    25=(large,large)',
     $      / '  26=random O(1) matrices.' )
*
 9992 FORMAT( / ' Tests performed:  (S is Schur, T is triangular, ',
     $      'Q and Z are ', a, ',', / 19x,
     $      'l and r are the appropriate left and right', / 19x,
     $      'eigenvectors, resp., a is alpha, b is beta, and', / 19x, a,
     $      ' means ', a, '.)', / ' Without ordering: ',
     $      / '  1 = | A - Q S Z', a,
     $      ' | / ( |A| n ulp )      2 = | B - Q T Z', a,
     $      ' | / ( |B| n ulp )', / '  3 = | I - QQ', a,
     $      ' | / ( n ulp )             4 = | I - ZZ', a,
     $      ' | / ( n ulp )', / '  5 = A is in Schur form S',
     $      / '  6 = difference between (alpha,beta)',
     $      ' and diagonals of (S,T)', / ' With ordering: ',
     $      / '  7 = | (A,B) - Q (S,T) Z', a,
     $      ' | / ( |(A,B)| n ulp )  ', / '  8 = | I - QQ', a,
     $      ' | / ( n ulp )            9 = | I - ZZ', a,
     $      ' | / ( n ulp )', / ' 10 = A is in Schur form S',
     $      / ' 11 = difference between (alpha,beta) and diagonals',
     $      ' of (S,T)', / ' 12 = SDIM is the correct number of ',
     $      'selected eigenvalues', / )
 9991 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 0p, f8.2 )
 9990 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 1p, d10.3 )
*
*     End of DDRGES
*

Here is the call graph for this function:

Here is the caller graph for this function: