 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ dpptrs()

 subroutine dpptrs ( character UPLO, integer N, integer NRHS, double precision, dimension( * ) AP, double precision, dimension( ldb, * ) B, integer LDB, integer INFO )

DPPTRS

Download DPPTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` DPPTRS solves a system of linear equations A*X = B with a symmetric
positive definite matrix A in packed storage using the Cholesky
factorization A = U**T*U or A = L*L**T computed by DPPTRF.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.``` [in] AP ``` AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) The triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, packed columnwise in a linear array. The j-th column of U or L is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.``` [in,out] B ``` B is DOUBLE PRECISION array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```

Definition at line 107 of file dpptrs.f.

108 *
109 * -- LAPACK computational routine --
110 * -- LAPACK is a software package provided by Univ. of Tennessee, --
111 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
112 *
113 * .. Scalar Arguments ..
114  CHARACTER UPLO
115  INTEGER INFO, LDB, N, NRHS
116 * ..
117 * .. Array Arguments ..
118  DOUBLE PRECISION AP( * ), B( LDB, * )
119 * ..
120 *
121 * =====================================================================
122 *
123 * .. Local Scalars ..
124  LOGICAL UPPER
125  INTEGER I
126 * ..
127 * .. External Functions ..
128  LOGICAL LSAME
129  EXTERNAL lsame
130 * ..
131 * .. External Subroutines ..
132  EXTERNAL dtpsv, xerbla
133 * ..
134 * .. Intrinsic Functions ..
135  INTRINSIC max
136 * ..
137 * .. Executable Statements ..
138 *
139 * Test the input parameters.
140 *
141  info = 0
142  upper = lsame( uplo, 'U' )
143  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
144  info = -1
145  ELSE IF( n.LT.0 ) THEN
146  info = -2
147  ELSE IF( nrhs.LT.0 ) THEN
148  info = -3
149  ELSE IF( ldb.LT.max( 1, n ) ) THEN
150  info = -6
151  END IF
152  IF( info.NE.0 ) THEN
153  CALL xerbla( 'DPPTRS', -info )
154  RETURN
155  END IF
156 *
157 * Quick return if possible
158 *
159  IF( n.EQ.0 .OR. nrhs.EQ.0 )
160  \$ RETURN
161 *
162  IF( upper ) THEN
163 *
164 * Solve A*X = B where A = U**T * U.
165 *
166  DO 10 i = 1, nrhs
167 *
168 * Solve U**T *X = B, overwriting B with X.
169 *
170  CALL dtpsv( 'Upper', 'Transpose', 'Non-unit', n, ap,
171  \$ b( 1, i ), 1 )
172 *
173 * Solve U*X = B, overwriting B with X.
174 *
175  CALL dtpsv( 'Upper', 'No transpose', 'Non-unit', n, ap,
176  \$ b( 1, i ), 1 )
177  10 CONTINUE
178  ELSE
179 *
180 * Solve A*X = B where A = L * L**T.
181 *
182  DO 20 i = 1, nrhs
183 *
184 * Solve L*Y = B, overwriting B with X.
185 *
186  CALL dtpsv( 'Lower', 'No transpose', 'Non-unit', n, ap,
187  \$ b( 1, i ), 1 )
188 *
189 * Solve L**T *X = Y, overwriting B with X.
190 *
191  CALL dtpsv( 'Lower', 'Transpose', 'Non-unit', n, ap,
192  \$ b( 1, i ), 1 )
193  20 CONTINUE
194  END IF
195 *
196  RETURN
197 *
198 * End of DPPTRS
199 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dtpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPSV
Definition: dtpsv.f:144
Here is the call graph for this function:
Here is the caller graph for this function: