LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ dpptri()

subroutine dpptri ( character  UPLO,
integer  N,
double precision, dimension( * )  AP,
integer  INFO 
)

DPPTRI

Download DPPTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DPPTRI computes the inverse of a real symmetric positive definite
 matrix A using the Cholesky factorization A = U**T*U or A = L*L**T
 computed by DPPTRF.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangular factor is stored in AP;
          = 'L':  Lower triangular factor is stored in AP.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]AP
          AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
          On entry, the triangular factor U or L from the Cholesky
          factorization A = U**T*U or A = L*L**T, packed columnwise as
          a linear array.  The j-th column of U or L is stored in the
          array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.

          On exit, the upper or lower triangle of the (symmetric)
          inverse of A, overwriting the input factor U or L.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, the (i,i) element of the factor U or L is
                zero, and the inverse could not be computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 92 of file dpptri.f.

93 *
94 * -- LAPACK computational routine --
95 * -- LAPACK is a software package provided by Univ. of Tennessee, --
96 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
97 *
98 * .. Scalar Arguments ..
99  CHARACTER UPLO
100  INTEGER INFO, N
101 * ..
102 * .. Array Arguments ..
103  DOUBLE PRECISION AP( * )
104 * ..
105 *
106 * =====================================================================
107 *
108 * .. Parameters ..
109  DOUBLE PRECISION ONE
110  parameter( one = 1.0d+0 )
111 * ..
112 * .. Local Scalars ..
113  LOGICAL UPPER
114  INTEGER J, JC, JJ, JJN
115  DOUBLE PRECISION AJJ
116 * ..
117 * .. External Functions ..
118  LOGICAL LSAME
119  DOUBLE PRECISION DDOT
120  EXTERNAL lsame, ddot
121 * ..
122 * .. External Subroutines ..
123  EXTERNAL dscal, dspr, dtpmv, dtptri, xerbla
124 * ..
125 * .. Executable Statements ..
126 *
127 * Test the input parameters.
128 *
129  info = 0
130  upper = lsame( uplo, 'U' )
131  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
132  info = -1
133  ELSE IF( n.LT.0 ) THEN
134  info = -2
135  END IF
136  IF( info.NE.0 ) THEN
137  CALL xerbla( 'DPPTRI', -info )
138  RETURN
139  END IF
140 *
141 * Quick return if possible
142 *
143  IF( n.EQ.0 )
144  $ RETURN
145 *
146 * Invert the triangular Cholesky factor U or L.
147 *
148  CALL dtptri( uplo, 'Non-unit', n, ap, info )
149  IF( info.GT.0 )
150  $ RETURN
151 *
152  IF( upper ) THEN
153 *
154 * Compute the product inv(U) * inv(U)**T.
155 *
156  jj = 0
157  DO 10 j = 1, n
158  jc = jj + 1
159  jj = jj + j
160  IF( j.GT.1 )
161  $ CALL dspr( 'Upper', j-1, one, ap( jc ), 1, ap )
162  ajj = ap( jj )
163  CALL dscal( j, ajj, ap( jc ), 1 )
164  10 CONTINUE
165 *
166  ELSE
167 *
168 * Compute the product inv(L)**T * inv(L).
169 *
170  jj = 1
171  DO 20 j = 1, n
172  jjn = jj + n - j + 1
173  ap( jj ) = ddot( n-j+1, ap( jj ), 1, ap( jj ), 1 )
174  IF( j.LT.n )
175  $ CALL dtpmv( 'Lower', 'Transpose', 'Non-unit', n-j,
176  $ ap( jjn ), ap( jj+1 ), 1 )
177  jj = jjn
178  20 CONTINUE
179  END IF
180 *
181  RETURN
182 *
183 * End of DPPTRI
184 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function ddot(N, DX, INCX, DY, INCY)
DDOT
Definition: ddot.f:82
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:79
subroutine dtpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPMV
Definition: dtpmv.f:142
subroutine dspr(UPLO, N, ALPHA, X, INCX, AP)
DSPR
Definition: dspr.f:127
subroutine dtptri(UPLO, DIAG, N, AP, INFO)
DTPTRI
Definition: dtptri.f:117
Here is the call graph for this function:
Here is the caller graph for this function: