LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ zgemlq()

subroutine zgemlq ( character  SIDE,
character  TRANS,
integer  M,
integer  N,
integer  K,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( * )  T,
integer  TSIZE,
complex*16, dimension( ldc, * )  C,
integer  LDC,
complex*16, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

ZGEMLQ

Purpose:
     ZGEMLQ overwrites the general real M-by-N matrix C with

                      SIDE = 'L'     SIDE = 'R'
      TRANS = 'N':      Q * C          C * Q
      TRANS = 'C':      Q**H * C       C * Q**H
      where Q is a complex unitary matrix defined as the product
      of blocked elementary reflectors computed by short wide
      LQ factorization (ZGELQ)
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply Q or Q**H from the Left;
          = 'R': apply Q or Q**H from the Right.
[in]TRANS
          TRANS is CHARACTER*1
          = 'N':  No transpose, apply Q;
          = 'C':  Conjugate transpose, apply Q**H.
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >=0.
[in]N
          N is INTEGER
          The number of columns of the matrix C. N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines
          the matrix Q.
          If SIDE = 'L', M >= K >= 0;
          if SIDE = 'R', N >= K >= 0.
[in]A
          A is COMPLEX*16 array, dimension
                               (LDA,M) if SIDE = 'L',
                               (LDA,N) if SIDE = 'R'
          Part of the data structure to represent Q as returned by ZGELQ.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,K).
[in]T
          T is COMPLEX*16 array, dimension (MAX(5,TSIZE)).
          Part of the data structure to represent Q as returned by ZGELQ.
[in]TSIZE
          TSIZE is INTEGER
          The dimension of the array T. TSIZE >= 5.
[in,out]C
          C is COMPLEX*16 array, dimension (LDC,N)
          On entry, the M-by-N matrix C.
          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
         (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
          If LWORK = -1, then a workspace query is assumed. The routine
          only calculates the size of the WORK array, returns this
          value as WORK(1), and no error message related to WORK 
          is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details
 These details are particular for this LAPACK implementation. Users should not 
 take them for granted. These details may change in the future, and are not likely
 true for another LAPACK implementation. These details are relevant if one wants
 to try to understand the code. They are not part of the interface.

 In this version,

          T(2): row block size (MB)
          T(3): column block size (NB)
          T(6:TSIZE): data structure needed for Q, computed by
                           ZLASWLQ or ZGELQT

  Depending on the matrix dimensions M and N, and row and column
  block sizes MB and NB returned by ILAENV, ZGELQ will use either
  ZLASWLQ (if the matrix is wide-and-short) or ZGELQT to compute
  the LQ factorization.
  This version of ZGEMLQ will use either ZLAMSWLQ or ZGEMLQT to 
  multiply matrix Q by another matrix.
  Further Details in ZLAMSWLQ or ZGEMLQT.

Definition at line 167 of file zgemlq.f.

169 *
170 * -- LAPACK computational routine --
171 * -- LAPACK is a software package provided by Univ. of Tennessee, --
172 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
173 *
174 * .. Scalar Arguments ..
175  CHARACTER SIDE, TRANS
176  INTEGER INFO, LDA, M, N, K, TSIZE, LWORK, LDC
177 * ..
178 * .. Array Arguments ..
179  COMPLEX*16 A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
180 * ..
181 *
182 * =====================================================================
183 *
184 * ..
185 * .. Local Scalars ..
186  LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
187  INTEGER MB, NB, LW, NBLCKS, MN
188 * ..
189 * .. External Functions ..
190  LOGICAL LSAME
191  EXTERNAL lsame
192 * ..
193 * .. External Subroutines ..
194  EXTERNAL zlamswlq, zgemlqt, xerbla
195 * ..
196 * .. Intrinsic Functions ..
197  INTRINSIC int, max, min, mod
198 * ..
199 * .. Executable Statements ..
200 *
201 * Test the input arguments
202 *
203  lquery = lwork.EQ.-1
204  notran = lsame( trans, 'N' )
205  tran = lsame( trans, 'C' )
206  left = lsame( side, 'L' )
207  right = lsame( side, 'R' )
208 *
209  mb = int( t( 2 ) )
210  nb = int( t( 3 ) )
211  IF( left ) THEN
212  lw = n * mb
213  mn = m
214  ELSE
215  lw = m * mb
216  mn = n
217  END IF
218 *
219  IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
220  IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
221  nblcks = ( mn - k ) / ( nb - k )
222  ELSE
223  nblcks = ( mn - k ) / ( nb - k ) + 1
224  END IF
225  ELSE
226  nblcks = 1
227  END IF
228 *
229  info = 0
230  IF( .NOT.left .AND. .NOT.right ) THEN
231  info = -1
232  ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
233  info = -2
234  ELSE IF( m.LT.0 ) THEN
235  info = -3
236  ELSE IF( n.LT.0 ) THEN
237  info = -4
238  ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
239  info = -5
240  ELSE IF( lda.LT.max( 1, k ) ) THEN
241  info = -7
242  ELSE IF( tsize.LT.5 ) THEN
243  info = -9
244  ELSE IF( ldc.LT.max( 1, m ) ) THEN
245  info = -11
246  ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
247  info = -13
248  END IF
249 *
250  IF( info.EQ.0 ) THEN
251  work( 1 ) = lw
252  END IF
253 *
254  IF( info.NE.0 ) THEN
255  CALL xerbla( 'ZGEMLQ', -info )
256  RETURN
257  ELSE IF( lquery ) THEN
258  RETURN
259  END IF
260 *
261 * Quick return if possible
262 *
263  IF( min( m, n, k ).EQ.0 ) THEN
264  RETURN
265  END IF
266 *
267  IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
268  $ .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
269  CALL zgemlqt( side, trans, m, n, k, mb, a, lda,
270  $ t( 6 ), mb, c, ldc, work, info )
271  ELSE
272  CALL zlamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
273  $ mb, c, ldc, work, lwork, info )
274  END IF
275 *
276  work( 1 ) = lw
277 *
278  RETURN
279 *
280 * End of ZGEMLQ
281 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zgemlqt(SIDE, TRANS, M, N, K, MB, V, LDV, T, LDT, C, LDC, WORK, INFO)
ZGEMLQT
Definition: zgemlqt.f:168
subroutine zlamswlq(SIDE, TRANS, M, N, K, MB, NB, A, LDA, T, LDT, C, LDC, WORK, LWORK, INFO)
ZLAMSWLQ
Definition: zlamswlq.f:195
Here is the call graph for this function:
Here is the caller graph for this function: