zlarf1l()

subroutine zlarf1l	(	character	side,
		integer	m,
		integer	n,
		complex*16, dimension( * )	v,
		integer	incv,
		complex*16	tau,
		complex*16, dimension( ldc, * )	c,
		integer	ldc,
		complex*16, dimension( * )	work )

ZLARF1L applies an elementary reflector to a general rectangular

Download ZLARF1L + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLARF1L applies a complex elementary reflector H to a complex m by n matrix
!> C, from either the left or the right. H is represented in the form
!>
!>       H = I - tau * v * v**H
!>
!> where tau is a real scalar and v is a real vector assuming v(lastv) = 1,
!> where lastv is the last non-zero element.
!>
!> If tau = 0, then H is taken to be the unit matrix.
!>
!> To apply H**H (the conjugate transpose of H), supply conjg(tau) instead
!> tau.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': form H * C !> = 'R': form C * H !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. !>
[in]	V	!> V is COMPLEX*16 array, dimension !> (1 + (M-1)*abs(INCV)) if SIDE = 'L' !> or (1 + (N-1)*abs(INCV)) if SIDE = 'R' !> The vector v in the representation of H. V is not used if !> TAU = 0. !>
[in]	INCV	!> INCV is INTEGER !> The increment between elements of v. INCV > 0. !>
[in]	TAU	!> TAU is COMPLEX*16 !> The value tau in the representation of H. !>
[in,out]	C	!> C is COMPLEX*16 array, dimension (LDC,N) !> On entry, the m by n matrix C. !> On exit, C is overwritten by the matrix H * C if SIDE = 'L', !> or C * H if SIDE = 'R'. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension !> (N) if SIDE = 'L' !> or (M) if SIDE = 'R' !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 129 of file zlarf1l.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE
      INTEGER            INCV, LDC, M, N
      COMPLEX*16         TAU
*     ..
*     .. Array Arguments ..
      COMPLEX*16         C( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            APPLYLEFT
      INTEGER            I, J, LASTV, LASTC, FIRSTV
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemv, zgerc, zscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dconjg
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAZLR, ILAZLC
      EXTERNAL           lsame, ilazlr, ilazlc
*     ..
*     .. Executable Statements ..
*
      applyleft = lsame( side, 'L' )
      firstv = 1
      lastc = 0
      IF( tau.NE.zero ) THEN
!     Set up variables for scanning V.  LASTV begins pointing to the end
!     of V up to V(1).
         IF( applyleft ) THEN
            lastv = m
         ELSE
            lastv = n
         END IF
         i = 1
!     Look for the last non-zero row in V.
         DO WHILE( lastv.GT.firstv .AND. v( i ).EQ.zero )
            firstv = firstv + 1
            i = i + incv
         END DO
         IF( applyleft ) THEN
!     Scan for the last non-zero column in C(1:lastv,:).
            lastc = ilazlc(lastv, n, c, ldc)
         ELSE
!     Scan for the last non-zero row in C(:,1:lastv).
            lastc = ilazlr(m, lastv, c, ldc)
         END IF
      END IF
      IF( lastc.EQ.0 ) THEN
         RETURN
      END IF
      IF( applyleft ) THEN
*
*        Form  H * C
*
         IF( lastv.EQ.firstv ) THEN        
*
*           C(lastv,1:lastc) := ( 1 - tau ) * C(lastv,1:lastc)
*
            CALL zscal( lastc, one - tau, c( lastv, 1 ), ldc )
         ELSE
*
*           w(1:lastc,1) := C(firstv:lastv-1,1:lastc)**T * v(firstv:lastv-1,1)
*
            CALL zgemv( 'Conjugate transpose', lastv - firstv, lastc,
     $                  one, c( firstv, 1 ), ldc, v( i ), incv, zero,
     $                  work, 1 )
*
*           w(1:lastc,1) += C(lastv,1:lastc)**H * v(lastv,1)
*
            DO j = 1, lastc
               work( j ) = work( j ) + conjg( c( lastv, j ) )
            END DO
*
*           C(lastv,1:lastc) += - tau * v(lastv,1) * w(1:lastc,1)**H
*
            DO j = 1, lastc
               c( lastv, j ) = c( lastv, j )
     $                         - tau * conjg( work( j ) )
            END DO
*
*           C(firstv:lastv-1,1:lastc) += - tau * v(firstv:lastv-1,1) * w(1:lastc,1)**H
*
            CALL zgerc( lastv - firstv, lastc, -tau, v( i ), incv,
     $                  work, 1, c( firstv, 1 ), ldc)
         END IF
      ELSE
*
*        Form  C * H
*
         IF( lastv.EQ.firstv ) THEN
*
*           C(1:lastc,lastv) := ( 1 - tau ) * C(1:lastc,lastv)
*
            CALL zscal( lastc, one - tau, c( 1, lastv ), 1 )
         ELSE
*
*           w(1:lastc,1) := C(1:lastc,firstv:lastv-1) * v(firstv:lastv-1,1)
*
            CALL zgemv( 'No transpose', lastc, lastv - firstv, one,
     $                  c( 1, firstv ), ldc, v( i ), incv, zero,
     $                  work, 1 )
*
*           w(1:lastc,1) += C(1:lastc,lastv) * v(lastv,1)
*
            CALL zaxpy( lastc, one, c( 1, lastv ), 1, work, 1 )
*
*           C(1:lastc,lastv) += - tau * v(lastv,1) * w(1:lastc,1)
*
            CALL zaxpy( lastc, -tau, work, 1, c( 1, lastv ), 1 )
*
*           C(1:lastc,firstv:lastv-1) += - tau * w(1:lastc,1) * v(firstv:lastv-1)**H
*
            CALL zgerc( lastc, lastv - firstv, -tau, work, 1, v( i ),
     $                  incv, c( 1, firstv ), ldc )
         END IF
      END IF
      RETURN
*
*     End of ZLARF1L
*

Here is the call graph for this function:

Here is the caller graph for this function: