 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ dlarzt()

 subroutine dlarzt ( character DIRECT, character STOREV, integer N, integer K, double precision, dimension( ldv, * ) V, integer LDV, double precision, dimension( * ) TAU, double precision, dimension( ldt, * ) T, integer LDT )

DLARZT forms the triangular factor T of a block reflector H = I - vtvH.

Purpose:
``` DLARZT forms the triangular factor T of a real block reflector
H of order > n, which is defined as a product of k elementary
reflectors.

If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;

If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.

If STOREV = 'C', the vector which defines the elementary reflector
H(i) is stored in the i-th column of the array V, and

H  =  I - V * T * V**T

If STOREV = 'R', the vector which defines the elementary reflector
H(i) is stored in the i-th row of the array V, and

H  =  I - V**T * T * V

Currently, only STOREV = 'R' and DIRECT = 'B' are supported.```
Parameters
 [in] DIRECT ``` DIRECT is CHARACTER*1 Specifies the order in which the elementary reflectors are multiplied to form the block reflector: = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet) = 'B': H = H(k) . . . H(2) H(1) (Backward)``` [in] STOREV ``` STOREV is CHARACTER*1 Specifies how the vectors which define the elementary reflectors are stored (see also Further Details): = 'C': columnwise (not supported yet) = 'R': rowwise``` [in] N ``` N is INTEGER The order of the block reflector H. N >= 0.``` [in] K ``` K is INTEGER The order of the triangular factor T (= the number of elementary reflectors). K >= 1.``` [in,out] V ``` V is DOUBLE PRECISION array, dimension (LDV,K) if STOREV = 'C' (LDV,N) if STOREV = 'R' The matrix V. See further details.``` [in] LDV ``` LDV is INTEGER The leading dimension of the array V. If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.``` [in] TAU ``` TAU is DOUBLE PRECISION array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i).``` [out] T ``` T is DOUBLE PRECISION array, dimension (LDT,K) The k by k triangular factor T of the block reflector. If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is lower triangular. The rest of the array is not used.``` [in] LDT ``` LDT is INTEGER The leading dimension of the array T. LDT >= K.```
Contributors:
A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
Further Details:
```  The shape of the matrix V and the storage of the vectors which define
the H(i) is best illustrated by the following example with n = 5 and
k = 3. The elements equal to 1 are not stored; the corresponding
array elements are modified but restored on exit. The rest of the
array is not used.

DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':

______V_____
( v1 v2 v3 )                        /            \
( v1 v2 v3 )                      ( v1 v1 v1 v1 v1 . . . . 1 )
V = ( v1 v2 v3 )                      ( v2 v2 v2 v2 v2 . . . 1   )
( v1 v2 v3 )                      ( v3 v3 v3 v3 v3 . . 1     )
( v1 v2 v3 )
.  .  .
.  .  .
1  .  .
1  .
1

DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':

______V_____
1                                          /            \
.  1                           ( 1 . . . . v1 v1 v1 v1 v1 )
.  .  1                        ( . 1 . . . v2 v2 v2 v2 v2 )
.  .  .                        ( . . 1 . . v3 v3 v3 v3 v3 )
.  .  .
( v1 v2 v3 )
( v1 v2 v3 )
V = ( v1 v2 v3 )
( v1 v2 v3 )
( v1 v2 v3 )```

Definition at line 184 of file dlarzt.f.

185 *
186 * -- LAPACK computational routine --
187 * -- LAPACK is a software package provided by Univ. of Tennessee, --
188 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
189 *
190 * .. Scalar Arguments ..
191  CHARACTER DIRECT, STOREV
192  INTEGER K, LDT, LDV, N
193 * ..
194 * .. Array Arguments ..
195  DOUBLE PRECISION T( LDT, * ), TAU( * ), V( LDV, * )
196 * ..
197 *
198 * =====================================================================
199 *
200 * .. Parameters ..
201  DOUBLE PRECISION ZERO
202  parameter( zero = 0.0d+0 )
203 * ..
204 * .. Local Scalars ..
205  INTEGER I, INFO, J
206 * ..
207 * .. External Subroutines ..
208  EXTERNAL dgemv, dtrmv, xerbla
209 * ..
210 * .. External Functions ..
211  LOGICAL LSAME
212  EXTERNAL lsame
213 * ..
214 * .. Executable Statements ..
215 *
216 * Check for currently supported options
217 *
218  info = 0
219  IF( .NOT.lsame( direct, 'B' ) ) THEN
220  info = -1
221  ELSE IF( .NOT.lsame( storev, 'R' ) ) THEN
222  info = -2
223  END IF
224  IF( info.NE.0 ) THEN
225  CALL xerbla( 'DLARZT', -info )
226  RETURN
227  END IF
228 *
229  DO 20 i = k, 1, -1
230  IF( tau( i ).EQ.zero ) THEN
231 *
232 * H(i) = I
233 *
234  DO 10 j = i, k
235  t( j, i ) = zero
236  10 CONTINUE
237  ELSE
238 *
239 * general case
240 *
241  IF( i.LT.k ) THEN
242 *
243 * T(i+1:k,i) = - tau(i) * V(i+1:k,1:n) * V(i,1:n)**T
244 *
245  CALL dgemv( 'No transpose', k-i, n, -tau( i ),
246  \$ v( i+1, 1 ), ldv, v( i, 1 ), ldv, zero,
247  \$ t( i+1, i ), 1 )
248 *
249 * T(i+1:k,i) = T(i+1:k,i+1:k) * T(i+1:k,i)
250 *
251  CALL dtrmv( 'Lower', 'No transpose', 'Non-unit', k-i,
252  \$ t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
253  END IF
254  t( i, i ) = tau( i )
255  END IF
256  20 CONTINUE
257  RETURN
258 *
259 * End of DLARZT
260 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dtrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
DTRMV
Definition: dtrmv.f:147
subroutine dgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
DGEMV
Definition: dgemv.f:156
Here is the call graph for this function:
Here is the caller graph for this function: