LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zgemlq.f
Go to the documentation of this file.
1*> \brief \b ZGEMLQ
2*
3* Definition:
4* ===========
5*
6* SUBROUTINE ZGEMLQ( SIDE, TRANS, M, N, K, A, LDA, T,
7* $ TSIZE, C, LDC, WORK, LWORK, INFO )
8*
9*
10* .. Scalar Arguments ..
11* CHARACTER SIDE, TRANS
12* INTEGER INFO, LDA, M, N, K, LDT, TSIZE, LWORK, LDC
13* ..
14* .. Array Arguments ..
15* COMPLEX*16 A( LDA, * ), T( * ), C(LDC, * ), WORK( * )
16*> \par Purpose:
17* =============
18*>
19*> \verbatim
20*>
21*> ZGEMLQ overwrites the general real M-by-N matrix C with
22*>
23*> SIDE = 'L' SIDE = 'R'
24*> TRANS = 'N': Q * C C * Q
25*> TRANS = 'C': Q**H * C C * Q**H
26*> where Q is a complex unitary matrix defined as the product
27*> of blocked elementary reflectors computed by short wide
28*> LQ factorization (ZGELQ)
29*>
30*> \endverbatim
31*
32* Arguments:
33* ==========
34*
35*> \param[in] SIDE
36*> \verbatim
37*> SIDE is CHARACTER*1
38*> = 'L': apply Q or Q**H from the Left;
39*> = 'R': apply Q or Q**H from the Right.
40*> \endverbatim
41*>
42*> \param[in] TRANS
43*> \verbatim
44*> TRANS is CHARACTER*1
45*> = 'N': No transpose, apply Q;
46*> = 'C': Conjugate transpose, apply Q**H.
47*> \endverbatim
48*>
49*> \param[in] M
50*> \verbatim
51*> M is INTEGER
52*> The number of rows of the matrix A. M >=0.
53*> \endverbatim
54*>
55*> \param[in] N
56*> \verbatim
57*> N is INTEGER
58*> The number of columns of the matrix C. N >= 0.
59*> \endverbatim
60*>
61*> \param[in] K
62*> \verbatim
63*> K is INTEGER
64*> The number of elementary reflectors whose product defines
65*> the matrix Q.
66*> If SIDE = 'L', M >= K >= 0;
67*> if SIDE = 'R', N >= K >= 0.
68*>
69*> \endverbatim
70*>
71*> \param[in] A
72*> \verbatim
73*> A is COMPLEX*16 array, dimension
74*> (LDA,M) if SIDE = 'L',
75*> (LDA,N) if SIDE = 'R'
76*> Part of the data structure to represent Q as returned by ZGELQ.
77*> \endverbatim
78*>
79*> \param[in] LDA
80*> \verbatim
81*> LDA is INTEGER
82*> The leading dimension of the array A. LDA >= max(1,K).
83*> \endverbatim
84*>
85*> \param[in] T
86*> \verbatim
87*> T is COMPLEX*16 array, dimension (MAX(5,TSIZE)).
88*> Part of the data structure to represent Q as returned by ZGELQ.
89*> \endverbatim
90*>
91*> \param[in] TSIZE
92*> \verbatim
93*> TSIZE is INTEGER
94*> The dimension of the array T. TSIZE >= 5.
95*> \endverbatim
96*>
97*> \param[in,out] C
98*> \verbatim
99*> C is COMPLEX*16 array, dimension (LDC,N)
100*> On entry, the M-by-N matrix C.
101*> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
102*> \endverbatim
103*>
104*> \param[in] LDC
105*> \verbatim
106*> LDC is INTEGER
107*> The leading dimension of the array C. LDC >= max(1,M).
108*> \endverbatim
109*>
110*> \param[out] WORK
111*> \verbatim
112*> (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
113*> \endverbatim
114*>
115*> \param[in] LWORK
116*> \verbatim
117*> LWORK is INTEGER
118*> The dimension of the array WORK.
119*> If LWORK = -1, then a workspace query is assumed. The routine
120*> only calculates the size of the WORK array, returns this
121*> value as WORK(1), and no error message related to WORK
122*> is issued by XERBLA.
123*> \endverbatim
124*>
125*> \param[out] INFO
126*> \verbatim
127*> INFO is INTEGER
128*> = 0: successful exit
129*> < 0: if INFO = -i, the i-th argument had an illegal value
130*> \endverbatim
131*
132* Authors:
133* ========
134*
135*> \author Univ. of Tennessee
136*> \author Univ. of California Berkeley
137*> \author Univ. of Colorado Denver
138*> \author NAG Ltd.
139*
140*> \par Further Details
141* ====================
142*>
143*> \verbatim
144*>
145*> These details are particular for this LAPACK implementation. Users should not
146*> take them for granted. These details may change in the future, and are not likely
147*> true for another LAPACK implementation. These details are relevant if one wants
148*> to try to understand the code. They are not part of the interface.
149*>
150*> In this version,
151*>
152*> T(2): row block size (MB)
153*> T(3): column block size (NB)
154*> T(6:TSIZE): data structure needed for Q, computed by
155*> ZLASWLQ or ZGELQT
156*>
157*> Depending on the matrix dimensions M and N, and row and column
158*> block sizes MB and NB returned by ILAENV, ZGELQ will use either
159*> ZLASWLQ (if the matrix is wide-and-short) or ZGELQT to compute
160*> the LQ factorization.
161*> This version of ZGEMLQ will use either ZLAMSWLQ or ZGEMLQT to
162*> multiply matrix Q by another matrix.
163*> Further Details in ZLAMSWLQ or ZGEMLQT.
164*> \endverbatim
165*>
166*> \ingroup gemlq
167*>
168* =====================================================================
169 SUBROUTINE zgemlq( SIDE, TRANS, M, N, K, A, LDA, T, TSIZE,
170 $ C, LDC, WORK, LWORK, INFO )
171*
172* -- LAPACK computational routine --
173* -- LAPACK is a software package provided by Univ. of Tennessee, --
174* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
175*
176* .. Scalar Arguments ..
177 CHARACTER SIDE, TRANS
178 INTEGER INFO, LDA, M, N, K, TSIZE, LWORK, LDC
179* ..
180* .. Array Arguments ..
181 COMPLEX*16 A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
182* ..
183*
184* =====================================================================
185*
186* ..
187* .. Local Scalars ..
188 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
189 INTEGER MB, NB, LW, NBLCKS, MN
190* ..
191* .. External Functions ..
192 LOGICAL LSAME
193 EXTERNAL lsame
194* ..
195* .. External Subroutines ..
196 EXTERNAL zlamswlq, zgemlqt, xerbla
197* ..
198* .. Intrinsic Functions ..
199 INTRINSIC int, max, min, mod
200* ..
201* .. Executable Statements ..
202*
203* Test the input arguments
204*
205 lquery = lwork.EQ.-1
206 notran = lsame( trans, 'N' )
207 tran = lsame( trans, 'C' )
208 left = lsame( side, 'L' )
209 right = lsame( side, 'R' )
210*
211 mb = int( t( 2 ) )
212 nb = int( t( 3 ) )
213 IF( left ) THEN
214 lw = n * mb
215 mn = m
216 ELSE
217 lw = m * mb
218 mn = n
219 END IF
220*
221 IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
222 IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
223 nblcks = ( mn - k ) / ( nb - k )
224 ELSE
225 nblcks = ( mn - k ) / ( nb - k ) + 1
226 END IF
227 ELSE
228 nblcks = 1
229 END IF
230*
231 info = 0
232 IF( .NOT.left .AND. .NOT.right ) THEN
233 info = -1
234 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
235 info = -2
236 ELSE IF( m.LT.0 ) THEN
237 info = -3
238 ELSE IF( n.LT.0 ) THEN
239 info = -4
240 ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
241 info = -5
242 ELSE IF( lda.LT.max( 1, k ) ) THEN
243 info = -7
244 ELSE IF( tsize.LT.5 ) THEN
245 info = -9
246 ELSE IF( ldc.LT.max( 1, m ) ) THEN
247 info = -11
248 ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
249 info = -13
250 END IF
251*
252 IF( info.EQ.0 ) THEN
253 work( 1 ) = lw
254 END IF
255*
256 IF( info.NE.0 ) THEN
257 CALL xerbla( 'ZGEMLQ', -info )
258 RETURN
259 ELSE IF( lquery ) THEN
260 RETURN
261 END IF
262*
263* Quick return if possible
264*
265 IF( min( m, n, k ).EQ.0 ) THEN
266 RETURN
267 END IF
268*
269 IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
270 $ .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
271 CALL zgemlqt( side, trans, m, n, k, mb, a, lda,
272 $ t( 6 ), mb, c, ldc, work, info )
273 ELSE
274 CALL zlamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
275 $ mb, c, ldc, work, lwork, info )
276 END IF
277*
278 work( 1 ) = lw
279*
280 RETURN
281*
282* End of ZGEMLQ
283*
284 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zgemlq(side, trans, m, n, k, a, lda, t, tsize, c, ldc, work, lwork, info)
ZGEMLQ
Definition zgemlq.f:171
subroutine zgemlqt(side, trans, m, n, k, mb, v, ldv, t, ldt, c, ldc, work, info)
ZGEMLQT
Definition zgemlqt.f:168
subroutine zlamswlq(side, trans, m, n, k, mb, nb, a, lda, t, ldt, c, ldc, work, lwork, info)
ZLAMSWLQ
Definition zlamswlq.f:197