zlahef()

subroutine zlahef	(	character	uplo,
		integer	n,
		integer	nb,
		integer	kb,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( * )	ipiv,
		complex*16, dimension( ldw, * )	w,
		integer	ldw,
		integer	info )

ZLAHEF computes a partial factorization of a complex Hermitian indefinite matrix using the Bunch-Kaufman diagonal pivoting method (blocked algorithm, calling Level 3 BLAS).

Download ZLAHEF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLAHEF computes a partial factorization of a complex Hermitian
!> matrix A using the Bunch-Kaufman diagonal pivoting method. The
!> partial factorization has the form:
!>
!> A  =  ( I  U12 ) ( A11  0  ) (  I      0     )  if UPLO = 'U', or:
!>       ( 0  U22 ) (  0   D  ) ( U12**H U22**H )
!>
!> A  =  ( L11  0 ) (  D   0  ) ( L11**H L21**H )  if UPLO = 'L'
!>       ( L21  I ) (  0  A22 ) (  0      I     )
!>
!> where the order of D is at most NB. The actual order is returned in
!> the argument KB, and is either NB or NB-1, or N if N <= NB.
!> Note that U**H denotes the conjugate transpose of U.
!>
!> ZLAHEF is an auxiliary routine called by ZHETRF. It uses blocked code
!> (calling Level 3 BLAS) to update the submatrix A11 (if UPLO = 'U') or
!> A22 (if UPLO = 'L').
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	NB	!> NB is INTEGER !> The maximum number of columns of the matrix A that should be !> factored. NB should be at least 2 to allow for 2-by-2 pivot !> blocks. !>
[out]	KB	!> KB is INTEGER !> The number of columns of A that were actually factored. !> KB is either NB-1 or NB, or N if N <= NB. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> n-by-n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n-by-n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> On exit, A contains details of the partial factorization. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	IPIV	!> IPIV is INTEGER array, dimension (N) !> Details of the interchanges and the block structure of D. !> !> If UPLO = 'U': !> Only the last KB elements of IPIV are set. !> !> If IPIV(k) > 0, then rows and columns k and IPIV(k) were !> interchanged and D(k,k) is a 1-by-1 diagonal block. !> !> If IPIV(k) = IPIV(k-1) < 0, then rows and columns !> k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k) !> is a 2-by-2 diagonal block. !> !> If UPLO = 'L': !> Only the first KB elements of IPIV are set. !> !> If IPIV(k) > 0, then rows and columns k and IPIV(k) were !> interchanged and D(k,k) is a 1-by-1 diagonal block. !> !> If IPIV(k) = IPIV(k+1) < 0, then rows and columns !> k+1 and -IPIV(k) were interchanged and D(k:k+1,k:k+1) !> is a 2-by-2 diagonal block. !>
[out]	W	!> W is COMPLEX*16 array, dimension (LDW,NB) !>
[in]	LDW	!> LDW is INTEGER !> The leading dimension of the array W. LDW >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> > 0: if INFO = k, D(k,k) is exactly zero. The factorization !> has been completed, but the block diagonal matrix D is !> exactly singular. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

!>
!>  December 2016,  Igor Kozachenko,
!>                  Computer Science Division,
!>                  University of California, Berkeley
!> 

Definition at line 174 of file zlahef.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, KB, LDA, LDW, N, NB
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX*16         A( LDA, * ), W( LDW, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
      DOUBLE PRECISION   EIGHT, SEVTEN
      parameter( eight = 8.0d+0, sevten = 17.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            IMAX, J, JJ, JMAX, JP, K, KK, KKW, KP,
     $                   KSTEP, KW
      DOUBLE PRECISION   ABSAKK, ALPHA, COLMAX, R1, ROWMAX, T
      COMPLEX*16         D11, D21, D22, Z
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IZAMAX
      EXTERNAL           lsame, izamax
*     ..
*     .. External Subroutines ..
      EXTERNAL           zcopy, zdscal, zgemmtr, zgemv, zlacgv,
     $                   zswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, dimag, max, min, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( z ) = abs( dble( z ) ) + abs( dimag( z ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
*
*     Initialize ALPHA for use in choosing pivot block size.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Factorize the trailing columns of A using the upper triangle
*        of A and working backwards, and compute the matrix W = U12*D
*        for use in updating A11 (note that conjg(W) is actually stored)
*
*        K is the main loop index, decreasing from N in steps of 1 or 2
*
*        KW is the column of W which corresponds to column K of A
*
         k = n
   10    CONTINUE
         kw = nb + k - n
*
*        Exit from loop
*
         IF( ( k.LE.n-nb+1 .AND. nb.LT.n ) .OR. k.LT.1 )
     $      GO TO 30
*
         kstep = 1
*
*        Copy column K of A to column KW of W and update it
*
         CALL zcopy( k-1, a( 1, k ), 1, w( 1, kw ), 1 )
         w( k, kw ) = dble( a( k, k ) )
         IF( k.LT.n ) THEN
            CALL zgemv( 'No transpose', k, n-k, -cone, a( 1, k+1 ),
     $                  lda,
     $                  w( k, kw+1 ), ldw, cone, w( 1, kw ), 1 )
            w( k, kw ) = dble( w( k, kw ) )
         END IF
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( dble( w( k, kw ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.GT.1 ) THEN
            imax = izamax( k-1, w( 1, kw ), 1 )
            colmax = cabs1( w( imax, kw ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            a( k, k ) = dble( a( k, k ) )
         ELSE
*
*           ============================================================
*
*           BEGIN pivot search
*
*           Case(1)
            IF( absakk.GE.alpha*colmax ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
            ELSE
*
*              BEGIN pivot search along IMAX row
*
*
*              Copy column IMAX to column KW-1 of W and update it
*
               CALL zcopy( imax-1, a( 1, imax ), 1, w( 1, kw-1 ), 1 )
               w( imax, kw-1 ) = dble( a( imax, imax ) )
               CALL zcopy( k-imax, a( imax, imax+1 ), lda,
     $                     w( imax+1, kw-1 ), 1 )
               CALL zlacgv( k-imax, w( imax+1, kw-1 ), 1 )
               IF( k.LT.n ) THEN
                  CALL zgemv( 'No transpose', k, n-k, -cone,
     $                        a( 1, k+1 ), lda, w( imax, kw+1 ), ldw,
     $                        cone, w( 1, kw-1 ), 1 )
                  w( imax, kw-1 ) = dble( w( imax, kw-1 ) )
               END IF
*
*              JMAX is the column-index of the largest off-diagonal
*              element in row IMAX, and ROWMAX is its absolute value.
*              Determine only ROWMAX.
*
               jmax = imax + izamax( k-imax, w( imax+1, kw-1 ), 1 )
               rowmax = cabs1( w( jmax, kw-1 ) )
               IF( imax.GT.1 ) THEN
                  jmax = izamax( imax-1, w( 1, kw-1 ), 1 )
                  rowmax = max( rowmax, cabs1( w( jmax, kw-1 ) ) )
               END IF
*
*              Case(2)
               IF( absakk.GE.alpha*colmax*( colmax / rowmax ) ) THEN
*
*                 no interchange, use 1-by-1 pivot block
*
                  kp = k
*
*              Case(3)
               ELSE IF( abs( dble( w( imax, kw-1 ) ) ).GE.alpha*rowmax )
     $                   THEN
*
*                 interchange rows and columns K and IMAX, use 1-by-1
*                 pivot block
*
                  kp = imax
*
*                 copy column KW-1 of W to column KW of W
*
                  CALL zcopy( k, w( 1, kw-1 ), 1, w( 1, kw ), 1 )
*
*              Case(4)
               ELSE
*
*                 interchange rows and columns K-1 and IMAX, use 2-by-2
*                 pivot block
*
                  kp = imax
                  kstep = 2
               END IF
*
*
*              END pivot search along IMAX row
*
            END IF
*
*           END pivot search
*
*           ============================================================
*
*           KK is the column of A where pivoting step stopped
*
            kk = k - kstep + 1
*
*           KKW is the column of W which corresponds to column KK of A
*
            kkw = nb + kk - n
*
*           Interchange rows and columns KP and KK.
*           Updated column KP is already stored in column KKW of W.
*
            IF( kp.NE.kk ) THEN
*
*              Copy non-updated column KK to column KP of submatrix A
*              at step K. No need to copy element into column K
*              (or K and K-1 for 2-by-2 pivot) of A, since these columns
*              will be later overwritten.
*
               a( kp, kp ) = dble( a( kk, kk ) )
               CALL zcopy( kk-1-kp, a( kp+1, kk ), 1, a( kp, kp+1 ),
     $                     lda )
               CALL zlacgv( kk-1-kp, a( kp, kp+1 ), lda )
               IF( kp.GT.1 )
     $            CALL zcopy( kp-1, a( 1, kk ), 1, a( 1, kp ), 1 )
*
*              Interchange rows KK and KP in last K+1 to N columns of A
*              (columns K (or K and K-1 for 2-by-2 pivot) of A will be
*              later overwritten). Interchange rows KK and KP
*              in last KKW to NB columns of W.
*
               IF( k.LT.n )
     $            CALL zswap( n-k, a( kk, k+1 ), lda, a( kp, k+1 ),
     $                        lda )
               CALL zswap( n-kk+1, w( kk, kkw ), ldw, w( kp, kkw ),
     $                     ldw )
            END IF
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column kw of W now holds
*
*              W(kw) = U(k)*D(k),
*
*              where U(k) is the k-th column of U
*
*              (1) Store subdiag. elements of column U(k)
*              and 1-by-1 block D(k) in column k of A.
*              (NOTE: Diagonal element U(k,k) is a UNIT element
*              and not stored)
*                 A(k,k) := D(k,k) = W(k,kw)
*                 A(1:k-1,k) := U(1:k-1,k) = W(1:k-1,kw)/D(k,k)
*
*              (NOTE: No need to use for Hermitian matrix
*              A( K, K ) = DBLE( W( K, K) ) to separately copy diagonal
*              element D(k,k) from W (potentially saves only one load))
               CALL zcopy( k, w( 1, kw ), 1, a( 1, k ), 1 )
               IF( k.GT.1 ) THEN
*
*                 (NOTE: No need to check if A(k,k) is NOT ZERO,
*                  since that was ensured earlier in pivot search:
*                  case A(k,k) = 0 falls into 2x2 pivot case(4))
*
                  r1 = one / dble( a( k, k ) )
                  CALL zdscal( k-1, r1, a( 1, k ), 1 )
*
*                 (2) Conjugate column W(kw)
*
                  CALL zlacgv( k-1, w( 1, kw ), 1 )
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns kw and kw-1 of W now hold
*
*              ( W(kw-1) W(kw) ) = ( U(k-1) U(k) )*D(k)
*
*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
*              of U
*
*              (1) Store U(1:k-2,k-1) and U(1:k-2,k) and 2-by-2
*              block D(k-1:k,k-1:k) in columns k-1 and k of A.
*              (NOTE: 2-by-2 diagonal block U(k-1:k,k-1:k) is a UNIT
*              block and not stored)
*                 A(k-1:k,k-1:k) := D(k-1:k,k-1:k) = W(k-1:k,kw-1:kw)
*                 A(1:k-2,k-1:k) := U(1:k-2,k:k-1:k) =
*                 = W(1:k-2,kw-1:kw) * ( D(k-1:k,k-1:k)**(-1) )
*
               IF( k.GT.2 ) THEN
*
*                 Factor out the columns of the inverse of 2-by-2 pivot
*                 block D, so that each column contains 1, to reduce the
*                 number of FLOPS when we multiply panel
*                 ( W(kw-1) W(kw) ) by this inverse, i.e. by D**(-1).
*
*                 D**(-1) = ( d11 cj(d21) )**(-1) =
*                           ( d21    d22 )
*
*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
*                                          ( (-d21) (     d11 ) )
*
*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
*
*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
*                     (     (      -1 )           ( d11/conj(d21) ) )
*
*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
*
*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
*                     (     (  -1 )           ( D22 ) )
*
*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
*                                      (     (  -1 )           ( D22 ) )
*
*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
*                   (               (  -1 )         ( D22 ) )
*
*                 = ( conj(D21)*( D11 ) D21*(  -1 ) )
*                   (           (  -1 )     ( D22 ) ),
*
*                 where D11 = d22/d21,
*                       D22 = d11/conj(d21),
*                       D21 = T/d21,
*                       T = 1/(D22*D11-1).
*
*                 (NOTE: No need to check for division by ZERO,
*                  since that was ensured earlier in pivot search:
*                  (a) d21 != 0, since in 2x2 pivot case(4)
*                      |d21| should be larger than |d11| and |d22|;
*                  (b) (D22*D11 - 1) != 0, since from (a),
*                      both |D11| < 1, |D22| < 1, hence |D22*D11| << 1.)
*
                  d21 = w( k-1, kw )
                  d11 = w( k, kw ) / dconjg( d21 )
                  d22 = w( k-1, kw-1 ) / d21
                  t = one / ( dble( d11*d22 )-one )
                  d21 = t / d21
*
*                 Update elements in columns A(k-1) and A(k) as
*                 dot products of rows of ( W(kw-1) W(kw) ) and columns
*                 of D**(-1)
*
                  DO 20 j = 1, k - 2
                     a( j, k-1 ) = d21*( d11*w( j, kw-1 )-w( j, kw ) )
                     a( j, k ) = dconjg( d21 )*
     $                           ( d22*w( j, kw )-w( j, kw-1 ) )
   20             CONTINUE
               END IF
*
*              Copy D(k) to A
*
               a( k-1, k-1 ) = w( k-1, kw-1 )
               a( k-1, k ) = w( k-1, kw )
               a( k, k ) = w( k, kw )
*
*              (2) Conjugate columns W(kw) and W(kw-1)
*
               CALL zlacgv( k-1, w( 1, kw ), 1 )
               CALL zlacgv( k-2, w( 1, kw-1 ), 1 )
*
            END IF
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -kp
            ipiv( k-1 ) = -kp
         END IF
*
*        Decrease K and return to the start of the main loop
*
         k = k - kstep
         GO TO 10
*
   30    CONTINUE
*
*        Update the upper triangle of A11 (= A(1:k,1:k)) as
*
*        A11 := A11 - U12*D*U12**H = A11 - U12*W**H
*
*        (note that conjg(W) is actually stored)
*
         CALL zgemmtr( 'Upper', 'No transpose', 'Transpose', k, n-k,
     $                 -cone, a( 1, k+1 ), lda, w( 1, kw+1 ), ldw,
     $                 cone, a( 1, 1 ), lda )
*
*        Put U12 in standard form by partially undoing the interchanges
*        in columns k+1:n looping backwards from k+1 to n
*
         j = k + 1
   60    CONTINUE
*
*           Undo the interchanges (if any) of rows JJ and JP at each
*           step J
*
*           (Here, J is a diagonal index)
            jj = j
            jp = ipiv( j )
            IF( jp.LT.0 ) THEN
               jp = -jp
*              (Here, J is a diagonal index)
               j = j + 1
            END IF
*           (NOTE: Here, J is used to determine row length. Length N-J+1
*           of the rows to swap back doesn't include diagonal element)
            j = j + 1
            IF( jp.NE.jj .AND. j.LE.n )
     $         CALL zswap( n-j+1, a( jp, j ), lda, a( jj, j ), lda )
         IF( j.LT.n )
     $      GO TO 60
*
*        Set KB to the number of columns factorized
*
         kb = n - k
*
      ELSE
*
*        Factorize the leading columns of A using the lower triangle
*        of A and working forwards, and compute the matrix W = L21*D
*        for use in updating A22 (note that conjg(W) is actually stored)
*
*        K is the main loop index, increasing from 1 in steps of 1 or 2
*
         k = 1
   70    CONTINUE
*
*        Exit from loop
*
         IF( ( k.GE.nb .AND. nb.LT.n ) .OR. k.GT.n )
     $      GO TO 90
*
         kstep = 1
*
*        Copy column K of A to column K of W and update it
*
         w( k, k ) = dble( a( k, k ) )
         IF( k.LT.n )
     $      CALL zcopy( n-k, a( k+1, k ), 1, w( k+1, k ), 1 )
         CALL zgemv( 'No transpose', n-k+1, k-1, -cone, a( k, 1 ),
     $               lda,
     $               w( k, 1 ), ldw, cone, w( k, k ), 1 )
         w( k, k ) = dble( w( k, k ) )
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( dble( w( k, k ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.LT.n ) THEN
            imax = k + izamax( n-k, w( k+1, k ), 1 )
            colmax = cabs1( w( imax, k ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            a( k, k ) = dble( a( k, k ) )
         ELSE
*
*           ============================================================
*
*           BEGIN pivot search
*
*           Case(1)
            IF( absakk.GE.alpha*colmax ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
            ELSE
*
*              BEGIN pivot search along IMAX row
*
*
*              Copy column IMAX to column K+1 of W and update it
*
               CALL zcopy( imax-k, a( imax, k ), lda, w( k, k+1 ),
     $                     1 )
               CALL zlacgv( imax-k, w( k, k+1 ), 1 )
               w( imax, k+1 ) = dble( a( imax, imax ) )
               IF( imax.LT.n )
     $            CALL zcopy( n-imax, a( imax+1, imax ), 1,
     $                        w( imax+1, k+1 ), 1 )
               CALL zgemv( 'No transpose', n-k+1, k-1, -cone, a( k,
     $                     1 ),
     $                     lda, w( imax, 1 ), ldw, cone, w( k, k+1 ),
     $                     1 )
               w( imax, k+1 ) = dble( w( imax, k+1 ) )
*
*              JMAX is the column-index of the largest off-diagonal
*              element in row IMAX, and ROWMAX is its absolute value.
*              Determine only ROWMAX.
*
               jmax = k - 1 + izamax( imax-k, w( k, k+1 ), 1 )
               rowmax = cabs1( w( jmax, k+1 ) )
               IF( imax.LT.n ) THEN
                  jmax = imax + izamax( n-imax, w( imax+1, k+1 ), 1 )
                  rowmax = max( rowmax, cabs1( w( jmax, k+1 ) ) )
               END IF
*
*              Case(2)
               IF( absakk.GE.alpha*colmax*( colmax / rowmax ) ) THEN
*
*                 no interchange, use 1-by-1 pivot block
*
                  kp = k
*
*              Case(3)
               ELSE IF( abs( dble( w( imax, k+1 ) ) ).GE.alpha*rowmax )
     $                   THEN
*
*                 interchange rows and columns K and IMAX, use 1-by-1
*                 pivot block
*
                  kp = imax
*
*                 copy column K+1 of W to column K of W
*
                  CALL zcopy( n-k+1, w( k, k+1 ), 1, w( k, k ), 1 )
*
*              Case(4)
               ELSE
*
*                 interchange rows and columns K+1 and IMAX, use 2-by-2
*                 pivot block
*
                  kp = imax
                  kstep = 2
               END IF
*
*
*              END pivot search along IMAX row
*
            END IF
*
*           END pivot search
*
*           ============================================================
*
*           KK is the column of A where pivoting step stopped
*
            kk = k + kstep - 1
*
*           Interchange rows and columns KP and KK.
*           Updated column KP is already stored in column KK of W.
*
            IF( kp.NE.kk ) THEN
*
*              Copy non-updated column KK to column KP of submatrix A
*              at step K. No need to copy element into column K
*              (or K and K+1 for 2-by-2 pivot) of A, since these columns
*              will be later overwritten.
*
               a( kp, kp ) = dble( a( kk, kk ) )
               CALL zcopy( kp-kk-1, a( kk+1, kk ), 1, a( kp, kk+1 ),
     $                     lda )
               CALL zlacgv( kp-kk-1, a( kp, kk+1 ), lda )
               IF( kp.LT.n )
     $            CALL zcopy( n-kp, a( kp+1, kk ), 1, a( kp+1, kp ),
     $                        1 )
*
*              Interchange rows KK and KP in first K-1 columns of A
*              (columns K (or K and K+1 for 2-by-2 pivot) of A will be
*              later overwritten). Interchange rows KK and KP
*              in first KK columns of W.
*
               IF( k.GT.1 )
     $            CALL zswap( k-1, a( kk, 1 ), lda, a( kp, 1 ), lda )
               CALL zswap( kk, w( kk, 1 ), ldw, w( kp, 1 ), ldw )
            END IF
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k of W now holds
*
*              W(k) = L(k)*D(k),
*
*              where L(k) is the k-th column of L
*
*              (1) Store subdiag. elements of column L(k)
*              and 1-by-1 block D(k) in column k of A.
*              (NOTE: Diagonal element L(k,k) is a UNIT element
*              and not stored)
*                 A(k,k) := D(k,k) = W(k,k)
*                 A(k+1:N,k) := L(k+1:N,k) = W(k+1:N,k)/D(k,k)
*
*              (NOTE: No need to use for Hermitian matrix
*              A( K, K ) = DBLE( W( K, K) ) to separately copy diagonal
*              element D(k,k) from W (potentially saves only one load))
               CALL zcopy( n-k+1, w( k, k ), 1, a( k, k ), 1 )
               IF( k.LT.n ) THEN
*
*                 (NOTE: No need to check if A(k,k) is NOT ZERO,
*                  since that was ensured earlier in pivot search:
*                  case A(k,k) = 0 falls into 2x2 pivot case(4))
*
                  r1 = one / dble( a( k, k ) )
                  CALL zdscal( n-k, r1, a( k+1, k ), 1 )
*
*                 (2) Conjugate column W(k)
*
                  CALL zlacgv( n-k, w( k+1, k ), 1 )
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns k and k+1 of W now hold
*
*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
*
*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
*              of L
*
*              (1) Store L(k+2:N,k) and L(k+2:N,k+1) and 2-by-2
*              block D(k:k+1,k:k+1) in columns k and k+1 of A.
*              (NOTE: 2-by-2 diagonal block L(k:k+1,k:k+1) is a UNIT
*              block and not stored)
*                 A(k:k+1,k:k+1) := D(k:k+1,k:k+1) = W(k:k+1,k:k+1)
*                 A(k+2:N,k:k+1) := L(k+2:N,k:k+1) =
*                 = W(k+2:N,k:k+1) * ( D(k:k+1,k:k+1)**(-1) )
*
               IF( k.LT.n-1 ) THEN
*
*                 Factor out the columns of the inverse of 2-by-2 pivot
*                 block D, so that each column contains 1, to reduce the
*                 number of FLOPS when we multiply panel
*                 ( W(kw-1) W(kw) ) by this inverse, i.e. by D**(-1).
*
*                 D**(-1) = ( d11 cj(d21) )**(-1) =
*                           ( d21    d22 )
*
*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
*                                          ( (-d21) (     d11 ) )
*
*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
*
*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
*                     (     (      -1 )           ( d11/conj(d21) ) )
*
*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
*
*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
*                     (     (  -1 )           ( D22 ) )
*
*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
*                                      (     (  -1 )           ( D22 ) )
*
*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
*                   (               (  -1 )         ( D22 ) )
*
*                 = ( conj(D21)*( D11 ) D21*(  -1 ) )
*                   (           (  -1 )     ( D22 ) ),
*
*                 where D11 = d22/d21,
*                       D22 = d11/conj(d21),
*                       D21 = T/d21,
*                       T = 1/(D22*D11-1).
*
*                 (NOTE: No need to check for division by ZERO,
*                  since that was ensured earlier in pivot search:
*                  (a) d21 != 0, since in 2x2 pivot case(4)
*                      |d21| should be larger than |d11| and |d22|;
*                  (b) (D22*D11 - 1) != 0, since from (a),
*                      both |D11| < 1, |D22| < 1, hence |D22*D11| << 1.)
*
                  d21 = w( k+1, k )
                  d11 = w( k+1, k+1 ) / d21
                  d22 = w( k, k ) / dconjg( d21 )
                  t = one / ( dble( d11*d22 )-one )
                  d21 = t / d21
*
*                 Update elements in columns A(k) and A(k+1) as
*                 dot products of rows of ( W(k) W(k+1) ) and columns
*                 of D**(-1)
*
                  DO 80 j = k + 2, n
                     a( j, k ) = dconjg( d21 )*
     $                           ( d11*w( j, k )-w( j, k+1 ) )
                     a( j, k+1 ) = d21*( d22*w( j, k+1 )-w( j, k ) )
   80             CONTINUE
               END IF
*
*              Copy D(k) to A
*
               a( k, k ) = w( k, k )
               a( k+1, k ) = w( k+1, k )
               a( k+1, k+1 ) = w( k+1, k+1 )
*
*              (2) Conjugate columns W(k) and W(k+1)
*
               CALL zlacgv( n-k, w( k+1, k ), 1 )
               CALL zlacgv( n-k-1, w( k+2, k+1 ), 1 )
*
            END IF
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -kp
            ipiv( k+1 ) = -kp
         END IF
*
*        Increase K and return to the start of the main loop
*
         k = k + kstep
         GO TO 70
*
   90    CONTINUE
*
*        Update the lower triangle of A22 (= A(k:n,k:n)) as
*
*        A22 := A22 - L21*D*L21**H = A22 - L21*W**H
*
*        (note that conjg(W) is actually stored)
*
         CALL zgemmtr( 'Lower', 'No transpose', 'Transpose', n-k+1,
     $                 k-1, -cone, a( k, 1 ), lda, w( k, 1 ), ldw,
     $                 cone, a( k, k ), lda )
*
*        Put L21 in standard form by partially undoing the interchanges
*        of rows in columns 1:k-1 looping backwards from k-1 to 1
*
         j = k - 1
  120    CONTINUE
*
*           Undo the interchanges (if any) of rows JJ and JP at each
*           step J
*
*           (Here, J is a diagonal index)
            jj = j
            jp = ipiv( j )
            IF( jp.LT.0 ) THEN
               jp = -jp
*              (Here, J is a diagonal index)
               j = j - 1
            END IF
*           (NOTE: Here, J is used to determine row length. Length J
*           of the rows to swap back doesn't include diagonal element)
            j = j - 1
            IF( jp.NE.jj .AND. j.GE.1 )
     $         CALL zswap( j, a( jp, 1 ), lda, a( jj, 1 ), lda )
         IF( j.GT.1 )
     $      GO TO 120
*
*        Set KB to the number of columns factorized
*
         kb = k - 1
*
      END IF
      RETURN
*
*     End of ZLAHEF
*

Here is the call graph for this function:

Here is the caller graph for this function: