LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ dpbcon()

subroutine dpbcon ( character  UPLO,
integer  N,
integer  KD,
double precision, dimension( ldab, * )  AB,
integer  LDAB,
double precision  ANORM,
double precision  RCOND,
double precision, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

DPBCON

Download DPBCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DPBCON estimates the reciprocal of the condition number (in the
 1-norm) of a real symmetric positive definite band matrix using the
 Cholesky factorization A = U**T*U or A = L*L**T computed by DPBTRF.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangular factor stored in AB;
          = 'L':  Lower triangular factor stored in AB.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]KD
          KD is INTEGER
          The number of superdiagonals of the matrix A if UPLO = 'U',
          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
[in]AB
          AB is DOUBLE PRECISION array, dimension (LDAB,N)
          The triangular factor U or L from the Cholesky factorization
          A = U**T*U or A = L*L**T of the band matrix A, stored in the
          first KD+1 rows of the array.  The j-th column of U or L is
          stored in the j-th column of the array AB as follows:
          if UPLO ='U', AB(kd+1+i-j,j) = U(i,j) for max(1,j-kd)<=i<=j;
          if UPLO ='L', AB(1+i-j,j)    = L(i,j) for j<=i<=min(n,j+kd).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KD+1.
[in]ANORM
          ANORM is DOUBLE PRECISION
          The 1-norm (or infinity-norm) of the symmetric band matrix A.
[out]RCOND
          RCOND is DOUBLE PRECISION
          The reciprocal of the condition number of the matrix A,
          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
          estimate of the 1-norm of inv(A) computed in this routine.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (3*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 130 of file dpbcon.f.

132 *
133 * -- LAPACK computational routine --
134 * -- LAPACK is a software package provided by Univ. of Tennessee, --
135 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
136 *
137 * .. Scalar Arguments ..
138  CHARACTER UPLO
139  INTEGER INFO, KD, LDAB, N
140  DOUBLE PRECISION ANORM, RCOND
141 * ..
142 * .. Array Arguments ..
143  INTEGER IWORK( * )
144  DOUBLE PRECISION AB( LDAB, * ), WORK( * )
145 * ..
146 *
147 * =====================================================================
148 *
149 * .. Parameters ..
150  DOUBLE PRECISION ONE, ZERO
151  parameter( one = 1.0d+0, zero = 0.0d+0 )
152 * ..
153 * .. Local Scalars ..
154  LOGICAL UPPER
155  CHARACTER NORMIN
156  INTEGER IX, KASE
157  DOUBLE PRECISION AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
158 * ..
159 * .. Local Arrays ..
160  INTEGER ISAVE( 3 )
161 * ..
162 * .. External Functions ..
163  LOGICAL LSAME
164  INTEGER IDAMAX
165  DOUBLE PRECISION DLAMCH
166  EXTERNAL lsame, idamax, dlamch
167 * ..
168 * .. External Subroutines ..
169  EXTERNAL dlacn2, dlatbs, drscl, xerbla
170 * ..
171 * .. Intrinsic Functions ..
172  INTRINSIC abs
173 * ..
174 * .. Executable Statements ..
175 *
176 * Test the input parameters.
177 *
178  info = 0
179  upper = lsame( uplo, 'U' )
180  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
181  info = -1
182  ELSE IF( n.LT.0 ) THEN
183  info = -2
184  ELSE IF( kd.LT.0 ) THEN
185  info = -3
186  ELSE IF( ldab.LT.kd+1 ) THEN
187  info = -5
188  ELSE IF( anorm.LT.zero ) THEN
189  info = -6
190  END IF
191  IF( info.NE.0 ) THEN
192  CALL xerbla( 'DPBCON', -info )
193  RETURN
194  END IF
195 *
196 * Quick return if possible
197 *
198  rcond = zero
199  IF( n.EQ.0 ) THEN
200  rcond = one
201  RETURN
202  ELSE IF( anorm.EQ.zero ) THEN
203  RETURN
204  END IF
205 *
206  smlnum = dlamch( 'Safe minimum' )
207 *
208 * Estimate the 1-norm of the inverse.
209 *
210  kase = 0
211  normin = 'N'
212  10 CONTINUE
213  CALL dlacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
214  IF( kase.NE.0 ) THEN
215  IF( upper ) THEN
216 *
217 * Multiply by inv(U**T).
218 *
219  CALL dlatbs( 'Upper', 'Transpose', 'Non-unit', normin, n,
220  $ kd, ab, ldab, work, scalel, work( 2*n+1 ),
221  $ info )
222  normin = 'Y'
223 *
224 * Multiply by inv(U).
225 *
226  CALL dlatbs( 'Upper', 'No transpose', 'Non-unit', normin, n,
227  $ kd, ab, ldab, work, scaleu, work( 2*n+1 ),
228  $ info )
229  ELSE
230 *
231 * Multiply by inv(L).
232 *
233  CALL dlatbs( 'Lower', 'No transpose', 'Non-unit', normin, n,
234  $ kd, ab, ldab, work, scalel, work( 2*n+1 ),
235  $ info )
236  normin = 'Y'
237 *
238 * Multiply by inv(L**T).
239 *
240  CALL dlatbs( 'Lower', 'Transpose', 'Non-unit', normin, n,
241  $ kd, ab, ldab, work, scaleu, work( 2*n+1 ),
242  $ info )
243  END IF
244 *
245 * Multiply by 1/SCALE if doing so will not cause overflow.
246 *
247  scale = scalel*scaleu
248  IF( scale.NE.one ) THEN
249  ix = idamax( n, work, 1 )
250  IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
251  $ GO TO 20
252  CALL drscl( n, scale, work, 1 )
253  END IF
254  GO TO 10
255  END IF
256 *
257 * Compute the estimate of the reciprocal condition number.
258 *
259  IF( ainvnm.NE.zero )
260  $ rcond = ( one / ainvnm ) / anorm
261 *
262  20 CONTINUE
263 *
264  RETURN
265 *
266 * End of DPBCON
267 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
integer function idamax(N, DX, INCX)
IDAMAX
Definition: idamax.f:71
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dlatbs(UPLO, TRANS, DIAG, NORMIN, N, KD, AB, LDAB, X, SCALE, CNORM, INFO)
DLATBS solves a triangular banded system of equations.
Definition: dlatbs.f:242
subroutine drscl(N, SA, SX, INCX)
DRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: drscl.f:84
subroutine dlacn2(N, V, X, ISGN, EST, KASE, ISAVE)
DLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: dlacn2.f:136
Here is the call graph for this function:
Here is the caller graph for this function: