zlarnd()

complex*16 function zlarnd	(	integer	idist,
		integer, dimension( 4 )	iseed )

ZLARND

Purpose:

!>
!> ZLARND returns a random complex number from a uniform or normal
!> distribution.
!> 

Parameters

[in]	IDIST	!> IDIST is INTEGER !> Specifies the distribution of the random numbers: !> = 1: real and imaginary parts each uniform (0,1) !> = 2: real and imaginary parts each uniform (-1,1) !> = 3: real and imaginary parts each normal (0,1) !> = 4: uniformly distributed on the disc abs(z) <= 1 !> = 5: uniformly distributed on the circle abs(z) = 1 !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry, the seed of the random number generator; the array !> elements must be between 0 and 4095, and ISEED(4) must be !> odd. !> On exit, the seed is updated. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  This routine calls the auxiliary routine DLARAN to generate a random
!>  real number from a uniform (0,1) distribution. The Box-Muller method
!>  is used to transform numbers from a uniform to a normal distribution.
!> 

Definition at line 74 of file zlarnd.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IDIST
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO
      parameter( zero = 0.0d+0, one = 1.0d+0, two = 2.0d+0 )
      DOUBLE PRECISION   TWOPI
      parameter( twopi = 6.28318530717958647692528676655900576839d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   T1, T2
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLARAN
      EXTERNAL           dlaran
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, exp, log, sqrt
*     ..
*     .. Executable Statements ..
*
*     Generate a pair of real random numbers from a uniform (0,1)
*     distribution
*
      t1 = dlaran( iseed )
      t2 = dlaran( iseed )
*
      IF( idist.EQ.1 ) THEN
*
*        real and imaginary parts each uniform (0,1)
*
         zlarnd = dcmplx( t1, t2 )
      ELSE IF( idist.EQ.2 ) THEN
*
*        real and imaginary parts each uniform (-1,1)
*
         zlarnd = dcmplx( two*t1-one, two*t2-one )
      ELSE IF( idist.EQ.3 ) THEN
*
*        real and imaginary parts each normal (0,1)
*
         zlarnd = sqrt( -two*log( t1 ) )*
     $            exp( dcmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.4 ) THEN
*
*        uniform distribution on the unit disc abs(z) <= 1
*
         zlarnd = sqrt( t1 )*exp( dcmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.5 ) THEN
*
*        uniform distribution on the unit circle abs(z) = 1
*
         zlarnd = exp( dcmplx( zero, twopi*t2 ) )
      END IF
      RETURN
*
*     End of ZLARND
*

Here is the call graph for this function:

Here is the caller graph for this function: