zhegs2()

subroutine zhegs2	(	integer	itype,
		character	uplo,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		integer	info
	)

ZHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorization results obtained from cpotrf (unblocked algorithm).

Download ZHEGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZHEGS2 reduces a complex Hermitian-definite generalized
 eigenproblem to standard form.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H *A*L.

 B must have been previously factorized as U**H *U or L*L**H by ZPOTRF.

Parameters

[in]	ITYPE	ITYPE is INTEGER = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H); = 2 or 3: compute U*A*U**H or L**H *A*L.
[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored, and how B has been factorized. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrices A and B. N >= 0.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading n by n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the transformed matrix, stored in the same format as A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,N) The triangular factor from the Cholesky factorization of B, as returned by ZPOTRF. B is modified by the routine but restored on exit.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 127 of file zhegs2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, HALF
      parameter( one = 1.0d+0, half = 0.5d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            K
      DOUBLE PRECISION   AKK, BKK
      COMPLEX*16         CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zdscal, zher2, zlacgv, ztrmv,
     $                   ztrsv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZHEGS2', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**H)*A*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of A(k:n,k:n)
*
               akk = dble( a( k, k ) )
               bkk = dble( b( k, k ) )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL zdscal( n-k, one / bkk, a( k, k+1 ), lda )
                  ct = -half*akk
                  CALL zlacgv( n-k, a( k, k+1 ), lda )
                  CALL zlacgv( n-k, b( k, k+1 ), ldb )
                  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL zher2( uplo, n-k, -cone, a( k, k+1 ), lda,
     $                        b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
                  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL zlacgv( n-k, b( k, k+1 ), ldb )
                  CALL ztrsv( uplo, 'Conjugate transpose', 'Non-unit',
     $                        n-k, b( k+1, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL zlacgv( n-k, a( k, k+1 ), lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L**H)
*
            DO 20 k = 1, n
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = dble( a( k, k ) )
               bkk = dble( b( k, k ) )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL zdscal( n-k, one / bkk, a( k+1, k ), 1 )
                  ct = -half*akk
                  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL zher2( uplo, n-k, -cone, a( k+1, k ), 1,
     $                        b( k+1, k ), 1, a( k+1, k+1 ), lda )
                  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL ztrsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
               END IF
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**H
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = dble( a( k, k ) )
               bkk = dble( b( k, k ) )
               CALL ztrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
     $                     ldb, a( 1, k ), 1 )
               ct = half*akk
               CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL zher2( uplo, k-1, cone, a( 1, k ), 1, b( 1, k ), 1,
     $                     a, lda )
               CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL zdscal( k-1, bkk, a( 1, k ), 1 )
               a( k, k ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L**H *A*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(1:k,1:k)
*
               akk = dble( a( k, k ) )
               bkk = dble( b( k, k ) )
               CALL zlacgv( k-1, a( k, 1 ), lda )
               CALL ztrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
     $                     b, ldb, a( k, 1 ), lda )
               ct = half*akk
               CALL zlacgv( k-1, b( k, 1 ), ldb )
               CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL zher2( uplo, k-1, cone, a( k, 1 ), lda, b( k, 1 ),
     $                     ldb, a, lda )
               CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL zlacgv( k-1, b( k, 1 ), ldb )
               CALL zdscal( k-1, bkk, a( k, 1 ), lda )
               CALL zlacgv( k-1, a( k, 1 ), lda )
               a( k, k ) = akk*bkk**2
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of ZHEGS2
*

Here is the call graph for this function:

Here is the caller graph for this function: