dpbtrs()

subroutine dpbtrs	(	character	uplo,
		integer	n,
		integer	kd,
		integer	nrhs,
		double precision, dimension( ldab, * )	ab,
		integer	ldab,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

DPBTRS

Download DPBTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPBTRS solves a system of linear equations A*X = B with a symmetric
!> positive definite band matrix A using the Cholesky factorization
!> A = U**T*U or A = L*L**T computed by DPBTRF.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangular factor stored in AB; !> = 'L': Lower triangular factor stored in AB. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of superdiagonals of the matrix A if UPLO = 'U', !> or the number of subdiagonals if UPLO = 'L'. KD >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	AB	!> AB is DOUBLE PRECISION array, dimension (LDAB,N) !> The triangular factor U or L from the Cholesky factorization !> A = U**T*U or A = L*L**T of the band matrix A, stored in the !> first KD+1 rows of the array. The j-th column of U or L is !> stored in the j-th column of the array AB as follows: !> if UPLO ='U', AB(kd+1+i-j,j) = U(i,j) for max(1,j-kd)<=i<=j; !> if UPLO ='L', AB(1+i-j,j) = L(i,j) for j<=i<=min(n,j+kd). !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KD+1. !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> On entry, the right hand side matrix B. !> On exit, the solution matrix X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 118 of file dpbtrs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, KD, LDAB, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AB( LDAB, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dtbsv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kd.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPBTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B where A = U**T *U.
*
         DO 10 j = 1, nrhs
*
*           Solve U**T *X = B, overwriting B with X.
*
            CALL dtbsv( 'Upper', 'Transpose', 'Non-unit', n, kd, ab,
     $                  ldab, b( 1, j ), 1 )
*
*           Solve U*X = B, overwriting B with X.
*
            CALL dtbsv( 'Upper', 'No transpose', 'Non-unit', n, kd,
     $                  ab,
     $                  ldab, b( 1, j ), 1 )
   10    CONTINUE
      ELSE
*
*        Solve A*X = B where A = L*L**T.
*
         DO 20 j = 1, nrhs
*
*           Solve L*X = B, overwriting B with X.
*
            CALL dtbsv( 'Lower', 'No transpose', 'Non-unit', n, kd,
     $                  ab,
     $                  ldab, b( 1, j ), 1 )
*
*           Solve L**T *X = B, overwriting B with X.
*
            CALL dtbsv( 'Lower', 'Transpose', 'Non-unit', n, kd, ab,
     $                  ldab, b( 1, j ), 1 )
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of DPBTRS
*

Here is the call graph for this function:

Here is the caller graph for this function: