cpstf2()

subroutine cpstf2	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( n )	piv,
		integer	rank,
		real	tol,
		real, dimension( 2*n )	work,
		integer	info
	)

CPSTF2 computes the Cholesky factorization with complete pivoting of complex Hermitian positive semidefinite matrix.

Download CPSTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CPSTF2 computes the Cholesky factorization with complete
 pivoting of a complex Hermitian positive semidefinite matrix A.

 The factorization has the form
    P**T * A * P = U**H * U ,  if UPLO = 'U',
    P**T * A * P = L  * L**H,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular, and
 P is stored as vector PIV.

 This algorithm does not attempt to check that A is positive
 semidefinite. This version of the algorithm calls level 2 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading n by n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the factor U or L from the Cholesky factorization as above.
[out]	PIV	PIV is INTEGER array, dimension (N) PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
[out]	RANK	RANK is INTEGER The rank of A given by the number of steps the algorithm completed.
[in]	TOL	TOL is REAL User defined tolerance. If TOL < 0, then N*U*MAX( A( K,K ) ) will be used. The algorithm terminates at the (K-1)st step if the pivot <= TOL.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	WORK	WORK is REAL array, dimension (2*N) Work space.
[out]	INFO	INFO is INTEGER < 0: If INFO = -K, the K-th argument had an illegal value, = 0: algorithm completed successfully, and > 0: the matrix A is either rank deficient with computed rank as returned in RANK, or is not positive semidefinite. See Section 7 of LAPACK Working Note #161 for further information.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 141 of file cpstf2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               TOL
      INTEGER            INFO, LDA, N, RANK
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
      REAL               WORK( 2*N )
      INTEGER            PIV( N )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      COMPLEX            CTEMP
      REAL               AJJ, SSTOP, STEMP
      INTEGER            I, ITEMP, J, PVT
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      LOGICAL            LSAME, SISNAN
      EXTERNAL           slamch, lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, clacgv, csscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPSTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Initialize PIV
*
      DO 100 i = 1, n
         piv( i ) = i
  100 CONTINUE
*
*     Compute stopping value
*
      DO 110 i = 1, n
         work( i ) = real( a( i, i ) )
  110 CONTINUE
      pvt = maxloc( work( 1:n ), 1 )
      ajj = real( a( pvt, pvt ) )
      IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
         rank = 0
         info = 1
         GO TO 200
      END IF
*
*     Compute stopping value if not supplied
*
      IF( tol.LT.zero ) THEN
         sstop = n * slamch( 'Epsilon' ) * ajj
      ELSE
         sstop = tol
      END IF
*
*     Set first half of WORK to zero, holds dot products
*
      DO 120 i = 1, n
         work( i ) = 0
  120 CONTINUE
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization P**T * A * P = U**H * U
*
         DO 150 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 130 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) +
     $                        real( conjg( a( j-1, i ) )*
     $                              a( j-1, i ) )
               END IF
               work( n+i ) = real( a( i, i ) ) - work( i )
*
  130       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 190
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL cswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
               IF( pvt.LT.n )
     $            CALL cswap( n-pvt, a( j, pvt+1 ), lda,
     $                        a( pvt, pvt+1 ), lda )
               DO 140 i = j + 1, pvt - 1
                  ctemp = conjg( a( j, i ) )
                  a( j, i ) = conjg( a( i, pvt ) )
                  a( i, pvt ) = ctemp
  140          CONTINUE
               a( j, pvt ) = conjg( a( j, pvt ) )
*
*              Swap dot products and PIV
*
               stemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = stemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J
*
            IF( j.LT.n ) THEN
               CALL clacgv( j-1, a( 1, j ), 1 )
               CALL cgemv( 'Trans', j-1, n-j, -cone, a( 1, j+1 ), lda,
     $                     a( 1, j ), 1, cone, a( j, j+1 ), lda )
               CALL clacgv( j-1, a( 1, j ), 1 )
               CALL csscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
*
  150    CONTINUE
*
      ELSE
*
*        Compute the Cholesky factorization P**T * A * P = L * L**H
*
         DO 180 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 160 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) +
     $                        real( conjg( a( i, j-1 ) )*
     $                              a( i, j-1 ) )
               END IF
               work( n+i ) = real( a( i, i ) ) - work( i )
*
  160       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 190
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL cswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
               IF( pvt.LT.n )
     $            CALL cswap( n-pvt, a( pvt+1, j ), 1, a( pvt+1, pvt ),
     $                        1 )
               DO 170 i = j + 1, pvt - 1
                  ctemp = conjg( a( i, j ) )
                  a( i, j ) = conjg( a( pvt, i ) )
                  a( pvt, i ) = ctemp
  170          CONTINUE
               a( pvt, j ) = conjg( a( pvt, j ) )
*
*              Swap dot products and PIV
*
               stemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = stemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J
*
            IF( j.LT.n ) THEN
               CALL clacgv( j-1, a( j, 1 ), lda )
               CALL cgemv( 'No Trans', n-j, j-1, -cone, a( j+1, 1 ),
     $                     lda, a( j, 1 ), lda, cone, a( j+1, j ), 1 )
               CALL clacgv( j-1, a( j, 1 ), lda )
               CALL csscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
*
  180    CONTINUE
*
      END IF
*
*     Ran to completion, A has full rank
*
      rank = n
*
      GO TO 200
  190 CONTINUE
*
*     Rank is number of steps completed.  Set INFO = 1 to signal
*     that the factorization cannot be used to solve a system.
*
      rank = j - 1
      info = 1
*
  200 CONTINUE
      RETURN
*
*     End of CPSTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: