dpot01()

subroutine dpot01	(	character	uplo,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldafac, * )	afac,
		integer	ldafac,
		double precision, dimension( * )	rwork,
		double precision	resid )

DPOT01

Purpose:

!>
!> DPOT01 reconstructs a symmetric positive definite matrix  A  from
!> its L*L' or U'*U factorization and computes the residual
!>    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
!>    norm( U'*U - A ) / ( N * norm(A) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> symmetric matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The original symmetric matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N) !>
[in,out]	AFAC	!> AFAC is DOUBLE PRECISION array, dimension (LDAFAC,N) !> On entry, the factor L or U from the L * L**T or U**T * U !> factorization of A. !> Overwritten with the reconstructed matrix, and then with !> the difference L * L**T - A (or U**T * U - A). !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. LDAFAC >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> If UPLO = 'L', norm(L * L**T - A) / ( N * norm(A) * EPS ) !> If UPLO = 'U', norm(U**T * U - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 103 of file dpot01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAFAC, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AFAC( LDAFAC, * ), RWORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      DOUBLE PRECISION   ANORM, EPS, T
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DDOT, DLAMCH, DLANSY
      EXTERNAL           lsame, ddot, dlamch, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dsyr, dtrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansy( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute the product U**T * U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            t = ddot( k, afac( 1, k ), 1, afac( 1, k ), 1 )
            afac( k, k ) = t
*
*           Compute the rest of column K.
*
            CALL dtrmv( 'Upper', 'Transpose', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
   10    CONTINUE
*
*     Compute the product L * L**T, overwriting L.
*
      ELSE
         DO 20 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL dsyr( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            t = afac( k, k )
            CALL dscal( n-k+1, t, afac( k, k ), 1 )
*
   20    CONTINUE
      END IF
*
*     Compute the difference L * L**T - A (or U**T * U - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 40 j = 1, n
            DO 30 i = 1, j
               afac( i, j ) = afac( i, j ) - a( i, j )
   30       CONTINUE
   40    CONTINUE
      ELSE
         DO 60 j = 1, n
            DO 50 i = j, n
               afac( i, j ) = afac( i, j ) - a( i, j )
   50       CONTINUE
   60    CONTINUE
      END IF
*
*     Compute norm(L*U - A) / ( N * norm(A) * EPS )
*
      resid = dlansy( '1', uplo, n, afac, ldafac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of DPOT01
*

Here is the call graph for this function:

Here is the caller graph for this function: