LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sormbr()

subroutine sormbr ( character vect,
character side,
character trans,
integer m,
integer n,
integer k,
real, dimension( lda, * ) a,
integer lda,
real, dimension( * ) tau,
real, dimension( ldc, * ) c,
integer ldc,
real, dimension( * ) work,
integer lwork,
integer info )

SORMBR

Download SORMBR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> If VECT = 'Q', SORMBR overwrites the general real M-by-N matrix C
!> with
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'T':      Q**T * C       C * Q**T
!>
!> If VECT = 'P', SORMBR overwrites the general real M-by-N matrix C
!> with
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      P * C          C * P
!> TRANS = 'T':      P**T * C       C * P**T
!>
!> Here Q and P**T are the orthogonal matrices determined by SGEBRD when
!> reducing a real matrix A to bidiagonal form: A = Q * B * P**T. Q and
!> P**T are defined as products of elementary reflectors H(i) and G(i)
!> respectively.
!>
!> Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
!> order of the orthogonal matrix Q or P**T that is applied.
!>
!> If VECT = 'Q', A is assumed to have been an NQ-by-K matrix:
!> if nq >= k, Q = H(1) H(2) . . . H(k);
!> if nq < k, Q = H(1) H(2) . . . H(nq-1).
!>
!> If VECT = 'P', A is assumed to have been a K-by-NQ matrix:
!> if k < nq, P = G(1) G(2) . . . G(k);
!> if k >= nq, P = G(1) G(2) . . . G(nq-1).
!>
Parameters
[in]VECT
!>          VECT is CHARACTER*1
!>          = 'Q': apply Q or Q**T;
!>          = 'P': apply P or P**T.
!>
[in]SIDE
!>          SIDE is CHARACTER*1
!>          = 'L': apply Q, Q**T, P or P**T from the Left;
!>          = 'R': apply Q, Q**T, P or P**T from the Right.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          = 'N':  No transpose, apply Q  or P;
!>          = 'T':  Transpose, apply Q**T or P**T.
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix C. M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix C. N >= 0.
!>
[in]K
!>          K is INTEGER
!>          If VECT = 'Q', the number of columns in the original
!>          matrix reduced by SGEBRD.
!>          If VECT = 'P', the number of rows in the original
!>          matrix reduced by SGEBRD.
!>          K >= 0.
!>
[in]A
!>          A is REAL array, dimension
!>                                (LDA,min(nq,K)) if VECT = 'Q'
!>                                (LDA,nq)        if VECT = 'P'
!>          The vectors which define the elementary reflectors H(i) and
!>          G(i), whose products determine the matrices Q and P, as
!>          returned by SGEBRD.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.
!>          If VECT = 'Q', LDA >= max(1,nq);
!>          if VECT = 'P', LDA >= max(1,min(nq,K)).
!>
[in]TAU
!>          TAU is REAL array, dimension (min(nq,K))
!>          TAU(i) must contain the scalar factor of the elementary
!>          reflector H(i) or G(i) which determines Q or P, as returned
!>          by SGEBRD in the array argument TAUQ or TAUP.
!>
[in,out]C
!>          C is REAL array, dimension (LDC,N)
!>          On entry, the M-by-N matrix C.
!>          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q
!>          or P*C or P**T*C or C*P or C*P**T.
!>
[in]LDC
!>          LDC is INTEGER
!>          The leading dimension of the array C. LDC >= max(1,M).
!>
[out]WORK
!>          WORK is REAL array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK.
!>          If SIDE = 'L', LWORK >= max(1,N);
!>          if SIDE = 'R', LWORK >= max(1,M).
!>          For optimum performance LWORK >= N*NB if SIDE = 'L', and
!>          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
!>          blocksize.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 192 of file sormbr.f.

194*
195* -- LAPACK computational routine --
196* -- LAPACK is a software package provided by Univ. of Tennessee, --
197* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
198*
199* .. Scalar Arguments ..
200 CHARACTER SIDE, TRANS, VECT
201 INTEGER INFO, K, LDA, LDC, LWORK, M, N
202* ..
203* .. Array Arguments ..
204 REAL A( LDA, * ), C( LDC, * ), TAU( * ),
205 $ WORK( * )
206* ..
207*
208* =====================================================================
209*
210* .. Local Scalars ..
211 LOGICAL APPLYQ, LEFT, LQUERY, NOTRAN
212 CHARACTER TRANST
213 INTEGER I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
214* ..
215* .. External Functions ..
216 LOGICAL LSAME
217 INTEGER ILAENV
218 REAL SROUNDUP_LWORK
219 EXTERNAL ilaenv, lsame, sroundup_lwork
220* ..
221* .. External Subroutines ..
222 EXTERNAL sormlq, sormqr, xerbla
223* ..
224* .. Intrinsic Functions ..
225 INTRINSIC max, min
226* ..
227* .. Executable Statements ..
228*
229* Test the input arguments
230*
231 info = 0
232 applyq = lsame( vect, 'Q' )
233 left = lsame( side, 'L' )
234 notran = lsame( trans, 'N' )
235 lquery = ( lwork.EQ.-1 )
236*
237* NQ is the order of Q or P and NW is the minimum dimension of WORK
238*
239 IF( left ) THEN
240 nq = m
241 nw = max( 1, n )
242 ELSE
243 nq = n
244 nw = max( 1, m )
245 END IF
246 IF( .NOT.applyq .AND. .NOT.lsame( vect, 'P' ) ) THEN
247 info = -1
248 ELSE IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
249 info = -2
250 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
251 info = -3
252 ELSE IF( m.LT.0 ) THEN
253 info = -4
254 ELSE IF( n.LT.0 ) THEN
255 info = -5
256 ELSE IF( k.LT.0 ) THEN
257 info = -6
258 ELSE IF( ( applyq .AND. lda.LT.max( 1, nq ) ) .OR.
259 $ ( .NOT.applyq .AND. lda.LT.max( 1, min( nq, k ) ) ) )
260 $ THEN
261 info = -8
262 ELSE IF( ldc.LT.max( 1, m ) ) THEN
263 info = -11
264 ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
265 info = -13
266 END IF
267*
268 IF( info.EQ.0 ) THEN
269 IF( applyq ) THEN
270 IF( left ) THEN
271 nb = ilaenv( 1, 'SORMQR', side // trans, m-1, n, m-1,
272 $ -1 )
273 ELSE
274 nb = ilaenv( 1, 'SORMQR', side // trans, m, n-1, n-1,
275 $ -1 )
276 END IF
277 ELSE
278 IF( left ) THEN
279 nb = ilaenv( 1, 'SORMLQ', side // trans, m-1, n, m-1,
280 $ -1 )
281 ELSE
282 nb = ilaenv( 1, 'SORMLQ', side // trans, m, n-1, n-1,
283 $ -1 )
284 END IF
285 END IF
286 lwkopt = nw*nb
287 work( 1 ) = sroundup_lwork(lwkopt)
288 END IF
289*
290 IF( info.NE.0 ) THEN
291 CALL xerbla( 'SORMBR', -info )
292 RETURN
293 ELSE IF( lquery ) THEN
294 RETURN
295 END IF
296*
297* Quick return if possible
298*
299 work( 1 ) = 1
300 IF( m.EQ.0 .OR. n.EQ.0 )
301 $ RETURN
302*
303 IF( applyq ) THEN
304*
305* Apply Q
306*
307 IF( nq.GE.k ) THEN
308*
309* Q was determined by a call to SGEBRD with nq >= k
310*
311 CALL sormqr( side, trans, m, n, k, a, lda, tau, c, ldc,
312 $ work, lwork, iinfo )
313 ELSE IF( nq.GT.1 ) THEN
314*
315* Q was determined by a call to SGEBRD with nq < k
316*
317 IF( left ) THEN
318 mi = m - 1
319 ni = n
320 i1 = 2
321 i2 = 1
322 ELSE
323 mi = m
324 ni = n - 1
325 i1 = 1
326 i2 = 2
327 END IF
328 CALL sormqr( side, trans, mi, ni, nq-1, a( 2, 1 ), lda,
329 $ tau,
330 $ c( i1, i2 ), ldc, work, lwork, iinfo )
331 END IF
332 ELSE
333*
334* Apply P
335*
336 IF( notran ) THEN
337 transt = 'T'
338 ELSE
339 transt = 'N'
340 END IF
341 IF( nq.GT.k ) THEN
342*
343* P was determined by a call to SGEBRD with nq > k
344*
345 CALL sormlq( side, transt, m, n, k, a, lda, tau, c, ldc,
346 $ work, lwork, iinfo )
347 ELSE IF( nq.GT.1 ) THEN
348*
349* P was determined by a call to SGEBRD with nq <= k
350*
351 IF( left ) THEN
352 mi = m - 1
353 ni = n
354 i1 = 2
355 i2 = 1
356 ELSE
357 mi = m
358 ni = n - 1
359 i1 = 1
360 i2 = 2
361 END IF
362 CALL sormlq( side, transt, mi, ni, nq-1, a( 1, 2 ), lda,
363 $ tau, c( i1, i2 ), ldc, work, lwork, iinfo )
364 END IF
365 END IF
366 work( 1 ) = sroundup_lwork(lwkopt)
367 RETURN
368*
369* End of SORMBR
370*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
sormlq
subroutine sormlq(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
SORMLQ
Definition sormlq.f:166
sormqr
subroutine sormqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
SORMQR
Definition sormqr.f:166
Here is the call graph for this function:
Here is the caller graph for this function: