LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ dtptri()

subroutine dtptri ( character  UPLO,
character  DIAG,
integer  N,
double precision, dimension( * )  AP,
integer  INFO 
)

DTPTRI

Download DTPTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DTPTRI computes the inverse of a real upper or lower triangular
 matrix A stored in packed format.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  A is upper triangular;
          = 'L':  A is lower triangular.
[in]DIAG
          DIAG is CHARACTER*1
          = 'N':  A is non-unit triangular;
          = 'U':  A is unit triangular.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]AP
          AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
          On entry, the upper or lower triangular matrix A, stored
          columnwise in a linear array.  The j-th column of A is stored
          in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*((2*n-j)/2) = A(i,j) for j<=i<=n.
          See below for further details.
          On exit, the (triangular) inverse of the original matrix, in
          the same packed storage format.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, A(i,i) is exactly zero.  The triangular
                matrix is singular and its inverse can not be computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
  A triangular matrix A can be transferred to packed storage using one
  of the following program segments:

  UPLO = 'U':                      UPLO = 'L':

        JC = 1                           JC = 1
        DO 2 J = 1, N                    DO 2 J = 1, N
           DO 1 I = 1, J                    DO 1 I = J, N
              AP(JC+I-1) = A(I,J)              AP(JC+I-J) = A(I,J)
      1    CONTINUE                    1    CONTINUE
           JC = JC + J                      JC = JC + N - J + 1
      2 CONTINUE                       2 CONTINUE

Definition at line 116 of file dtptri.f.

117 *
118 * -- LAPACK computational routine --
119 * -- LAPACK is a software package provided by Univ. of Tennessee, --
120 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121 *
122 * .. Scalar Arguments ..
123  CHARACTER DIAG, UPLO
124  INTEGER INFO, N
125 * ..
126 * .. Array Arguments ..
127  DOUBLE PRECISION AP( * )
128 * ..
129 *
130 * =====================================================================
131 *
132 * .. Parameters ..
133  DOUBLE PRECISION ONE, ZERO
134  parameter( one = 1.0d+0, zero = 0.0d+0 )
135 * ..
136 * .. Local Scalars ..
137  LOGICAL NOUNIT, UPPER
138  INTEGER J, JC, JCLAST, JJ
139  DOUBLE PRECISION AJJ
140 * ..
141 * .. External Functions ..
142  LOGICAL LSAME
143  EXTERNAL lsame
144 * ..
145 * .. External Subroutines ..
146  EXTERNAL dscal, dtpmv, xerbla
147 * ..
148 * .. Executable Statements ..
149 *
150 * Test the input parameters.
151 *
152  info = 0
153  upper = lsame( uplo, 'U' )
154  nounit = lsame( diag, 'N' )
155  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
156  info = -1
157  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
158  info = -2
159  ELSE IF( n.LT.0 ) THEN
160  info = -3
161  END IF
162  IF( info.NE.0 ) THEN
163  CALL xerbla( 'DTPTRI', -info )
164  RETURN
165  END IF
166 *
167 * Check for singularity if non-unit.
168 *
169  IF( nounit ) THEN
170  IF( upper ) THEN
171  jj = 0
172  DO 10 info = 1, n
173  jj = jj + info
174  IF( ap( jj ).EQ.zero )
175  $ RETURN
176  10 CONTINUE
177  ELSE
178  jj = 1
179  DO 20 info = 1, n
180  IF( ap( jj ).EQ.zero )
181  $ RETURN
182  jj = jj + n - info + 1
183  20 CONTINUE
184  END IF
185  info = 0
186  END IF
187 *
188  IF( upper ) THEN
189 *
190 * Compute inverse of upper triangular matrix.
191 *
192  jc = 1
193  DO 30 j = 1, n
194  IF( nounit ) THEN
195  ap( jc+j-1 ) = one / ap( jc+j-1 )
196  ajj = -ap( jc+j-1 )
197  ELSE
198  ajj = -one
199  END IF
200 *
201 * Compute elements 1:j-1 of j-th column.
202 *
203  CALL dtpmv( 'Upper', 'No transpose', diag, j-1, ap,
204  $ ap( jc ), 1 )
205  CALL dscal( j-1, ajj, ap( jc ), 1 )
206  jc = jc + j
207  30 CONTINUE
208 *
209  ELSE
210 *
211 * Compute inverse of lower triangular matrix.
212 *
213  jc = n*( n+1 ) / 2
214  DO 40 j = n, 1, -1
215  IF( nounit ) THEN
216  ap( jc ) = one / ap( jc )
217  ajj = -ap( jc )
218  ELSE
219  ajj = -one
220  END IF
221  IF( j.LT.n ) THEN
222 *
223 * Compute elements j+1:n of j-th column.
224 *
225  CALL dtpmv( 'Lower', 'No transpose', diag, n-j,
226  $ ap( jclast ), ap( jc+1 ), 1 )
227  CALL dscal( n-j, ajj, ap( jc+1 ), 1 )
228  END IF
229  jclast = jc
230  jc = jc - n + j - 2
231  40 CONTINUE
232  END IF
233 *
234  RETURN
235 *
236 * End of DTPTRI
237 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:79
subroutine dtpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPMV
Definition: dtpmv.f:142
Here is the call graph for this function:
Here is the caller graph for this function: