zla_geamv.f

Go to the documentation of this file.

*> \brief \b ZLA_GEAMV computes a matrix-vector product using a general matrix to calculate error bounds.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download ZLA_GEAMV + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_geamv.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_geamv.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_geamv.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLA_GEAMV( TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA,
*                             Y, INCY )
*
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   ALPHA, BETA
*       INTEGER            INCX, INCY, LDA, M, N
*       INTEGER            TRANS
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), X( * )
*       DOUBLE PRECISION   Y( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLA_GEAMV  performs one of the matrix-vector operations
*>
*>         y := alpha*abs(A)*abs(x) + beta*abs(y),
*>    or   y := alpha*abs(A)**T*abs(x) + beta*abs(y),
*>
*> where alpha and beta are scalars, x and y are vectors and A is an
*> m by n matrix.
*>
*> This function is primarily used in calculating error bounds.
*> To protect against underflow during evaluation, components in
*> the resulting vector are perturbed away from zero by (N+1)
*> times the underflow threshold.  To prevent unnecessarily large
*> errors for block-structure embedded in general matrices,
*> "symbolically" zero components are not perturbed.  A zero
*> entry is considered "symbolic" if all multiplications involved
*> in computing that entry have at least one zero multiplicand.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is INTEGER
*>           On entry, TRANS specifies the operation to be performed as
*>           follows:
*>
*>             BLAS_NO_TRANS      y := alpha*abs(A)*abs(x) + beta*abs(y)
*>             BLAS_TRANS         y := alpha*abs(A**T)*abs(x) + beta*abs(y)
*>             BLAS_CONJ_TRANS    y := alpha*abs(A**T)*abs(x) + beta*abs(y)
*>
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>           On entry, M specifies the number of rows of the matrix A.
*>           M must be at least zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the number of columns of the matrix A.
*>           N must be at least zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*>          ALPHA is DOUBLE PRECISION
*>           On entry, ALPHA specifies the scalar alpha.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension ( LDA, n )
*>           Before entry, the leading m by n part of the array A must
*>           contain the matrix of coefficients.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>           On entry, LDA specifies the first dimension of A as declared
*>           in the calling (sub) program. LDA must be at least
*>           max( 1, m ).
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension at least
*>           ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
*>           and at least
*>           ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
*>           Before entry, the incremented array X must contain the
*>           vector x.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] BETA
*> \verbatim
*>          BETA is DOUBLE PRECISION
*>           On entry, BETA specifies the scalar beta. When BETA is
*>           supplied as zero then Y need not be set on input.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in,out] Y
*> \verbatim
*>          Y is DOUBLE PRECISION array, dimension
*>           ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
*>           and at least
*>           ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
*>           Before entry with BETA non-zero, the incremented array Y
*>           must contain the vector y. On exit, Y is overwritten by the
*>           updated vector y.
*>           If either m or n is zero, then Y not referenced and the function
*>           performs a quick return.
*> \endverbatim
*>
*> \param[in] INCY
*> \verbatim
*>          INCY is INTEGER
*>           On entry, INCY specifies the increment for the elements of
*>           Y. INCY must not be zero.
*>           Unchanged on exit.
*>
*>  Level 2 Blas routine.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup la_geamv
*
*  =====================================================================
      SUBROUTINE zla_geamv( TRANS, M, N, ALPHA, A, LDA, X, INCX,
     $                      BETA,
     $                      Y, INCY )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   ALPHA, BETA
      INTEGER            INCX, INCY, LDA, M, N
      INTEGER            TRANS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), X( * )
      DOUBLE PRECISION   Y( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      PARAMETER          ( ONE = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            SYMB_ZERO
      DOUBLE PRECISION   TEMP, SAFE1
      INTEGER            I, INFO, IY, J, JX, KX, KY, LENX, LENY
      COMPLEX*16         CDUM
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, dlamch
      DOUBLE PRECISION   DLAMCH
*     ..
*     .. External Functions ..
      EXTERNAL           ilatrans
      INTEGER            ILATRANS
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, abs, real, dimag, sign
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF     ( .NOT.( ( trans.EQ.ilatrans( 'N' ) )
     $           .OR. ( trans.EQ.ilatrans( 'T' ) )
     $           .OR. ( trans.EQ.ilatrans( 'C' ) ) ) ) THEN
         info = 1
      ELSE IF( m.LT.0 )THEN
         info = 2
      ELSE IF( n.LT.0 )THEN
         info = 3
      ELSE IF( lda.LT.max( 1, m ) )THEN
         info = 6
      ELSE IF( incx.EQ.0 )THEN
         info = 8
      ELSE IF( incy.EQ.0 )THEN
         info = 11
      END IF
      IF( info.NE.0 )THEN
         CALL xerbla( 'ZLA_GEAMV ', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( m.EQ.0 ).OR.( n.EQ.0 ).OR.
     $    ( ( alpha.EQ.zero ).AND.( beta.EQ.one ) ) )
     $   RETURN
*
*     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
*     up the start points in  X  and  Y.
*
      IF( trans.EQ.ilatrans( 'N' ) )THEN
         lenx = n
         leny = m
      ELSE
         lenx = m
         leny = n
      END IF
      IF( incx.GT.0 )THEN
         kx = 1
      ELSE
         kx = 1 - ( lenx - 1 )*incx
      END IF
      IF( incy.GT.0 )THEN
         ky = 1
      ELSE
         ky = 1 - ( leny - 1 )*incy
      END IF
*
*     Set SAFE1 essentially to be the underflow threshold times the
*     number of additions in each row.
*
      safe1 = dlamch( 'Safe minimum' )
      safe1 = (n+1)*safe1
*
*     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
*
*     The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
*     the inexact flag.  Still doesn't help change the iteration order
*     to per-column.
*
      iy = ky
      IF ( incx.EQ.1 ) THEN
         IF( trans.EQ.ilatrans( 'N' ) )THEN
            DO i = 1, leny
               IF ( beta .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. 0.0d+0 ) THEN
                  DO j = 1, lenx
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
               END IF
 
               IF ( .NOT.symb_zero ) y( iy ) =
     $              y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         ELSE
            DO i = 1, leny
               IF ( beta .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. 0.0d+0 ) THEN
                  DO j = 1, lenx
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
               END IF
 
               IF ( .NOT.symb_zero ) y( iy ) =
     $              y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         END IF
      ELSE
         IF( trans.EQ.ilatrans( 'N' ) )THEN
            DO i = 1, leny
               IF ( beta .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. 0.0d+0 ) THEN
                  jx = kx
                  DO j = 1, lenx
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( jx ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
               END IF
 
               IF ( .NOT.symb_zero ) y( iy ) =
     $              y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         ELSE
            DO i = 1, leny
               IF ( beta .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. 0.0d+0 ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. 0.0d+0 ) THEN
                  jx = kx
                  DO j = 1, lenx
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( jx ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
               END IF
 
               IF ( .NOT.symb_zero ) y( iy ) =
     $              y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         END IF
 
      END IF
*
      RETURN
*
*     End of ZLA_GEAMV
*
      END