cchkunhr_col()

subroutine cchkunhr_col	(	real	thresh,
		logical	tsterr,
		integer	nm,
		integer, dimension( * )	mval,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nout
	)

CCHKUNHR_COL

Purpose:

 CCHKUNHR_COL tests:
   1) CUNGTSQR and CUNHR_COL using CLATSQR, CGEMQRT,
   2) CUNGTSQR_ROW and CUNHR_COL inside CGETSQRHRT
      (which calls CLATSQR, CUNGTSQR_ROW and CUNHR_COL) using CGEMQRT.
 Therefore, CLATSQR (part of CGEQR), CGEMQRT (part of CGEMQR)
 have to be tested before this test.

Parameters

[in]	THRESH	THRESH is REAL The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NM	NM is INTEGER The number of values of M contained in the vector MVAL.
[in]	MVAL	MVAL is INTEGER array, dimension (NM) The values of the matrix row dimension M.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix column dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB contained in the vector NBVAL.
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 106 of file cchkunhr_col.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NN, NNB, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            MVAL( * ), NBVAL( * ), NVAL( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTESTS
      parameter( ntests = 6 )
*     ..
*     .. Local Scalars ..
      CHARACTER(LEN=3)   PATH
      INTEGER            I, IMB1, INB1, INB2, J, T, M, N, MB1, NB1,
     $                   NB2, NFAIL, NERRS, NRUN
*
*     .. Local Arrays ..
      REAL               RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahd, alasum, cerrunhr_col, cunhr_col01,
     $                   cunhr_col02
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER(LEN=32)  SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Initialize constants
*
      path( 1: 1 ) = 'C'
      path( 2: 3 ) = 'HH'
      nrun = 0
      nfail = 0
      nerrs = 0
*
*     Test the error exits
*
      IF( tsterr ) CALL cerrunhr_col( path, nout )
      infot = 0
*
*     Do for each value of M in MVAL.
*
      DO i = 1, nm
         m = mval( i )
*
*        Do for each value of N in NVAL.
*
         DO j = 1, nn
            n = nval( j )
*
*           Only for M >= N
*
            IF ( min( m, n ).GT.0 .AND. m.GE.n ) THEN
*
*              Do for each possible value of MB1
*
               DO imb1 = 1, nnb
                  mb1 = nbval( imb1 )
*
*                 Only for MB1 > N
*
                  IF ( mb1.GT.n ) THEN
*
*                    Do for each possible value of NB1
*
                     DO inb1 = 1, nnb
                        nb1 = nbval( inb1 )
*
*                       Do for each possible value of NB2
*
                        DO inb2 = 1, nnb
                           nb2 = nbval( inb2 )
*
                           IF( nb1.GT.0 .AND. nb2.GT.0 ) THEN
*
*                             Test CUNHR_COL
*
                              CALL cunhr_col01( m, n, mb1, nb1,
     $                                          nb2, result )
*
*                             Print information about the tests that did
*                             not pass the threshold.
*
                              DO t = 1, ntests
                                 IF( result( t ).GE.thresh ) THEN
                                    IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                              CALL alahd( nout, path )
                                    WRITE( nout, fmt = 9999 ) m, n, mb1,
     $                                     nb1, nb2, t, result( t )
                                    nfail = nfail + 1
                                 END IF
                              END DO
                              nrun = nrun + ntests
                           END IF
                        END DO
                     END DO
                  END IF
                END DO
            END IF
         END DO
      END DO
*
*     Do for each value of M in MVAL.
*
      DO i = 1, nm
         m = mval( i )
*
*        Do for each value of N in NVAL.
*
         DO j = 1, nn
            n = nval( j )
*
*           Only for M >= N
*
            IF ( min( m, n ).GT.0 .AND. m.GE.n ) THEN
*
*              Do for each possible value of MB1
*
               DO imb1 = 1, nnb
                  mb1 = nbval( imb1 )
*
*                 Only for MB1 > N
*
                  IF ( mb1.GT.n ) THEN
*
*                    Do for each possible value of NB1
*
                     DO inb1 = 1, nnb
                        nb1 = nbval( inb1 )
*
*                       Do for each possible value of NB2
*
                        DO inb2 = 1, nnb
                           nb2 = nbval( inb2 )
*
                           IF( nb1.GT.0 .AND. nb2.GT.0 ) THEN
*
*                             Test CUNHR_COL
*
                              CALL cunhr_col02( m, n, mb1, nb1,
     $                                          nb2, result )
*
*                             Print information about the tests that did
*                             not pass the threshold.
*
                              DO t = 1, ntests
                                 IF( result( t ).GE.thresh ) THEN
                                    IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                              CALL alahd( nout, path )
                                    WRITE( nout, fmt = 9998 ) m, n, mb1,
     $                                     nb1, nb2, t, result( t )
                                    nfail = nfail + 1
                                 END IF
                              END DO
                              nrun = nrun + ntests
                           END IF
                        END DO
                     END DO
                  END IF
                END DO
            END IF
         END DO
      END DO
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 'CUNGTSQR and CUNHR_COL: M=', i5, ', N=', i5,
     $        ', MB1=', i5, ', NB1=', i5, ', NB2=', i5,
     $        ' test(', i2, ')=', g12.5 )
 9998 FORMAT( 'CUNGTSQR_ROW and CUNHR_COL: M=', i5, ', N=', i5,
     $        ', MB1=', i5, ', NB1=', i5, ', NB2=', i5,
     $        ' test(', i2, ')=', g12.5 )
      RETURN
*
*     End of CCHKUNHR_COL
*

Here is the call graph for this function:

Here is the caller graph for this function: