LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

## ◆ slamswlq()

 subroutine slamswlq ( character SIDE, character TRANS, integer M, integer N, integer K, integer MB, integer NB, real, dimension( lda, * ) A, integer LDA, real, dimension( ldt, * ) T, integer LDT, real, dimension(ldc, * ) C, integer LDC, real, dimension( * ) WORK, integer LWORK, integer INFO )

SLAMSWLQ

Purpose:
```    SLAMSWLQ overwrites the general real M-by-N matrix C with

SIDE = 'L'     SIDE = 'R'
TRANS = 'N':      Q * C          C * Q
TRANS = 'T':      Q**T * C       C * Q**T
where Q is a real orthogonal matrix defined as the product of blocked
elementary reflectors computed by short wide LQ
factorization (SLASWLQ)```
Parameters
 [in] SIDE ``` SIDE is CHARACTER*1 = 'L': apply Q or Q**T from the Left; = 'R': apply Q or Q**T from the Right.``` [in] TRANS ``` TRANS is CHARACTER*1 = 'N': No transpose, apply Q; = 'T': Transpose, apply Q**T.``` [in] M ``` M is INTEGER The number of rows of the matrix C. M >=0.``` [in] N ``` N is INTEGER The number of columns of the matrix C. N >= 0.``` [in] K ``` K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0;``` [in] MB ``` MB is INTEGER The row block size to be used in the blocked LQ. M >= MB >= 1``` [in] NB ``` NB is INTEGER The column block size to be used in the blocked LQ. NB > M.``` [in] A ``` A is REAL array, dimension (LDA,M) if SIDE = 'L', (LDA,N) if SIDE = 'R' The i-th row must contain the vector which defines the blocked elementary reflector H(i), for i = 1,2,...,k, as returned by SLASWLQ in the first k rows of its array argument A.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,K).``` [in] T ``` T is REAL array, dimension ( M * Number of blocks(CEIL(N-K/NB-K)), The blocked upper triangular block reflectors stored in compact form as a sequence of upper triangular blocks. See below for further details.``` [in] LDT ``` LDT is INTEGER The leading dimension of the array T. LDT >= MB.``` [in,out] C ``` C is REAL array, dimension (LDC,N) On entry, the M-by-N matrix C. On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.``` [in] LDC ``` LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).``` [out] WORK ` (workspace) REAL array, dimension (MAX(1,LWORK))` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. If SIDE = 'L', LWORK >= max(1,NB) * MB; if SIDE = 'R', LWORK >= max(1,M) * MB. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```
Further Details:
``` Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations,
representing Q as a product of other orthogonal matrices
Q = Q(1) * Q(2) * . . . * Q(k)
where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
Q(1) zeros out the upper diagonal entries of rows 1:NB of A
Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
. . .

Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
stored under the diagonal of rows 1:MB of A, and by upper triangular
block reflectors, stored in array T(1:LDT,1:N).
For more information see Further Details in GELQT.

Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
The last Q(k) may use fewer rows.
For more information see Further Details in TPLQT.

For more details of the overall algorithm, see the description of
Sequential TSQR in Section 2.2 of [1].

[1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
SIAM J. Sci. Comput, vol. 34, no. 1, 2012```

Definition at line 193 of file slamswlq.f.

195*
196* -- LAPACK computational routine --
197* -- LAPACK is a software package provided by Univ. of Tennessee, --
198* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
199*
200* .. Scalar Arguments ..
201 CHARACTER SIDE, TRANS
202 INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
203* ..
204* .. Array Arguments ..
205 REAL A( LDA, * ), WORK( * ), C(LDC, * ),
206 \$ T( LDT, * )
207* ..
208*
209* =====================================================================
210*
211* ..
212* .. Local Scalars ..
213 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
214 INTEGER I, II, KK, LW, CTR
215* ..
216* .. External Functions ..
217 LOGICAL LSAME
218 EXTERNAL lsame
219* .. External Subroutines ..
220 EXTERNAL stpmlqt, sgemlqt, xerbla
221* ..
222* .. Executable Statements ..
223*
224* Test the input arguments
225*
226 lquery = lwork.LT.0
227 notran = lsame( trans, 'N' )
228 tran = lsame( trans, 'T' )
229 left = lsame( side, 'L' )
230 right = lsame( side, 'R' )
231 IF (left) THEN
232 lw = n * mb
233 ELSE
234 lw = m * mb
235 END IF
236*
237 info = 0
238 IF( .NOT.left .AND. .NOT.right ) THEN
239 info = -1
240 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
241 info = -2
242 ELSE IF( k.LT.0 ) THEN
243 info = -5
244 ELSE IF( m.LT.k ) THEN
245 info = -3
246 ELSE IF( n.LT.0 ) THEN
247 info = -4
248 ELSE IF( k.LT.mb .OR. mb.LT.1) THEN
249 info = -6
250 ELSE IF( lda.LT.max( 1, k ) ) THEN
251 info = -9
252 ELSE IF( ldt.LT.max( 1, mb) ) THEN
253 info = -11
254 ELSE IF( ldc.LT.max( 1, m ) ) THEN
255 info = -13
256 ELSE IF(( lwork.LT.max(1,lw)).AND.(.NOT.lquery)) THEN
257 info = -15
258 END IF
259*
260 IF( info.NE.0 ) THEN
261 CALL xerbla( 'SLAMSWLQ', -info )
262 work(1) = lw
263 RETURN
264 ELSE IF (lquery) THEN
265 work(1) = lw
266 RETURN
267 END IF
268*
269* Quick return if possible
270*
271 IF( min(m,n,k).EQ.0 ) THEN
272 RETURN
273 END IF
274*
275 IF((nb.LE.k).OR.(nb.GE.max(m,n,k))) THEN
276 CALL sgemlqt( side, trans, m, n, k, mb, a, lda,
277 \$ t, ldt, c, ldc, work, info)
278 RETURN
279 END IF
280*
281 IF(left.AND.tran) THEN
282*
283* Multiply Q to the last block of C
284*
285 kk = mod((m-k),(nb-k))
286 ctr = (m-k)/(nb-k)
287*
288 IF (kk.GT.0) THEN
289 ii=m-kk+1
290 CALL stpmlqt('L','T',kk , n, k, 0, mb, a(1,ii), lda,
291 \$ t(1,ctr*k+1), ldt, c(1,1), ldc,
292 \$ c(ii,1), ldc, work, info )
293 ELSE
294 ii=m+1
295 END IF
296*
297 DO i=ii-(nb-k),nb+1,-(nb-k)
298*
299* Multiply Q to the current block of C (1:M,I:I+NB)
300*
301 ctr = ctr - 1
302 CALL stpmlqt('L','T',nb-k , n, k, 0,mb, a(1,i), lda,
303 \$ t(1,ctr*k+1),ldt, c(1,1), ldc,
304 \$ c(i,1), ldc, work, info )
305 END DO
306*
307* Multiply Q to the first block of C (1:M,1:NB)
308*
309 CALL sgemlqt('L','T',nb , n, k, mb, a(1,1), lda, t
310 \$ ,ldt ,c(1,1), ldc, work, info )
311*
312 ELSE IF (left.AND.notran) THEN
313*
314* Multiply Q to the first block of C
315*
316 kk = mod((m-k),(nb-k))
317 ii=m-kk+1
318 ctr = 1
319 CALL sgemlqt('L','N',nb , n, k, mb, a(1,1), lda, t
320 \$ ,ldt ,c(1,1), ldc, work, info )
321*
322 DO i=nb+1,ii-nb+k,(nb-k)
323*
324* Multiply Q to the current block of C (I:I+NB,1:N)
325*
326 CALL stpmlqt('L','N',nb-k , n, k, 0,mb, a(1,i), lda,
327 \$ t(1,ctr * k+1), ldt, c(1,1), ldc,
328 \$ c(i,1), ldc, work, info )
329 ctr = ctr + 1
330*
331 END DO
332 IF(ii.LE.m) THEN
333*
334* Multiply Q to the last block of C
335*
336 CALL stpmlqt('L','N',kk , n, k, 0, mb, a(1,ii), lda,
337 \$ t(1,ctr*k+1), ldt, c(1,1), ldc,
338 \$ c(ii,1), ldc, work, info )
339*
340 END IF
341*
342 ELSE IF(right.AND.notran) THEN
343*
344* Multiply Q to the last block of C
345*
346 kk = mod((n-k),(nb-k))
347 ctr = (n-k)/(nb-k)
348 IF (kk.GT.0) THEN
349 ii=n-kk+1
350 CALL stpmlqt('R','N',m , kk, k, 0, mb, a(1, ii), lda,
351 \$ t(1,ctr*k+1), ldt, c(1,1), ldc,
352 \$ c(1,ii), ldc, work, info )
353 ELSE
354 ii=n+1
355 END IF
356*
357 DO i=ii-(nb-k),nb+1,-(nb-k)
358*
359* Multiply Q to the current block of C (1:M,I:I+MB)
360*
361 ctr = ctr - 1
362 CALL stpmlqt('R','N', m, nb-k, k, 0, mb, a(1, i), lda,
363 \$ t(1,ctr*k+1), ldt, c(1,1), ldc,
364 \$ c(1,i), ldc, work, info )
365
366 END DO
367*
368* Multiply Q to the first block of C (1:M,1:MB)
369*
370 CALL sgemlqt('R','N',m , nb, k, mb, a(1,1), lda, t
371 \$ ,ldt ,c(1,1), ldc, work, info )
372*
373 ELSE IF (right.AND.tran) THEN
374*
375* Multiply Q to the first block of C
376*
377 kk = mod((n-k),(nb-k))
378 ii=n-kk+1
379 ctr = 1
380 CALL sgemlqt('R','T',m , nb, k, mb, a(1,1), lda, t
381 \$ ,ldt ,c(1,1), ldc, work, info )
382*
383 DO i=nb+1,ii-nb+k,(nb-k)
384*
385* Multiply Q to the current block of C (1:M,I:I+MB)
386*
387 CALL stpmlqt('R','T',m , nb-k, k, 0,mb, a(1,i), lda,
388 \$ t(1, ctr*k+1), ldt, c(1,1), ldc,
389 \$ c(1,i), ldc, work, info )
390 ctr = ctr + 1
391*
392 END DO
393 IF(ii.LE.n) THEN
394*
395* Multiply Q to the last block of C
396*
397 CALL stpmlqt('R','T',m , kk, k, 0,mb, a(1,ii), lda,
398 \$ t(1,ctr*k+1),ldt, c(1,1), ldc,
399 \$ c(1,ii), ldc, work, info )
400*
401 END IF
402*
403 END IF
404*
405 work(1) = lw
406 RETURN
407*
408* End of SLAMSWLQ
409*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine sgemlqt(SIDE, TRANS, M, N, K, MB, V, LDV, T, LDT, C, LDC, WORK, INFO)
SGEMLQT
Definition: sgemlqt.f:153
subroutine stpmlqt(SIDE, TRANS, M, N, K, L, MB, V, LDV, T, LDT, A, LDA, B, LDB, WORK, INFO)
STPMLQT
Definition: stpmlqt.f:214
Here is the call graph for this function:
Here is the caller graph for this function: