LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ dtrtrs()

subroutine dtrtrs ( character  UPLO,
character  TRANS,
character  DIAG,
integer  N,
integer  NRHS,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

DTRTRS

Download DTRTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DTRTRS solves a triangular system of the form

    A * X = B  or  A**T * X = B,

 where A is a triangular matrix of order N, and B is an N-by-NRHS
 matrix.  A check is made to verify that A is nonsingular.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  A is upper triangular;
          = 'L':  A is lower triangular.
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the form of the system of equations:
          = 'N':  A * X = B  (No transpose)
          = 'T':  A**T * X = B  (Transpose)
          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
[in]DIAG
          DIAG is CHARACTER*1
          = 'N':  A is non-unit triangular;
          = 'U':  A is unit triangular.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The triangular matrix A.  If UPLO = 'U', the leading N-by-N
          upper triangular part of the array A contains the upper
          triangular matrix, and the strictly lower triangular part of
          A is not referenced.  If UPLO = 'L', the leading N-by-N lower
          triangular part of the array A contains the lower triangular
          matrix, and the strictly upper triangular part of A is not
          referenced.  If DIAG = 'U', the diagonal elements of A are
          also not referenced and are assumed to be 1.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
          On entry, the right hand side matrix B.
          On exit, if INFO = 0, the solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
          > 0: if INFO = i, the i-th diagonal element of A is zero,
               indicating that the matrix is singular and the solutions
               X have not been computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 138 of file dtrtrs.f.

140 *
141 * -- LAPACK computational routine --
142 * -- LAPACK is a software package provided by Univ. of Tennessee, --
143 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
144 *
145 * .. Scalar Arguments ..
146  CHARACTER DIAG, TRANS, UPLO
147  INTEGER INFO, LDA, LDB, N, NRHS
148 * ..
149 * .. Array Arguments ..
150  DOUBLE PRECISION A( LDA, * ), B( LDB, * )
151 * ..
152 *
153 * =====================================================================
154 *
155 * .. Parameters ..
156  DOUBLE PRECISION ZERO, ONE
157  parameter( zero = 0.0d+0, one = 1.0d+0 )
158 * ..
159 * .. Local Scalars ..
160  LOGICAL NOUNIT
161 * ..
162 * .. External Functions ..
163  LOGICAL LSAME
164  EXTERNAL lsame
165 * ..
166 * .. External Subroutines ..
167  EXTERNAL dtrsm, xerbla
168 * ..
169 * .. Intrinsic Functions ..
170  INTRINSIC max
171 * ..
172 * .. Executable Statements ..
173 *
174 * Test the input parameters.
175 *
176  info = 0
177  nounit = lsame( diag, 'N' )
178  IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
179  info = -1
180  ELSE IF( .NOT.lsame( trans, 'N' ) .AND. .NOT.
181  $ lsame( trans, 'T' ) .AND. .NOT.lsame( trans, 'C' ) ) THEN
182  info = -2
183  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
184  info = -3
185  ELSE IF( n.LT.0 ) THEN
186  info = -4
187  ELSE IF( nrhs.LT.0 ) THEN
188  info = -5
189  ELSE IF( lda.LT.max( 1, n ) ) THEN
190  info = -7
191  ELSE IF( ldb.LT.max( 1, n ) ) THEN
192  info = -9
193  END IF
194  IF( info.NE.0 ) THEN
195  CALL xerbla( 'DTRTRS', -info )
196  RETURN
197  END IF
198 *
199 * Quick return if possible
200 *
201  IF( n.EQ.0 )
202  $ RETURN
203 *
204 * Check for singularity.
205 *
206  IF( nounit ) THEN
207  DO 10 info = 1, n
208  IF( a( info, info ).EQ.zero )
209  $ RETURN
210  10 CONTINUE
211  END IF
212  info = 0
213 *
214 * Solve A * x = b or A**T * x = b.
215 *
216  CALL dtrsm( 'Left', uplo, trans, diag, n, nrhs, one, a, lda, b,
217  $ ldb )
218 *
219  RETURN
220 *
221 * End of DTRTRS
222 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dtrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRSM
Definition: dtrsm.f:181
Here is the call graph for this function:
Here is the caller graph for this function: