dptt01()

subroutine dptt01	(	integer	n,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( * )	df,
		double precision, dimension( * )	ef,
		double precision, dimension( * )	work,
		double precision	resid )

DPTT01

Purpose:

!>
!> DPTT01 reconstructs a tridiagonal matrix A from its L*D*L'
!> factorization and computes the residual
!>    norm(L*D*L' - A) / ( n * norm(A) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the tridiagonal matrix A. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the tridiagonal matrix A. !>
[in]	DF	!> DF is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the factor L from the L*D*L' !> factorization of A. !>
[in]	EF	!> EF is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the factor L from the !> L*D*L' factorization of A. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (2*N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> norm(L*D*L' - A) / (n * norm(A) * EPS) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 90 of file dptt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), DF( * ), E( * ), EF( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION   ANORM, DE, EPS
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
      eps = dlamch( 'Epsilon' )
*
*     Construct the difference L*D*L' - A.
*
      work( 1 ) = df( 1 ) - d( 1 )
      DO 10 i = 1, n - 1
         de = df( i )*ef( i )
         work( n+i ) = de - e( i )
         work( 1+i ) = de*ef( i ) + df( i+1 ) - d( i+1 )
   10 CONTINUE
*
*     Compute the 1-norms of the tridiagonal matrices A and WORK.
*
      IF( n.EQ.1 ) THEN
         anorm = d( 1 )
         resid = abs( work( 1 ) )
      ELSE
         anorm = max( d( 1 )+abs( e( 1 ) ), d( n )+abs( e( n-1 ) ) )
         resid = max( abs( work( 1 ) )+abs( work( n+1 ) ),
     $           abs( work( n ) )+abs( work( 2*n-1 ) ) )
         DO 20 i = 2, n - 1
            anorm = max( anorm, d( i )+abs( e( i ) )+abs( e( i-1 ) ) )
            resid = max( resid, abs( work( i ) )+abs( work( n+i-1 ) )+
     $              abs( work( n+i ) ) )
   20    CONTINUE
      END IF
*
*     Compute norm(L*D*L' - A) / (n * norm(A) * EPS)
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of DPTT01
*

Here is the caller graph for this function: