cdrvrf1()

subroutine cdrvrf1	(	integer	nout,
		integer	nn,
		integer, dimension( nn )	nval,
		real	thresh,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	arf,
		real, dimension( * )	work
	)

CDRVRF1

Purpose:

 CDRVRF1 tests the LAPACK RFP routines:
     CLANHF.F

Parameters

[in]	NOUT	NOUT is INTEGER The unit number for output.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix dimension N.
[in]	THRESH	THRESH is REAL The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[out]	A	A is COMPLEX array, dimension (LDA,NMAX)
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,NMAX).
[out]	ARF	ARF is COMPLEX array, dimension ((NMAX*(NMAX+1))/2).
[out]	WORK	WORK is COMPLEX array, dimension ( NMAX )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 94 of file cdrvrf1.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, NN, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            NVAL( NN )
      REAL               WORK( * )
      COMPLEX            A( LDA, * ), ARF( * )
*     ..
*
*  =====================================================================
*     ..
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
      INTEGER            NTESTS
      parameter( ntests = 1 )
*     ..
*     .. Local Scalars ..
      CHARACTER          UPLO, CFORM, NORM
      INTEGER            I, IFORM, IIN, IIT, INFO, INORM, IUPLO, J, N,
     +                   NERRS, NFAIL, NRUN
      REAL               EPS, LARGE, NORMA, NORMARF, SMALL
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 ), FORMS( 2 ), NORMS( 4 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Functions ..
      COMPLEX            CLARND
      REAL               SLAMCH, CLANHE, CLANHF
      EXTERNAL           slamch, clarnd, clanhe, clanhf
*     ..
*     .. External Subroutines ..
      EXTERNAL           ctrttf
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
      DATA               forms / 'N', 'C' /
      DATA               norms / 'M', '1', 'I', 'F' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      nrun = 0
      nfail = 0
      nerrs = 0
      info = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
      eps = slamch( 'Precision' )
      small = slamch( 'Safe minimum' )
      large = one / small
      small = small * lda * lda
      large = large / lda / lda
*
      DO 130 iin = 1, nn
*
         n = nval( iin )
*
         DO 120 iit = 1, 3
*           Nothing to do for N=0
            IF ( n .EQ. 0 ) EXIT
*
*           IIT = 1 : random matrix
*           IIT = 2 : random matrix scaled near underflow
*           IIT = 3 : random matrix scaled near overflow
*
            DO j = 1, n
               DO i = 1, n
                  a( i, j) = clarnd( 4, iseed )
               END DO
            END DO
*
            IF ( iit.EQ.2 ) THEN
               DO j = 1, n
                  DO i = 1, n
                     a( i, j) = a( i, j ) * large
                  END DO
               END DO
            END IF
*
            IF ( iit.EQ.3 ) THEN
               DO j = 1, n
                  DO i = 1, n
                     a( i, j) = a( i, j) * small
                  END DO
               END DO
            END IF
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 110 iuplo = 1, 2
*
               uplo = uplos( iuplo )
*
*              Do first for CFORM = 'N', then for CFORM = 'C'
*
               DO 100 iform = 1, 2
*
                  cform = forms( iform )
*
                  srnamt = 'CTRTTF'
                  CALL ctrttf( cform, uplo, n, a, lda, arf, info )
*
*                 Check error code from CTRTTF
*
                  IF( info.NE.0 ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 ) THEN
                        WRITE( nout, * )
                        WRITE( nout, fmt = 9999 )
                     END IF
                     WRITE( nout, fmt = 9998 ) srnamt, uplo, cform, n
                     nerrs = nerrs + 1
                     GO TO 100
                  END IF
*
                  DO 90 inorm = 1, 4
*
*                    Check all four norms: 'M', '1', 'I', 'F'
*
                     norm = norms( inorm )
                     normarf = clanhf( norm, cform, uplo, n, arf, work )
                     norma = clanhe( norm, uplo, n, a, lda, work )
*
                     result(1) = ( norma - normarf ) / norma / eps
                     nrun = nrun + 1
*
                     IF( result(1).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 ) THEN
                           WRITE( nout, * )
                           WRITE( nout, fmt = 9999 )
                        END IF
                        WRITE( nout, fmt = 9997 ) 'CLANHF',
     +                      n, iit, uplo, cform, norm, result(1)
                        nfail = nfail + 1
                     END IF
   90             CONTINUE
  100          CONTINUE
  110       CONTINUE
  120    CONTINUE
  130 CONTINUE
*
*     Print a summary of the results.
*
      IF ( nfail.EQ.0 ) THEN
         WRITE( nout, fmt = 9996 )'CLANHF', nrun
      ELSE
         WRITE( nout, fmt = 9995 ) 'CLANHF', nfail, nrun
      END IF
      IF ( nerrs.NE.0 ) THEN
         WRITE( nout, fmt = 9994 ) nerrs, 'CLANHF'
      END IF
*
 9999 FORMAT( 1x, ' *** Error(s) or Failure(s) while testing CLANHF
     +         ***')
 9998 FORMAT( 1x, '     Error in ',a6,' with UPLO=''',a1,''', FORM=''',
     +        a1,''', N=',i5)
 9997 FORMAT( 1x, '     Failure in ',a6,' N=',i5,' TYPE=',i5,' UPLO=''',
     +        a1, ''', FORM =''',a1,''', NORM=''',a1,''', test=',g12.5)
 9996 FORMAT( 1x, 'All tests for ',a6,' auxiliary routine passed the ',
     +        'threshold ( ',i5,' tests run)')
 9995 FORMAT( 1x, a6, ' auxiliary routine: ',i5,' out of ',i5,
     +        ' tests failed to pass the threshold')
 9994 FORMAT( 26x, i5,' error message recorded (',a6,')')
*
      RETURN
*
*     End of CDRVRF1
*

Here is the call graph for this function:

Here is the caller graph for this function: